t/watch_maildir.t

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use Test::More;
   4 use File::Temp qw/tempdir/;
   5 use Email::MIME;
   6 use PublicInbox::Config;
   7 my @mods = qw(Filesys::Notify::Simple);
   8 foreach my $mod (@mods) {
   9         eval "require $mod";
  10         plan skip_all => "$mod missing for watch_maildir.t" if $@;
  11 }
  12
  13 my $tmpdir = tempdir('watch_maildir-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  14 my $git_dir = "$tmpdir/test.git";
  15 my $maildir = "$tmpdir/md";
  16 my $spamdir = "$tmpdir/spam";
  17 use_ok 'PublicInbox::WatchMaildir';
  18 use_ok 'PublicInbox::Emergency';
  19 my $cfgpfx = "publicinbox.test";
  20 my $addr = 'test-public@example.com';
  21 is(system(qw(git init -q --bare), $git_dir), 0, 'initialized git dir');
  22
  23 my $msg = <<EOF;
  24 From: user\@example.com
  25 To: $addr
  26 Subject: spam
  27 Message-Id: <a\@b.com>
  28 Date: Sat, 18 Jun 2016 00:00:00 +0000
  29
  30 something
  31 EOF
  32 PublicInbox::Emergency->new($maildir)->prepare(\$msg);
  33 ok(POSIX::mkfifo("$maildir/cur/fifo", 0777));
  34 my $sem = PublicInbox::Emergency->new($spamdir); # create dirs
  35
  36 my $config = PublicInbox::Config->new({
  37         "$cfgpfx.address" => $addr,
  38         "$cfgpfx.mainrepo" => $git_dir,
  39         "$cfgpfx.watch" => "maildir:$maildir",
  40         "$cfgpfx.filter" => 'PublicInbox::Filter::Vger',
  41         "publicinboxlearn.watchspam" => "maildir:$spamdir",
  42 });
  43
  44 PublicInbox::WatchMaildir->new($config)->scan;
  45 my $git = PublicInbox::Git->new($git_dir);
  46 my @list = $git->qx(qw(rev-list refs/heads/master));
  47 is(scalar @list, 1, 'one revision in rev-list');
  48
  49 my $write_spam = sub {
  50         is(scalar glob("$spamdir/new/*"), undef, 'no spam existing');
  51         $sem->prepare(\$msg);
  52         $sem->commit;
  53         my @new = glob("$spamdir/new/*");
  54         is(scalar @new, 1);
  55         my @p = split(m!/+!, $new[0]);
  56         ok(link($new[0], "$spamdir/cur/".$p[-1].":2,S"));
  57         is(unlink($new[0]), 1);
  58 };
  59 $write_spam->();
  60 is(unlink(glob("$maildir/new/*")), 1, 'unlinked old spam');
  61 PublicInbox::WatchMaildir->new($config)->scan;
  62 @list = $git->qx(qw(rev-list refs/heads/master));
  63 is(scalar @list, 2, 'two revisions in rev-list');
  64 @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  65 is(scalar @list, 0, 'tree is empty');
  66
  67 # check with scrubbing
  68 {
  69         $msg .= qq(--
  70 To unsubscribe from this list: send the line "unsubscribe git" in
  71 the body of a message to majordomo\@vger.kernel.org
  72 More majordomo info at  http://vger.kernel.org/majordomo-info.html\n);
  73         PublicInbox::Emergency->new($maildir)->prepare(\$msg);
  74         PublicInbox::WatchMaildir->new($config)->scan;
  75         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  76         is(scalar @list, 1, 'tree has one file');
  77         my $mref = $git->cat_file('HEAD:'.$list[0]);
  78         like($$mref, qr/something\n\z/s, 'message scrubbed on import');
  79
  80         is(unlink(glob("$maildir/new/*")), 1, 'unlinked spam');
  81         $write_spam->();
  82         PublicInbox::WatchMaildir->new($config)->scan;
  83         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  84         is(scalar @list, 0, 'tree is empty');
  85         @list = $git->qx(qw(rev-list refs/heads/master));
  86         is(scalar @list, 4, 'four revisions in rev-list');
  87 }
  88
  89 done_testing;