t/watch_maildir.t

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use Test::More;
   5 use PublicInbox::Eml;
   6 use Cwd;
   7 use PublicInbox::Config;
   8 use PublicInbox::TestCommon;
   9 use PublicInbox::Import;
  10 require_mods(qw(Filesys::Notify::Simple));
  11 my ($tmpdir, $for_destroy) = tmpdir();
  12 my $git_dir = "$tmpdir/test.git";
  13 my $maildir = "$tmpdir/md";
  14 my $spamdir = "$tmpdir/spam";
  15 use_ok 'PublicInbox::WatchMaildir';
  16 use_ok 'PublicInbox::Emergency';
  17 my $cfgpfx = "publicinbox.test";
  18 my $addr = 'test-public@example.com';
  19 PublicInbox::Import::init_bare($git_dir);
  20
  21 my $msg = <<EOF;
  22 From: user\@example.com
  23 To: $addr
  24 Subject: spam
  25 Message-Id: <a\@b.com>
  26 Date: Sat, 18 Jun 2016 00:00:00 +0000
  27
  28 something
  29 EOF
  30 PublicInbox::Emergency->new($maildir)->prepare(\$msg);
  31 ok(POSIX::mkfifo("$maildir/cur/fifo", 0777),
  32         'create FIFO to ensure we do not get stuck on it :P');
  33 my $sem = PublicInbox::Emergency->new($spamdir); # create dirs
  34
  35 {
  36         my @w;
  37         local $SIG{__WARN__} = sub { push @w, @_ };
  38         my $config = PublicInbox::Config->new(\<<EOF);
  39 $cfgpfx.address=$addr
  40 $cfgpfx.inboxdir=$git_dir
  41 $cfgpfx.watch=maildir:$spamdir
  42 publicinboxlearn.watchspam=maildir:$spamdir
  43 EOF
  44         my $wm = PublicInbox::WatchMaildir->new($config);
  45         is(scalar grep(/is a spam folder/, @w), 1, 'got warning about spam');
  46         is_deeply($wm->{mdmap}, { "$spamdir/cur" => 'watchspam' },
  47                 'only got the spam folder to watch');
  48 }
  49
  50 my $config = PublicInbox::Config->new(\<<EOF);
  51 $cfgpfx.address=$addr
  52 $cfgpfx.inboxdir=$git_dir
  53 $cfgpfx.watch=maildir:$maildir
  54 $cfgpfx.filter=PublicInbox::Filter::Vger
  55 publicinboxlearn.watchspam=maildir:$spamdir
  56 EOF
  57
  58 PublicInbox::WatchMaildir->new($config)->scan('full');
  59 my $git = PublicInbox::Git->new($git_dir);
  60 my @list = $git->qx(qw(rev-list refs/heads/master));
  61 is(scalar @list, 1, 'one revision in rev-list');
  62
  63 my $write_spam = sub {
  64         is(scalar glob("$spamdir/new/*"), undef, 'no spam existing');
  65         $sem->prepare(\$msg);
  66         $sem->commit;
  67         my @new = glob("$spamdir/new/*");
  68         is(scalar @new, 1);
  69         my @p = split(m!/+!, $new[0]);
  70         ok(link($new[0], "$spamdir/cur/".$p[-1].":2,S"));
  71         is(unlink($new[0]), 1);
  72 };
  73 $write_spam->();
  74 is(unlink(glob("$maildir/new/*")), 1, 'unlinked old spam');
  75 PublicInbox::WatchMaildir->new($config)->scan('full');
  76 @list = $git->qx(qw(rev-list refs/heads/master));
  77 is(scalar @list, 2, 'two revisions in rev-list');
  78 @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  79 is(scalar @list, 0, 'tree is empty');
  80
  81 # check with scrubbing
  82 {
  83         $msg .= qq(--
  84 To unsubscribe from this list: send the line "unsubscribe git" in
  85 the body of a message to majordomo\@vger.kernel.org
  86 More majordomo info at  http://vger.kernel.org/majordomo-info.html\n);
  87         PublicInbox::Emergency->new($maildir)->prepare(\$msg);
  88         PublicInbox::WatchMaildir->new($config)->scan('full');
  89         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  90         is(scalar @list, 1, 'tree has one file');
  91         my $mref = $git->cat_file('HEAD:'.$list[0]);
  92         like($$mref, qr/something\n\z/s, 'message scrubbed on import');
  93
  94         is(unlink(glob("$maildir/new/*")), 1, 'unlinked spam');
  95         $write_spam->();
  96         PublicInbox::WatchMaildir->new($config)->scan('full');
  97         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  98         is(scalar @list, 0, 'tree is empty');
  99         @list = $git->qx(qw(rev-list refs/heads/master));
 100         is(scalar @list, 4, 'four revisions in rev-list');
 101 }
 102
 103 {
 104         my $fail_bin = getcwd()."/t/fail-bin";
 105         ok(-x "$fail_bin/spamc", "mock spamc exists");
 106         my $fail_path = "$fail_bin:$ENV{PATH}"; # for spamc ham mock
 107         local $ENV{PATH} = $fail_path;
 108         PublicInbox::Emergency->new($maildir)->prepare(\$msg);
 109         $config->{'publicinboxwatch.spamcheck'} = 'spamc';
 110         {
 111                 local $SIG{__WARN__} = sub {}; # quiet spam check warning
 112                 PublicInbox::WatchMaildir->new($config)->scan('full');
 113         }
 114         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
 115         is(scalar @list, 0, 'tree has no files spamc checked');
 116         is(unlink(glob("$maildir/new/*")), 1);
 117 }
 118
 119 {
 120         my $main_bin = getcwd()."/t/main-bin";
 121         ok(-x "$main_bin/spamc", "mock spamc exists");
 122         my $main_path = "$main_bin:$ENV{PATH}"; # for spamc ham mock
 123         local $ENV{PATH} = $main_path;
 124         PublicInbox::Emergency->new($maildir)->prepare(\$msg);
 125         $config->{'publicinboxwatch.spamcheck'} = 'spamc';
 126         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
 127         PublicInbox::WatchMaildir->new($config)->scan('full');
 128         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
 129         is(scalar @list, 1, 'tree has one file after spamc checked');
 130
 131         # XXX: workaround some weird caching/memoization in cat-file,
 132         # shouldn't be an issue in real-world use, though...
 133         $git = PublicInbox::Git->new($git_dir);
 134
 135         my $mref = $git->cat_file('refs/heads/master:'.$list[0]);
 136         like($$mref, qr/something\n\z/s, 'message scrubbed on import');
 137 }
 138
 139 sub is_maildir {
 140         my ($dir) = @_;
 141         PublicInbox::WatchMaildir::is_maildir($dir);
 142 }
 143
 144 is(is_maildir('maildir:/hello//world'), '/hello/world', 'extra slash gone');
 145 is(is_maildir('maildir:/hello/world/'), '/hello/world', 'trailing slash gone');
 146 is(is_maildir('faildir:/hello/world/'), undef, 'non-maildir rejected');
 147
 148 done_testing;