t/v2writable.t

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::MIME;
   7 use PublicInbox::ContentId qw(content_digest);
   8 use File::Temp qw/tempdir/;
   9 foreach my $mod (qw(DBD::SQLite Search::Xapian)) {
  10         eval "require $mod";
  11         plan skip_all => "$mod missing for nntpd.t" if $@;
  12 }
  13 use_ok 'PublicInbox::V2Writable';
  14 my $mainrepo = tempdir('pi-v2writable-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  15 my $ibx = {
  16         mainrepo => $mainrepo,
  17         name => 'test-v2writable',
  18         version => 2,
  19         -primary_address => 'test@example.com',
  20 };
  21 $ibx = PublicInbox::Inbox->new($ibx);
  22 my $mime = PublicInbox::MIME->create(
  23         header => [
  24                 From => 'a@example.com',
  25                 To => 'test@example.com',
  26                 Subject => 'this is a subject',
  27                 'Message-ID' => '<a-mid@b>',
  28                 Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  29         ],
  30         body => "hello world\n",
  31 );
  32
  33 my $im = PublicInbox::V2Writable->new($ibx, 1);
  34 ok($im->add($mime), 'ordinary message added');
  35 {
  36         my @warn;
  37         local $SIG{__WARN__} = sub { push @warn, @_ };
  38         is(undef, $im->add($mime), 'obvious duplicate rejected');
  39         like(join(' ', @warn), qr/resent/, 'warned about resent message');
  40
  41         @warn = ();
  42         $mime->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  43         ok($im->add($mime), 'secondary MID used');
  44         like(join(' ', @warn), qr/mismatched/, 'warned about mismatch');
  45         like(join(' ', @warn), qr/alternative/, 'warned about alternative');
  46         is_deeply([ '<a-mid@b>', '<c@d>' ],
  47                 [ $mime->header_obj->header_raw('Message-Id') ],
  48                 'no new Message-Id added');
  49
  50         @warn = ();
  51         $mime->header_set('Message-Id', '<a-mid@b>');
  52         $mime->body_set('different');
  53         ok($im->add($mime), 'reused mid ok');
  54         like(join(' ', @warn), qr/reused/, 'warned about reused MID');
  55         my @mids = $mime->header_obj->header_raw('Message-Id');
  56         is($mids[1], '<a-mid@b>', 'original mid not changed');
  57         like($mids[0], qr/\A<\w+\@localhost>\z/, 'new MID added');
  58         is(scalar(@mids), 2, 'only one new MID added');
  59
  60         @warn = ();
  61         $mime->header_set('Message-Id', '<a-mid@b>');
  62         $mime->body_set('this one needs a random mid');
  63         my $gen = content_digest($mime)->hexdigest . '@localhost';
  64         my $fake = PublicInbox::MIME->new($mime->as_string);
  65         $fake->header_set('Message-Id', $gen);
  66         ok($im->add($fake), 'fake added easily');
  67         is_deeply(\@warn, [], 'no warnings from a faker');
  68         ok($im->add($mime), 'random MID made');
  69         like(join(' ', @warn), qr/using random/, 'warned about using random');
  70         @mids = $mime->header_obj->header_raw('Message-Id');
  71         is($mids[1], '<a-mid@b>', 'original mid not changed');
  72         like($mids[0], qr/\A<\w+\@localhost>\z/, 'new MID added');
  73         is(scalar(@mids), 2, 'only one new MID added');
  74
  75         @warn = ();
  76         $mime->header_set('Message-Id');
  77         ok($im->add($mime), 'random MID made for MID free message');
  78         @mids = $mime->header_obj->header_raw('Message-Id');
  79         like($mids[0], qr/\A<\w+\@localhost>\z/, 'mid was generated');
  80         is(scalar(@mids), 1, 'new generated');
  81 }
  82
  83 {
  84         $mime->header_set('Message-Id', '<abcde@1>', '<abcde@2>');
  85         ok($im->add($mime), 'message with multiple Message-ID');
  86         $im->done;
  87         my @found;
  88         $ibx->search->each_smsg_by_mid('abcde@1', sub { push @found, @_; 1 });
  89         is(scalar(@found), 1, 'message found by first MID');
  90         $ibx->search->each_smsg_by_mid('abcde@2', sub { push @found, @_; 1 });
  91         is(scalar(@found), 2, 'message found by second MID');
  92         is($found[0]->{doc_id}, $found[1]->{doc_id}, 'same document');
  93         ok($found[1]->{doc_id} > 0, 'doc_id is positive');
  94 }
  95
  96
  97 done_testing();