t/watch_maildir.t

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use Test::More;
   4 use File::Temp qw/tempdir/;
   5 use Email::MIME;
   6 use PublicInbox::Config;
   7
   8 my $tmpdir = tempdir('watch_maildir-XXXXXX', TMPDIR => 1, CLEANUP => 1);
   9 my $git_dir = "$tmpdir/test.git";
  10 my $maildir = "$tmpdir/md";
  11 my $spamdir = "$tmpdir/spam";
  12 use_ok 'PublicInbox::WatchMaildir';
  13 use_ok 'PublicInbox::Emergency';
  14 my $cfgpfx = "publicinbox.test";
  15 my $addr = 'test-public@example.com';
  16 is(system(qw(git init -q --bare), $git_dir), 0, 'initialized git dir');
  17
  18 my $msg = <<EOF;
  19 From: user\@example.com
  20 To: $addr
  21 Subject: spam
  22 Message-Id: <a\@b.com>
  23 Date: Sat, 18 Jun 2016 00:00:00 +0000
  24
  25 something
  26 EOF
  27 PublicInbox::Emergency->new($maildir)->prepare(\$msg);
  28 ok(POSIX::mkfifo("$maildir/cur/fifo", 0777));
  29 my $sem = PublicInbox::Emergency->new($spamdir); # create dirs
  30
  31 my $config = PublicInbox::Config->new({
  32         "$cfgpfx.address" => $addr,
  33         "$cfgpfx.mainrepo" => $git_dir,
  34         "$cfgpfx.watch" => "maildir:$maildir",
  35         "$cfgpfx.filter" => 'PublicInbox::Filter::Vger',
  36         "publicinboxlearn.watchspam" => "maildir:$spamdir",
  37 });
  38
  39 PublicInbox::WatchMaildir->new($config)->scan;
  40 my $git = PublicInbox::Git->new($git_dir);
  41 my @list = $git->qx(qw(rev-list refs/heads/master));
  42 is(scalar @list, 1, 'one revision in rev-list');
  43
  44 my $write_spam = sub {
  45         is(scalar glob("$spamdir/new/*"), undef, 'no spam existing');
  46         $sem->prepare(\$msg);
  47         $sem->commit;
  48         my @new = glob("$spamdir/new/*");
  49         is(scalar @new, 1);
  50         my @p = split(m!/+!, $new[0]);
  51         ok(link($new[0], "$spamdir/cur/".$p[-1].":2,S"));
  52         is(unlink($new[0]), 1);
  53 };
  54 $write_spam->();
  55 is(unlink(glob("$maildir/new/*")), 1, 'unlinked old spam');
  56 PublicInbox::WatchMaildir->new($config)->scan;
  57 @list = $git->qx(qw(rev-list refs/heads/master));
  58 is(scalar @list, 2, 'two revisions in rev-list');
  59 @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  60 is(scalar @list, 0, 'tree is empty');
  61
  62 # check with scrubbing
  63 {
  64         $msg .= qq(--
  65 To unsubscribe from this list: send the line "unsubscribe git" in
  66 the body of a message to majordomo\@vger.kernel.org
  67 More majordomo info at  http://vger.kernel.org/majordomo-info.html\n);
  68         PublicInbox::Emergency->new($maildir)->prepare(\$msg);
  69         PublicInbox::WatchMaildir->new($config)->scan;
  70         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  71         is(scalar @list, 1, 'tree has one file');
  72         my $mref = $git->cat_file('HEAD:'.$list[0]);
  73         like($$mref, qr/something\n\z/s, 'message scrubbed on import');
  74
  75         is(unlink(glob("$maildir/new/*")), 1, 'unlinked spam');
  76         $write_spam->();
  77         PublicInbox::WatchMaildir->new($config)->scan;
  78         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  79         is(scalar @list, 0, 'tree is empty');
  80         @list = $git->qx(qw(rev-list refs/heads/master));
  81         is(scalar @list, 4, 'four revisions in rev-list');
  82 }
  83
  84 done_testing;