t/watch_maildir.t

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use Test::More;
   4 use File::Temp qw/tempdir/;
   5 use Email::MIME;
   6 use PublicInbox::Config;
   7
   8 my $tmpdir = tempdir('watch_maildir-XXXXXX', TMPDIR => 1, CLEANUP => 1);
   9 my $git_dir = "$tmpdir/test.git";
  10 my $maildir = "$tmpdir/md";
  11 my $spamdir = "$tmpdir/spam";
  12 use_ok 'PublicInbox::WatchMaildir';
  13 use_ok 'PublicInbox::Emergency';
  14 my $cfgpfx = "publicinbox.test";
  15 my $addr = 'test-public@example.com';
  16 is(system(qw(git init -q --bare), $git_dir), 0, 'initialized git dir');
  17
  18 my $msg = <<EOF;
  19 From: user\@example.com
  20 To: $addr
  21 Subject: spam
  22 Message-Id: <a\@b.com>
  23 Date: Sat, 18 Jun 2016 00:00:00 +0000
  24
  25 something
  26 EOF
  27 PublicInbox::Emergency->new($maildir)->prepare(\$msg);
  28 my $sem = PublicInbox::Emergency->new($spamdir); # create dirs
  29
  30 my $config = PublicInbox::Config->new({
  31         "$cfgpfx.address" => $addr,
  32         "$cfgpfx.mainrepo" => $git_dir,
  33         "$cfgpfx.watch" => "maildir:$maildir",
  34         "$cfgpfx.filter" => 'PublicInbox::Filter::Vger',
  35         "publicinboxlearn.watchspam" => "maildir:$spamdir",
  36 });
  37
  38 PublicInbox::WatchMaildir->new($config)->scan;
  39 my $git = PublicInbox::Git->new($git_dir);
  40 my @list = $git->qx(qw(rev-list refs/heads/master));
  41 is(scalar @list, 1, 'one revision in rev-list');
  42
  43 my $write_spam = sub {
  44         is(scalar glob("$spamdir/new/*"), undef, 'no spam existing');
  45         $sem->prepare(\$msg);
  46         $sem->commit;
  47         my @new = glob("$spamdir/new/*");
  48         is(scalar @new, 1);
  49         my @p = split(m!/+!, $new[0]);
  50         ok(link($new[0], "$spamdir/cur/".$p[-1]));
  51         is(unlink($new[0]), 1);
  52 };
  53 $write_spam->();
  54 is(unlink(glob("$maildir/new/*")), 1, 'unlinked old spam');
  55 PublicInbox::WatchMaildir->new($config)->scan;
  56 @list = $git->qx(qw(rev-list refs/heads/master));
  57 is(scalar @list, 2, 'two revisions in rev-list');
  58 @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  59 is(scalar @list, 0, 'tree is empty');
  60
  61 # check with scrubbing
  62 {
  63         $msg .= qq(--
  64 To unsubscribe from this list: send the line "unsubscribe git" in
  65 the body of a message to majordomo\@vger.kernel.org
  66 More majordomo info at  http://vger.kernel.org/majordomo-info.html\n);
  67         PublicInbox::Emergency->new($maildir)->prepare(\$msg);
  68         PublicInbox::WatchMaildir->new($config)->scan;
  69         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  70         is(scalar @list, 1, 'tree has one file');
  71         my $mref = $git->cat_file('HEAD:'.$list[0]);
  72         like($$mref, qr/something\n\z/s, 'message scrubbed on import');
  73
  74         is(unlink(glob("$maildir/new/*")), 1, 'unlinked spam');
  75         $write_spam->();
  76         PublicInbox::WatchMaildir->new($config)->scan;
  77         @list = $git->qx(qw(ls-tree -r --name-only refs/heads/master));
  78         is(scalar @list, 0, 'tree is empty');
  79         @list = $git->qx(qw(rev-list refs/heads/master));
  80         is(scalar @list, 4, 'four revisions in rev-list');
  81 }
  82
  83 done_testing;