t/www_listing.t

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # manifest.js.gz generation and grok-pull integration test
   4 use strict;
   5 use warnings;
   6 use Test::More;
   7 use PublicInbox::Spawn qw(which);
   8 use File::Temp qw/tempdir/;
   9 require './t/common.perl';
  10 my @mods = qw(URI::Escape Plack::Builder IPC::Run Digest::SHA
  11                 IO::Compress::Gzip IO::Uncompress::Gunzip HTTP::Tiny);
  12 foreach my $mod (@mods) {
  13         eval("require $mod") or plan skip_all => "$mod missing for $0";
  14 }
  15
  16 require PublicInbox::WwwListing;
  17 my $json = eval { PublicInbox::WwwListing::_json() };
  18 plan skip_all => "JSON module missing: $@" if $@;
  19
  20 use_ok 'PublicInbox::Git';
  21
  22 my $fi_data = './t/git.fast-import-data';
  23 my $tmpdir = tempdir('www_listing-tmp-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  24 my $bare = PublicInbox::Git->new("$tmpdir/bare.git");
  25 is(system(qw(git init -q --bare), $bare->{git_dir}), 0, 'git init --bare');
  26 is(PublicInbox::WwwListing::fingerprint($bare), undef,
  27         'empty repo has no fingerprint');
  28
  29 my $cmd = [ 'git', "--git-dir=$bare->{git_dir}", qw(fast-import --quiet) ];
  30 ok(IPC::Run::run($cmd, '<', $fi_data), 'fast-import');
  31
  32 like(PublicInbox::WwwListing::fingerprint($bare), qr/\A[a-f0-9]{40}\z/,
  33         'got fingerprint with non-empty repo');
  34
  35 sub tiny_test {
  36         my ($host, $port) = @_;
  37         my $http = HTTP::Tiny->new;
  38         my $res = $http->get("http://$host:$port/manifest.js.gz");
  39         is($res->{status}, 200, 'got manifest');
  40         my $tmp;
  41         IO::Uncompress::Gunzip::gunzip(\(delete $res->{content}) => \$tmp);
  42         unlike($tmp, qr/"modified":\s*"/, 'modified is an integer');
  43         my $manifest = $json->decode($tmp);
  44         ok(my $clone = $manifest->{'/alt'}, '/alt in manifest');
  45         is($clone->{owner}, 'lorelei', 'owner set');
  46         is($clone->{reference}, '/bare', 'reference detected');
  47         is($clone->{description}, "we're all clones", 'description read');
  48         ok(my $bare = $manifest->{'/bare'}, '/bare in manifest');
  49         is($bare->{description}, 'Unnamed repository',
  50                 'missing $GIT_DIR/description fallback');
  51
  52         like($bare->{fingerprint}, qr/\A[a-f0-9]{40}\z/, 'fingerprint');
  53         is($clone->{fingerprint}, $bare->{fingerprint}, 'fingerprint matches');
  54         is(HTTP::Date::time2str($bare->{modified}),
  55                 $res->{headers}->{'last-modified'},
  56                 'modified field and Last-Modified header match');
  57
  58         ok(my $v2epoch0 = $manifest->{'/v2/git/0.git'}, 'v2 epoch 0 appeared');
  59         like($v2epoch0->{description}, qr/ \[epoch 0\]\z/,
  60                 'epoch 0 in description');
  61         ok(my $v2epoch1 = $manifest->{'/v2/git/1.git'}, 'v2 epoch 1 appeared');
  62         like($v2epoch1->{description}, qr/ \[epoch 1\]\z/,
  63                 'epoch 1 in description');
  64 }
  65
  66 my $pid;
  67 END { kill 'TERM', $pid if defined $pid };
  68 SKIP: {
  69         my $err = "$tmpdir/stderr.log";
  70         my $out = "$tmpdir/stdout.log";
  71         my $alt = "$tmpdir/alt.git";
  72         my $cfgfile = "$tmpdir/config";
  73         my $v2 = "$tmpdir/v2";
  74         my $httpd = 'blib/script/public-inbox-httpd';
  75         my $sock = tcp_server();
  76         ok($sock, 'sock created');
  77         my ($host, $port) = ($sock->sockhost, $sock->sockport);
  78         my @clone = qw(git clone -q -s --bare);
  79         is(system(@clone, $bare->{git_dir}, $alt), 0, 'clone shared repo');
  80
  81         for my $i (0..2) {
  82                 is(system(@clone, $alt, "$v2/git/$i.git"), 0, "clone epoch $i");
  83         }
  84         ok(open(my $fh, '>', "$v2/inbox.lock"), 'mock a v2 inbox');
  85         open $fh, '>', "$alt/description" or die;
  86         print $fh "we're all clones\n" or die;
  87         close $fh or die;
  88         is(system('git', "--git-dir=$alt", qw(config gitweb.owner lorelei)), 0,
  89                 'set gitweb user');
  90         ok(unlink("$bare->{git_dir}/description"), 'removed bare/description');
  91         open $fh, '>', $cfgfile or die;
  92         print $fh <<"" or die;
  93 [publicinbox "bare"]
  94         inboxdir = $bare->{git_dir}
  95         url = http://$host/bare
  96         address = bare\@example.com
  97 [publicinbox "alt"]
  98         inboxdir = $alt
  99         url = http://$host/alt
 100         address = alt\@example.com
 101 [publicinbox "v2"]
 102         inboxdir = $v2
 103         url = http://$host/v2
 104         address = v2\@example.com
 105
 106         close $fh or die;
 107         my $env = { PI_CONFIG => $cfgfile };
 108         my $cmd = [ $httpd, "--stdout=$out", "--stderr=$err" ];
 109         $pid = spawn_listener($env, $cmd, [$sock]);
 110         $sock = undef;
 111
 112         tiny_test($host, $port);
 113
 114         skip 'skipping grok-pull integration test', 2 if !which('grok-pull');
 115
 116         ok(mkdir("$tmpdir/mirror"), 'prepare grok mirror dest');
 117         open $fh, '>', "$tmpdir/repos.conf" or die;
 118         print $fh <<"" or die;
 119 # You can pull from multiple grok mirrors, just create
 120 # a separate section for each mirror. The name can be anything.
 121 [test]
 122 site = http://$host:$port
 123 manifest = http://$host:$port/manifest.js.gz
 124 toplevel = $tmpdir/mirror
 125 mymanifest = $tmpdir/local-manifest.js.gz
 126
 127         close $fh or die;
 128
 129         system(qw(grok-pull -c), "$tmpdir/repos.conf");
 130         is($? >> 8, 127, 'grok-pull exit code as expected');
 131         for (qw(alt bare v2/git/0.git v2/git/1.git v2/git/2.git)) {
 132                 ok(-d "$tmpdir/mirror/$_", "grok-pull created $_");
 133         }
 134
 135         # support per-inbox manifests, handy for v2:
 136         # /$INBOX/v2/manifest.js.gz
 137         open $fh, '>', "$tmpdir/per-inbox.conf" or die;
 138         print $fh <<"" or die;
 139 # You can pull from multiple grok mirrors, just create
 140 # a separate section for each mirror. The name can be anything.
 141 [v2]
 142 site = http://$host:$port
 143 manifest = http://$host:$port/v2/manifest.js.gz
 144 toplevel = $tmpdir/per-inbox
 145 mymanifest = $tmpdir/per-inbox-manifest.js.gz
 146
 147         close $fh or die;
 148         ok(mkdir("$tmpdir/per-inbox"), 'prepare single-v2-inbox mirror');
 149         system(qw(grok-pull -c), "$tmpdir/per-inbox.conf");
 150         is($? >> 8, 127, 'grok-pull exit code as expected');
 151         for (qw(v2/git/0.git v2/git/1.git v2/git/2.git)) {
 152                 ok(-d "$tmpdir/per-inbox/$_", "grok-pull created $_");
 153         }
 154 }
 155
 156 done_testing();