t/www_altid.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use PublicInbox::Config;
   6 use PublicInbox::Spawn qw(spawn);
   7 require_cmd('sqlite3');
   8 require_mods(qw(DBD::SQLite HTTP::Request::Common Plack::Test URI::Escape
   9         Plack::Builder IO::Uncompress::Gunzip));
  10 use_ok($_) for qw(Plack::Test HTTP::Request::Common);
  11 require_ok 'PublicInbox::Msgmap';
  12 require_ok 'PublicInbox::AltId';
  13 require_ok 'PublicInbox::WWW';
  14 my ($tmpdir, $for_destroy) = tmpdir();
  15 my $aid = 'xyz';
  16 my $cfgpath;
  17 my $ibx = create_inbox 'test', indexlevel => 'basic', sub {
  18         my ($im, $ibx) = @_;
  19         $im->add(PublicInbox::Eml->new(<<'EOF')) or BAIL_OUT;
  20 From: a@example.com
  21 Message-Id: <a@example.com>
  22
  23 EOF
  24         # $im->done;
  25         my $spec = "serial:$aid:file=blah.sqlite3";
  26         my $altid = PublicInbox::AltId->new($ibx, $spec, 1);
  27         $altid->mm_alt->mid_set(1, 'a@example.com');
  28         $cfgpath = "$ibx->{inboxdir}/cfg";
  29         open my $fh, '>', $cfgpath or BAIL_OUT "open $cfgpath: $!";
  30         print $fh <<EOF or BAIL_OUT $!;
  31 [publicinbox "test"]
  32         inboxdir = $ibx->{inboxdir}
  33         address = $ibx->{-primary_address}
  34         altid = $spec
  35         url = http://example.com/test
  36 EOF
  37         close $fh or BAIL_OUT $!;
  38 };
  39 $cfgpath //= "$ibx->{inboxdir}/cfg";
  40 my $cfg = PublicInbox::Config->new($cfgpath);
  41 my $www = PublicInbox::WWW->new($cfg);
  42 my $cmpfile = "$tmpdir/cmp.sqlite3";
  43 my $client = sub {
  44         my ($cb) = @_;
  45         my $res = $cb->(POST("/test/$aid.sql.gz"));
  46         is($res->code, 200, 'retrieved gzipped dump');
  47         IO::Uncompress::Gunzip::gunzip(\($res->content) => \(my $buf));
  48         pipe(my ($r, $w)) or die;
  49         my $cmd = ['sqlite3', $cmpfile];
  50         my $pid = spawn($cmd, undef, { 0 => $r });
  51         print $w $buf or die;
  52         close $w or die;
  53         is(waitpid($pid, 0), $pid, 'sqlite3 exited');
  54         is($?, 0, 'sqlite3 loaded dump');
  55         my $mm_cmp = PublicInbox::Msgmap->new_file($cmpfile);
  56         is($mm_cmp->mid_for(1), 'a@example.com', 'sqlite3 dump valid');
  57         $mm_cmp = undef;
  58         unlink $cmpfile or die;
  59 };
  60 test_psgi(sub { $www->call(@_) }, $client);
  61 SKIP: {
  62         require_mods(qw(Plack::Test::ExternalServer), 4);
  63         my $env = { PI_CONFIG => $cfgpath };
  64         my $sock = tcp_server() or die;
  65         my ($out, $err) = map { "$tmpdir/std$_.log" } qw(out err);
  66         my $cmd = [ qw(-httpd -W0), "--stdout=$out", "--stderr=$err" ];
  67         my $td = start_script($cmd, $env, { 3 => $sock });
  68         my ($h, $p) = tcp_host_port($sock);
  69         local $ENV{PLACK_TEST_EXTERNALSERVER_URI} = "http://$h:$p";
  70         Plack::Test::ExternalServer::test_psgi(client => $client);
  71 }
  72 done_testing;