t/v2writable.t

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::MIME;
   7 use PublicInbox::ContentId qw(content_digest);
   8 use File::Temp qw/tempdir/;
   9 require './t/common.perl';
  10 require_git(2.6);
  11 foreach my $mod (qw(DBD::SQLite Search::Xapian)) {
  12         eval "require $mod";
  13         plan skip_all => "$mod missing for nntpd.t" if $@;
  14 }
  15 use_ok 'PublicInbox::V2Writable';
  16 umask 007;
  17 my $mainrepo = tempdir('pi-v2writable-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  18 my $ibx = {
  19         mainrepo => $mainrepo,
  20         name => 'test-v2writable',
  21         version => 2,
  22         -primary_address => 'test@example.com',
  23 };
  24 $ibx = PublicInbox::Inbox->new($ibx);
  25 my $mime = PublicInbox::MIME->create(
  26         header => [
  27                 From => 'a@example.com',
  28                 To => 'test@example.com',
  29                 Subject => 'this is a subject',
  30                 'Message-ID' => '<a-mid@b>',
  31                 Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  32         ],
  33         body => "hello world\n",
  34 );
  35
  36 my $im = PublicInbox::V2Writable->new($ibx, {nproc => 1});
  37 is($im->{shards}, 1, 'one shard when forced');
  38 ok($im->add($mime), 'ordinary message added');
  39 foreach my $f ("$mainrepo/msgmap.sqlite3",
  40                 glob("$mainrepo/xap*/*"),
  41                 glob("$mainrepo/xap*/*/*")) {
  42         my @st = stat($f);
  43         my ($bn) = (split(m!/!, $f))[-1];
  44         is($st[2] & 07777, -f _ ? 0660 : 0770,
  45                 "default sharedRepository respected for $bn");
  46 }
  47
  48 my $git0;
  49
  50 if ('ensure git configs are correct') {
  51         my @cmd = (qw(git config), "--file=$mainrepo/all.git/config",
  52                 qw(core.sharedRepository 0644));
  53         is(system(@cmd), 0, "set sharedRepository in all.git");
  54         $git0 = PublicInbox::Git->new("$mainrepo/git/0.git");
  55         chomp(my $v = $git0->qx(qw(config core.sharedRepository)));
  56         is($v, '0644', 'child repo inherited core.sharedRepository');
  57         chomp($v = $git0->qx(qw(config --bool repack.writeBitmaps)));
  58         is($v, 'true', 'child repo inherited repack.writeBitmaps');
  59 }
  60
  61 {
  62         my @warn;
  63         local $SIG{__WARN__} = sub { push @warn, @_ };
  64         is($im->add($mime), undef, 'obvious duplicate rejected');
  65         is(scalar(@warn), 0, 'no warning about resent message');
  66
  67         @warn = ();
  68         $mime->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  69         is($im->add($mime), undef, 'secondary MID ignored if first matches');
  70         my $sec = PublicInbox::MIME->new($mime->as_string);
  71         $sec->header_set('Date');
  72         $sec->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  73         ok($im->add($sec), 'secondary MID used if data is different');
  74         like(join(' ', @warn), qr/mismatched/, 'warned about mismatch');
  75         like(join(' ', @warn), qr/alternative/, 'warned about alternative');
  76         is_deeply([ '<a-mid@b>', '<c@d>' ],
  77                 [ $sec->header_obj->header_raw('Message-Id') ],
  78                 'no new Message-Id added');
  79
  80         my $sane_mid = qr/\A<[\w\-\.]+\@\w+>\z/;
  81         @warn = ();
  82         $mime->header_set('Message-Id', '<a-mid@b>');
  83         $mime->body_set('different');
  84         ok($im->add($mime), 'reused mid ok');
  85         like(join(' ', @warn), qr/reused/, 'warned about reused MID');
  86         my @mids = $mime->header_obj->header_raw('Message-Id');
  87         is($mids[0], '<a-mid@b>', 'original mid not changed');
  88         like($mids[1], $sane_mid, 'new MID added');
  89         is(scalar(@mids), 2, 'only one new MID added');
  90
  91         @warn = ();
  92         $mime->header_set('Message-Id', '<a-mid@b>');
  93         $mime->body_set('this one needs a random mid');
  94         my $hdr = $mime->header_obj;
  95         my $gen = PublicInbox::Import::digest2mid(content_digest($mime), $hdr);
  96         unlike($gen, qr![\+/=]!, 'no URL-unfriendly chars in Message-Id');
  97         my $fake = PublicInbox::MIME->new($mime->as_string);
  98         $fake->header_set('Message-Id', "<$gen>");
  99         ok($im->add($fake), 'fake added easily');
 100         is_deeply(\@warn, [], 'no warnings from a faker');
 101         ok($im->add($mime), 'random MID made');
 102         like(join(' ', @warn), qr/using random/, 'warned about using random');
 103         @mids = $mime->header_obj->header_raw('Message-Id');
 104         is($mids[0], '<a-mid@b>', 'original mid not changed');
 105         like($mids[1], $sane_mid, 'new MID added');
 106         is(scalar(@mids), 2, 'only one new MID added');
 107
 108         @warn = ();
 109         $mime->header_set('Message-Id');
 110         ok($im->add($mime), 'random MID made for MID free message');
 111         @mids = $mime->header_obj->header_raw('Message-Id');
 112         like($mids[0], $sane_mid, 'mid was generated');
 113         is(scalar(@mids), 1, 'new generated');
 114 }
 115
 116 {
 117         $mime->header_set('Message-Id', '<abcde@1>', '<abcde@2>');
 118         $mime->header_set('References', '<zz-mid@b>');
 119         ok($im->add($mime), 'message with multiple Message-ID');
 120         $im->done;
 121         my $srch = $ibx->search;
 122         my $mset1 = $srch->reopen->query('m:abcde@1', { mset => 1 });
 123         is($mset1->size, 1, 'message found by first MID');
 124         my $mset2 = $srch->reopen->query('m:abcde@2', { mset => 1 });
 125         is($mset2->size, 1, 'message found by second MID');
 126         is((($mset1->items)[0])->get_docid, (($mset2->items)[0])->get_docid,
 127                 'same document') if ($mset1->size);
 128 }
 129
 130 {
 131         use Net::NNTP;
 132         use IO::Socket::INET;
 133         my $err = "$mainrepo/stderr.log";
 134         my $out = "$mainrepo/stdout.log";
 135         my %opts = (
 136                 LocalAddr => '127.0.0.1',
 137                 ReuseAddr => 1,
 138                 Proto => 'tcp',
 139                 Type => SOCK_STREAM,
 140                 Listen => 1024,
 141         );
 142         my $group = 'inbox.comp.test.v2writable';
 143         my $pi_config = "$mainrepo/pi_config";
 144         open my $fh, '>', $pi_config or die "open: $!\n";
 145         print $fh <<EOF
 146 [publicinbox "test-v2writable"]
 147         mainrepo = $mainrepo
 148         version = 2
 149         address = test\@example.com
 150         newsgroup = $group
 151 EOF
 152         ;
 153         close $fh or die "close: $!\n";
 154         my $sock = IO::Socket::INET->new(%opts);
 155         ok($sock, 'sock created');
 156         my $pid;
 157         my $len;
 158         END { kill 'TERM', $pid if defined $pid };
 159         my $nntpd = 'blib/script/public-inbox-nntpd';
 160         my $cmd = [ $nntpd, "--stdout=$out", "--stderr=$err" ];
 161         $pid = spawn_listener({ PI_CONFIG => $pi_config }, $cmd, [ $sock ]);
 162         my $host_port = $sock->sockhost . ':' . $sock->sockport;
 163         my $n = Net::NNTP->new($host_port);
 164         $n->group($group);
 165         my $x = $n->xover('1-');
 166         my %uniq;
 167         foreach my $num (sort { $a <=> $b } keys %$x) {
 168                 my $mid = $x->{$num}->[3];
 169                 is($uniq{$mid}++, 0, "MID for $num is unique in XOVER");
 170                 is_deeply($n->xhdr('Message-ID', $num),
 171                          { $num => $mid }, "XHDR lookup OK on num $num");
 172                 is_deeply($n->xhdr('Message-ID', $mid),
 173                          { $mid => $mid }, "XHDR lookup OK on MID $num");
 174         }
 175         my %nn;
 176         foreach my $mid (@{$n->newnews(0, $group)}) {
 177                 is($nn{$mid}++, 0, "MID is unique in NEWNEWS");
 178         }
 179         is_deeply([sort keys %nn], [sort keys %uniq]);
 180
 181         my %lg;
 182         foreach my $num (@{$n->listgroup($group)}) {
 183                 is($lg{$num}++, 0, "num is unique in LISTGROUP");
 184         }
 185         is_deeply([sort keys %lg], [sort keys %$x],
 186                 'XOVER and LISTGROUPS return the same article numbers');
 187
 188         my $xref = $n->xhdr('Xref', '1-');
 189         is_deeply([sort keys %lg], [sort keys %$xref], 'Xref range OK');
 190
 191         my $mids = $n->xhdr('Message-ID', '1-');
 192         is_deeply([sort keys %lg], [sort keys %$xref], 'Message-ID range OK');
 193
 194         my $rover = $n->xrover('1-');
 195         is_deeply([sort keys %lg], [sort keys %$rover], 'XROVER range OK');
 196 };
 197 {
 198         my @log = qw(log --no-decorate --no-abbrev --no-notes --no-color);
 199         my @before = $git0->qx(@log, qw(--pretty=oneline));
 200         my $before = $git0->qx(@log, qw(--pretty=raw --raw -r));
 201         $im = PublicInbox::V2Writable->new($ibx, {nproc => 2});
 202         is($im->{shards}, 1, 'detected single shard from previous');
 203         my $smsg = $im->remove($mime, 'test removal');
 204         $im->done;
 205         my @after = $git0->qx(@log, qw(--pretty=oneline));
 206         my $tip = shift @after;
 207         like($tip, qr/\A[a-f0-9]+ test removal\n\z/s,
 208                 'commit message propagated to git');
 209         is_deeply(\@after, \@before, 'only one commit written to git');
 210         is($ibx->mm->num_for($smsg->mid), undef, 'no longer in Msgmap by mid');
 211         my $num = $smsg->{num};
 212         like($num, qr/\A\d+\z/, 'numeric number in return message');
 213         is($ibx->mm->mid_for($num), undef, 'no longer in Msgmap by num');
 214         my $srch = $ibx->search->reopen;
 215         my $mset = $srch->query('m:'.$smsg->mid, { mset => 1});
 216         is($mset->size, 0, 'no longer found in Xapian');
 217         my @log1 = (@log, qw(-1 --pretty=raw --raw -r --no-renames));
 218         is($srch->{over_ro}->get_art($num), undef,
 219                 'removal propagated to Over DB');
 220
 221         my $after = $git0->qx(@log1);
 222         if ($after =~ m!( [a-f0-9]+ )A\td$!m) {
 223                 my $oid = $1;
 224                 ok(index($before, $oid) > 0, 'no new blob introduced');
 225         } else {
 226                 fail('failed to extract blob from log output');
 227         }
 228         is($im->remove($mime, 'test removal'), undef,
 229                 'remove is idempotent');
 230         $im->done;
 231         is($git0->qx(@log1),
 232                 $after, 'no git history made with idempotent remove');
 233         eval { $im->done };
 234         ok(!$@, '->done is idempotent');
 235 }
 236
 237 {
 238         ok($im->add($mime), 'add message to be purged');
 239         local $SIG{__WARN__} = sub {};
 240         ok(my $cmts = $im->purge($mime), 'purged message');
 241         like($cmts->[0], qr/\A[a-f0-9]{40}\z/, 'purge returned current commit');
 242         $im->done;
 243
 244         # again
 245         is($im->purge($mime), undef, 'no-op returns undef');
 246 }
 247
 248 {
 249         my $x = 'x'x250;
 250         my $y = 'y'x250;
 251         local $SIG{__WARN__} = sub {};
 252         $mime->header_set('Subject', 'long mid');
 253         $mime->header_set('Message-ID', "<$x>");
 254         ok($im->add($mime), 'add excessively long Message-ID');
 255
 256         $mime->header_set('Message-ID', "<$y>");
 257         $mime->header_set('References', "<$x>");
 258         ok($im->add($mime), 'add excessively long References');
 259         $im->barrier;
 260
 261         my $msgs = $ibx->search->{over_ro}->get_thread('x'x244);
 262         is(2, scalar(@$msgs), 'got both messages');
 263         is($msgs->[0]->{mid}, 'x'x244, 'stored truncated mid');
 264         is($msgs->[1]->{references}, '<'.('x'x244).'>', 'stored truncated ref');
 265         is($msgs->[1]->{mid}, 'y'x244, 'stored truncated mid(2)');
 266         $im->done;
 267 }
 268
 269 done_testing();