t/www_listing.t

   1 #!perl -w
   2 # Copyright (C) all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # manifest.js.gz generation and grok-pull integration test
   5 use strict; use v5.10.1; use PublicInbox::TestCommon;
   6 use PublicInbox::Import;
   7 use IO::Uncompress::Gunzip qw(gunzip);
   8 require_mods(qw(json URI::Escape Plack::Builder HTTP::Tiny));
   9 require PublicInbox::WwwListing;
  10 require PublicInbox::ManifestJsGz;
  11 use PublicInbox::Config;
  12 my $json = PublicInbox::Config::json();
  13
  14 use_ok 'PublicInbox::Git';
  15
  16 my ($tmpdir, $for_destroy) = tmpdir();
  17 my $bare = PublicInbox::Git->new("$tmpdir/bare.git");
  18 PublicInbox::Import::init_bare($bare->{git_dir});
  19 is($bare->manifest_entry, undef, 'empty repo has no manifest entry');
  20 {
  21         my $fi_data = './t/git.fast-import-data';
  22         open my $fh, '<', $fi_data or die "open $fi_data: $!";
  23         my $env = { GIT_DIR => $bare->{git_dir} };
  24         is(xsys([qw(git fast-import --quiet)], $env, { 0 => $fh }), 0,
  25                 'fast-import');
  26 }
  27
  28 like($bare->manifest_entry->{fingerprint}, qr/\A[a-f0-9]{40}\z/,
  29         'got fingerprint with non-empty repo');
  30
  31 sub tiny_test {
  32         my ($json, $host, $port, $html) = @_;
  33         my ($tmp, $res);
  34         my $http = HTTP::Tiny->new;
  35         if ($html) {
  36                 $res = $http->get("http://$host:$port/");
  37                 is($res->{status}, 200, 'got HTML listing');
  38                 like($res->{content}, qr!</html>!si, 'listing looks like HTML');
  39
  40                 $res = $http->get("http://$host:$port/",
  41                                 {'Accept-Encoding'=>'gzip'});
  42                 is($res->{status}, 200, 'got gzipped HTML listing');
  43                 gunzip(\(delete $res->{content}) => \$tmp);
  44                 like($tmp, qr!</html>!si, 'unzipped listing looks like HTML');
  45         }
  46         $res = $http->get("http://$host:$port/manifest.js.gz");
  47         is($res->{status}, 200, 'got manifest');
  48         gunzip(\(delete $res->{content}) => \$tmp);
  49         unlike($tmp, qr/"modified":\s*"/, 'modified is an integer');
  50         my $manifest = $json->decode($tmp);
  51         ok(my $clone = $manifest->{'/alt'}, '/alt in manifest');
  52         is($clone->{owner}, "lorelei \x{100}", 'owner set');
  53         is($clone->{reference}, '/bare', 'reference detected');
  54         is($clone->{description}, "we're \x{100}ll clones", 'description read');
  55         ok(my $bare = $manifest->{'/bare'}, '/bare in manifest');
  56         is($bare->{description}, 'Unnamed repository',
  57                 'missing $GIT_DIR/description fallback');
  58
  59         like($bare->{fingerprint}, qr/\A[a-f0-9]{40}\z/, 'fingerprint');
  60         is($clone->{fingerprint}, $bare->{fingerprint}, 'fingerprint matches');
  61         is(HTTP::Date::time2str($bare->{modified}),
  62                 $res->{headers}->{'last-modified'},
  63                 'modified field and Last-Modified header match');
  64
  65         ok(my $v2epoch0 = $manifest->{'/v2/git/0.git'}, 'v2 epoch 0 appeared');
  66         like($v2epoch0->{description}, qr/ \[epoch 0\]\z/,
  67                 'epoch 0 in description');
  68         ok(my $v2epoch1 = $manifest->{'/v2/git/1.git'}, 'v2 epoch 1 appeared');
  69         like($v2epoch1->{description}, qr/ \[epoch 1\]\z/,
  70                 'epoch 1 in description');
  71
  72         $res = $http->get("http://$host:$port/alt/description");
  73         is($res->{content}, "we're \xc4\x80ll clones\n", 'UTF-8 description')
  74                 or diag explain($res);
  75 }
  76
  77 my $td;
  78 SKIP: {
  79         my $err = "$tmpdir/stderr.log";
  80         my $out = "$tmpdir/stdout.log";
  81         my $alt = "$tmpdir/alt.git";
  82         my $cfgfile = "$tmpdir/config";
  83         my $v2 = "$tmpdir/v2";
  84         my $sock = tcp_server();
  85         my ($host, $port) = tcp_host_port($sock);
  86         my @clone = qw(git clone -q -s --bare);
  87         is(xsys(@clone, $bare->{git_dir}, $alt), 0, 'clone shared repo');
  88
  89         PublicInbox::Import::init_bare("$v2/all.git");
  90         for my $i (0..2) {
  91                 is(xsys(@clone, $alt, "$v2/git/$i.git"), 0, "clone epoch $i")
  92         }
  93         ok(open(my $fh, '>', "$v2/inbox.lock"), 'mock a v2 inbox');
  94         open($fh, '>', "$v2/description") or xbail "open $v2/description: $!";
  95         print $fh "a v2 inbox\n" or xbail "print $!";
  96         close $fh or xbail "write: $v2/description $!";
  97
  98         open $fh, '>', "$alt/description" or xbail "open $alt/description $!";
  99         print $fh "we're \xc4\x80ll clones\n" or xbail "print $!";
 100         close $fh or xbail "write: $alt/description $!";
 101         is(xsys('git', "--git-dir=$alt", qw(config gitweb.owner),
 102                 "lorelei \xc4\x80"), 0,
 103                 'set gitweb user');
 104         open $fh, '>', $cfgfile or xbail "open $cfgfile: $!";
 105         $fh->autoflush(1);
 106         print $fh <<"" or xbail "print $!";
 107 [publicinbox "bare"]
 108         inboxdir = $bare->{git_dir}
 109         url = http://$host/bare
 110         address = bare\@example.com
 111 [publicinbox "alt"]
 112         inboxdir = $alt
 113         url = http://$host/alt
 114         address = alt\@example.com
 115 [publicinbox "v2"]
 116         inboxdir = $v2
 117         url = http://$host/v2
 118         address = v2\@example.com
 119
 120         my $env = { PI_CONFIG => $cfgfile };
 121         my $cmd = [ '-httpd', '-W0', "--stdout=$out", "--stderr=$err" ];
 122         my $psgi = "$tmpdir/pfx.psgi";
 123         {
 124                 open my $psgi_fh, '>', $psgi or xbail "open: $!";
 125                 print $psgi_fh <<'EOM' or xbail "print $!";
 126 use PublicInbox::WWW;
 127 use Plack::Builder;
 128 my $www = PublicInbox::WWW->new;
 129 builder {
 130         enable 'Head';
 131         mount '/pfx/' => sub { $www->call(@_) }
 132 }
 133 EOM
 134                 close $psgi_fh or xbail "close: $!";
 135         }
 136
 137         # ensure prefixed mount full clones work:
 138         $td = start_script([@$cmd, $psgi], $env, { 3 => $sock });
 139         my $opt = { 2 => \(my $clone_err = '') };
 140         ok(run_script(['-clone', "http://$host:$port/pfx", "$tmpdir/pfx" ],
 141                 undef, $opt), 'pfx clone w/pfx') or diag "clone_err=$clone_err";
 142
 143         open my $mh, '<', "$tmpdir/pfx/manifest.js.gz" or xbail "open: $!";
 144         gunzip(\(do { local $/; <$mh> }) => \(my $mjs = ''));
 145         my $mf = $json->decode($mjs);
 146         is_deeply([sort keys %$mf], [ qw(/alt /bare /v2/git/0.git
 147                                         /v2/git/1.git /v2/git/2.git) ],
 148                 'manifest saved');
 149         for (keys %$mf) { ok(-d "$tmpdir/pfx$_", "pfx/$_ cloned") }
 150         open my $desc, '<', "$tmpdir/pfx/v2/description" or xbail "open: $!";
 151         $desc = <$desc>;
 152         is($desc, "a v2 inbox\n", 'v2 description retrieved');
 153
 154         $clone_err = '';
 155         ok(run_script(['-clone', '--include=*/alt',
 156                         "http://$host:$port/pfx", "$tmpdir/incl" ],
 157                 undef, $opt), 'clone w/include') or diag "clone_err=$clone_err";
 158         ok(-d "$tmpdir/incl/alt", 'alt cloned');
 159         ok(!-d "$tmpdir/incl/v2" && !-d "$tmpdir/incl/bare", 'only alt cloned');
 160         is(xqx([qw(git config -f), "$tmpdir/incl/alt/config", 'gitweb.owner']),
 161                 "lorelei \xc4\x80\n", 'gitweb.owner set by -clone');
 162
 163         $clone_err = '';
 164         ok(run_script(['-clone', '--dry-run',
 165                         "http://$host:$port/pfx", "$tmpdir/dry-run" ],
 166                 undef, $opt), 'clone --dry-run') or diag "clone_err=$clone_err";
 167         ok(!-d "$tmpdir/dry-run", 'nothing cloned with --dry-run');
 168
 169         undef $td;
 170
 171         open $mh, '<', "$tmpdir/incl/manifest.js.gz" or xbail "open: $!";
 172         gunzip(\(do { local $/; <$mh> }) => \($mjs = ''));
 173         $mf = $json->decode($mjs);
 174         is_deeply([keys %$mf], [ '/alt' ], 'excluded keys skipped in manifest');
 175
 176         $td = start_script($cmd, $env, { 3 => $sock });
 177
 178         # default publicinboxGrokManifest match=domain default
 179         tiny_test($json, $host, $port);
 180
 181         # normal full clone on /
 182         $clone_err = '';
 183         ok(run_script(['-clone', "http://$host:$port/", "$tmpdir/full" ],
 184                 undef, $opt), 'full clone') or diag "clone_err=$clone_err";
 185         ok(-d "$tmpdir/full/$_", "$_ cloned") for qw(alt v2 bare);
 186
 187         undef $td;
 188
 189         print $fh <<"" or xbail "print $!";
 190 [publicinbox]
 191         wwwlisting = all
 192
 193         close $fh or xbail "close $!";
 194         $td = start_script($cmd, $env, { 3 => $sock });
 195         undef $sock;
 196         tiny_test($json, $host, $port, 1);
 197
 198         # grok-pull sleeps a long while some places:
 199         # https://lore.kernel.org/tools/20211013110344.GA10632@dcvr/
 200         skip 'TEST_GROK unset', 12 unless $ENV{TEST_GROK};
 201         my $grok_pull = require_cmd('grok-pull', 1) or
 202                 skip('grok-pull not available', 12);
 203         my ($grok_version) = (xqx([$grok_pull, "--version"])
 204                         =~ /(\d+)\.(?:\d+)(?:\.(\d+))?/);
 205         $grok_version >= 2 or
 206                 skip('grok-pull v2 or later not available', 12);
 207         my $grok_loglevel = $ENV{TEST_GROK_LOGLEVEL} // 'info';
 208
 209         ok(mkdir("$tmpdir/mirror"), 'prepare grok mirror dest');
 210         my $tail = tail_f("$tmpdir/grok.log");
 211         open $fh, '>', "$tmpdir/repos.conf" or xbail $!;
 212         print $fh <<"" or xbail $!;
 213 [core]
 214 toplevel = $tmpdir/mirror
 215 manifest = $tmpdir/local-manifest.js.gz
 216 log = $tmpdir/grok.log
 217 loglevel = $grok_loglevel
 218 [remote]
 219 site = http://$host:$port
 220 manifest = \${site}/manifest.js.gz
 221 [pull]
 222 [fsck]
 223
 224         close $fh or xbail $!;
 225         xsys($grok_pull, '-c', "$tmpdir/repos.conf");
 226         is($? >> 8, 0, 'grok-pull exit code as expected');
 227         for (qw(alt bare v2/git/0.git v2/git/1.git v2/git/2.git)) {
 228                 ok(-d "$tmpdir/mirror/$_", "grok-pull created $_");
 229         }
 230
 231         # support per-inbox manifests, handy for v2:
 232         # /$INBOX/v2/manifest.js.gz
 233         open $fh, '>', "$tmpdir/per-inbox.conf" or xbail $!;
 234         print $fh <<"" or xbail $!;
 235 [core]
 236 toplevel = $tmpdir/per-inbox
 237 manifest = $tmpdir/per-inbox-manifest.js.gz
 238 log = $tmpdir/grok.log
 239 loglevel = $grok_loglevel
 240 [remote]
 241 site = http://$host:$port
 242 manifest = \${site}/v2/manifest.js.gz
 243 [pull]
 244 [fsck]
 245
 246         close $fh or xbail $!;
 247         ok(mkdir("$tmpdir/per-inbox"), 'prepare single-v2-inbox mirror');
 248         xsys($grok_pull, '-c', "$tmpdir/per-inbox.conf");
 249         is($? >> 8, 0, 'grok-pull exit code as expected');
 250         for (qw(v2/git/0.git v2/git/1.git v2/git/2.git)) {
 251                 ok(-d "$tmpdir/per-inbox/$_", "grok-pull created $_");
 252         }
 253         $td->kill;
 254         $td->join;
 255         is($?, 0, 'no error in exited process');
 256         open $fh, '<', $err or BAIL_OUT("open $err failed: $!");
 257         my $eout = do { local $/; <$fh> };
 258         unlike($eout, qr/wide/i, 'no Wide character warnings');
 259         unlike($eout, qr/uninitialized/i, 'no uninitialized warnings');
 260 }
 261
 262 done_testing();