t/v2writable.t

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::MIME;
   7 use PublicInbox::ContentId qw(content_digest);
   8 use File::Temp qw/tempdir/;
   9 foreach my $mod (qw(DBD::SQLite Search::Xapian)) {
  10         eval "require $mod";
  11         plan skip_all => "$mod missing for nntpd.t" if $@;
  12 }
  13 use_ok 'PublicInbox::V2Writable';
  14 my $mainrepo = tempdir('pi-v2writable-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  15 my $ibx = {
  16         mainrepo => $mainrepo,
  17         name => 'test-v2writable',
  18         version => 2,
  19         -primary_address => 'test@example.com',
  20 };
  21 $ibx = PublicInbox::Inbox->new($ibx);
  22 my $mime = PublicInbox::MIME->create(
  23         header => [
  24                 From => 'a@example.com',
  25                 To => 'test@example.com',
  26                 Subject => 'this is a subject',
  27                 'Message-ID' => '<a-mid@b>',
  28                 Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  29         ],
  30         body => "hello world\n",
  31 );
  32
  33 my $im = eval {
  34         local $ENV{NPROC} = '1';
  35         PublicInbox::V2Writable->new($ibx, 1);
  36 };
  37 is($im->{partitions}, 1, 'one partition when forced');
  38 ok($im->add($mime), 'ordinary message added');
  39
  40 if ('ensure git configs are correct') {
  41         my @cmd = (qw(git config), "--file=$mainrepo/all.git/config",
  42                 qw(core.sharedRepository 0644));
  43         is(system(@cmd), 0, "set sharedRepository in all.git");
  44         my $git0 = PublicInbox::Git->new("$mainrepo/git/0.git");
  45         my $fh = $git0->popen(qw(config core.sharedRepository));
  46         my $v = eval { local $/; <$fh> };
  47         chomp $v;
  48         is($v, '0644', 'child repo inherited core.sharedRepository');
  49         $fh = $git0->popen(qw(config --bool repack.writeBitmaps));
  50         $v = eval { local $/; <$fh> };
  51         chomp $v;
  52         is($v, 'true', 'child repo inherited repack.writeBitmaps');
  53 }
  54
  55 {
  56         my @warn;
  57         local $SIG{__WARN__} = sub { push @warn, @_ };
  58         is(undef, $im->add($mime), 'obvious duplicate rejected');
  59         like(join(' ', @warn), qr/resent/, 'warned about resent message');
  60
  61         @warn = ();
  62         $mime->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  63         ok($im->add($mime), 'secondary MID used');
  64         like(join(' ', @warn), qr/mismatched/, 'warned about mismatch');
  65         like(join(' ', @warn), qr/alternative/, 'warned about alternative');
  66         is_deeply([ '<a-mid@b>', '<c@d>' ],
  67                 [ $mime->header_obj->header_raw('Message-Id') ],
  68                 'no new Message-Id added');
  69
  70         @warn = ();
  71         $mime->header_set('Message-Id', '<a-mid@b>');
  72         $mime->body_set('different');
  73         ok($im->add($mime), 'reused mid ok');
  74         like(join(' ', @warn), qr/reused/, 'warned about reused MID');
  75         my @mids = $mime->header_obj->header_raw('Message-Id');
  76         is($mids[1], '<a-mid@b>', 'original mid not changed');
  77         like($mids[0], qr/\A<\w+\@localhost>\z/, 'new MID added');
  78         is(scalar(@mids), 2, 'only one new MID added');
  79
  80         @warn = ();
  81         $mime->header_set('Message-Id', '<a-mid@b>');
  82         $mime->body_set('this one needs a random mid');
  83         my $gen = content_digest($mime)->hexdigest . '@localhost';
  84         my $fake = PublicInbox::MIME->new($mime->as_string);
  85         $fake->header_set('Message-Id', $gen);
  86         ok($im->add($fake), 'fake added easily');
  87         is_deeply(\@warn, [], 'no warnings from a faker');
  88         ok($im->add($mime), 'random MID made');
  89         like(join(' ', @warn), qr/using random/, 'warned about using random');
  90         @mids = $mime->header_obj->header_raw('Message-Id');
  91         is($mids[1], '<a-mid@b>', 'original mid not changed');
  92         like($mids[0], qr/\A<\w+\@localhost>\z/, 'new MID added');
  93         is(scalar(@mids), 2, 'only one new MID added');
  94
  95         @warn = ();
  96         $mime->header_set('Message-Id');
  97         ok($im->add($mime), 'random MID made for MID free message');
  98         @mids = $mime->header_obj->header_raw('Message-Id');
  99         like($mids[0], qr/\A<\w+\@localhost>\z/, 'mid was generated');
 100         is(scalar(@mids), 1, 'new generated');
 101 }
 102
 103 {
 104         $mime->header_set('Message-Id', '<abcde@1>', '<abcde@2>');
 105         ok($im->add($mime), 'message with multiple Message-ID');
 106         $im->done;
 107         my @found;
 108         $ibx->search->each_smsg_by_mid('abcde@1', sub { push @found, @_; 1 });
 109         is(scalar(@found), 1, 'message found by first MID');
 110         $ibx->search->each_smsg_by_mid('abcde@2', sub { push @found, @_; 1 });
 111         is(scalar(@found), 2, 'message found by second MID');
 112         is($found[0]->{doc_id}, $found[1]->{doc_id}, 'same document');
 113         ok($found[1]->{doc_id} > 0, 'doc_id is positive');
 114 }
 115
 116 SKIP: {
 117         use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 118         use Net::NNTP;
 119         use IO::Socket;
 120         use Socket qw(SO_KEEPALIVE IPPROTO_TCP TCP_NODELAY);
 121         eval { require Danga::Socket };
 122         skip "Danga::Socket missing $@", 2 if $@;
 123         my $err = "$mainrepo/stderr.log";
 124         my $out = "$mainrepo/stdout.log";
 125         my %opts = (
 126                 LocalAddr => '127.0.0.1',
 127                 ReuseAddr => 1,
 128                 Proto => 'tcp',
 129                 Type => SOCK_STREAM,
 130                 Listen => 1024,
 131         );
 132         my $group = 'inbox.comp.test.v2writable';
 133         my $pi_config = "$mainrepo/pi_config";
 134         open my $fh, '>', $pi_config or die "open: $!\n";
 135         print $fh <<EOF
 136 [publicinbox "test-v2writable"]
 137         mainrepo = $mainrepo
 138         version = 2
 139         address = test\@example.com
 140         newsgroup = $group
 141 EOF
 142         ;
 143         close $fh or die "close: $!\n";
 144         my $sock = IO::Socket::INET->new(%opts);
 145         ok($sock, 'sock created');
 146         my $pid;
 147         my $len;
 148         END { kill 'TERM', $pid if defined $pid };
 149         $! = 0;
 150         my $fl = fcntl($sock, F_GETFD, 0);
 151         ok(! $!, 'no error from fcntl(F_GETFD)');
 152         is($fl, FD_CLOEXEC, 'cloexec set by default (Perl behavior)');
 153         $pid = fork;
 154         if ($pid == 0) {
 155                 use POSIX qw(dup2);
 156                 $ENV{PI_CONFIG} = $pi_config;
 157                 # pretend to be systemd
 158                 fcntl($sock, F_SETFD, $fl &= ~FD_CLOEXEC);
 159                 dup2(fileno($sock), 3) or die "dup2 failed: $!\n";
 160                 $ENV{LISTEN_PID} = $$;
 161                 $ENV{LISTEN_FDS} = 1;
 162                 my $nntpd = 'blib/script/public-inbox-nntpd';
 163                 exec $nntpd, "--stdout=$out", "--stderr=$err";
 164                 die "FAIL: $!\n";
 165         }
 166         ok(defined $pid, 'forked nntpd process successfully');
 167         $! = 0;
 168         fcntl($sock, F_SETFD, $fl |= FD_CLOEXEC);
 169         ok(! $!, 'no error from fcntl(F_SETFD)');
 170         my $host_port = $sock->sockhost . ':' . $sock->sockport;
 171         my $n = Net::NNTP->new($host_port);
 172         $n->group($group);
 173         my $x = $n->xover('1-');
 174         my %uniq;
 175         foreach my $num (sort { $a <=> $b } keys %$x) {
 176                 my $mid = $x->{$num}->[3];
 177                 is($uniq{$mid}++, 0, "MID for $num is unique in XOVER");
 178                 is_deeply($n->xhdr('Message-ID', $num),
 179                          { $num => $mid }, "XHDR lookup OK on num $num");
 180                 is_deeply($n->xhdr('Message-ID', $mid),
 181                          { $mid => $mid }, "XHDR lookup OK on MID $num");
 182         }
 183         my %nn;
 184         foreach my $mid (@{$n->newnews(0, $group)}) {
 185                 is($nn{$mid}++, 0, "MID is unique in NEWNEWS");
 186         }
 187         is_deeply([sort keys %nn], [sort keys %uniq]);
 188 };
 189 {
 190         local $ENV{NPROC} = 2;
 191         $im = PublicInbox::V2Writable->new($ibx, 1);
 192         is($im->{partitions}, 1, 'detected single partition from previous');
 193 }
 194
 195 done_testing();