t/xcpdb-reshard.t

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 my @mods = qw(DBI DBD::SQLite Search::Xapian);
   7 foreach my $mod (@mods) {
   8         eval "require $mod";
   9         plan skip_all => "missing $mod for $0" if $@;
  10 };
  11 require './t/common.perl';
  12 require_git('2.6');
  13 use File::Temp qw/tempdir/;
  14 use PublicInbox::MIME;
  15 use PublicInbox::InboxWritable;
  16
  17 my $mime = PublicInbox::MIME->create(
  18         header => [
  19                 From => 'a@example.com',
  20                 To => 'test@example.com',
  21                 Subject => 'this is a subject',
  22                 Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  23         ],
  24         body => '',
  25 );
  26
  27 my ($this) = (split('/', $0))[-1];
  28 my $tmpdir = tempdir($this.'-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  29 my $ibx = PublicInbox::Inbox->new({
  30         inboxdir => "$tmpdir/testbox",
  31         name => $this,
  32         version => 2,
  33         -primary_address => 'test@example.com',
  34         indexlevel => 'medium',
  35 });
  36 my @xcpdb = qw(-xcpdb -q);
  37 my $nproc = 8;
  38 my $ndoc = 13;
  39 my $im = PublicInbox::InboxWritable->new($ibx, {nproc => $nproc})->importer(1);
  40 for my $i (1..$ndoc) {
  41         $mime->header_set('Message-ID', "<m$i\@example.com>");
  42         ok($im->add($mime), "message $i added");
  43 }
  44 $im->done;
  45 my @shards = grep(m!/\d+\z!, glob("$ibx->{inboxdir}/xap*/*"));
  46 is(scalar(@shards), $nproc, 'got expected shards');
  47 my $orig = $ibx->over->query_xover(1, $ndoc);
  48 my %nums = map {; "$_->{num}" => 1 } @$orig;
  49
  50 # ensure we can go up or down in shards, or stay the same:
  51 for my $R (qw(2 4 1 3 3)) {
  52         delete $ibx->{search}; # release old handles
  53         ok(run_script([@xcpdb, "-R$R", $ibx->{inboxdir}]), "xcpdb -R$R");
  54         my @new_shards = grep(m!/\d+\z!, glob("$ibx->{inboxdir}/xap*/*"));
  55         is(scalar(@new_shards), $R, 'resharded to two shards');
  56         my $msgs = $ibx->search->query('s:this');
  57         is(scalar(@$msgs), $ndoc, 'got expected docs after resharding');
  58         my %by_mid = map {; "$_->{mid}" => $_ } @$msgs;
  59         ok($by_mid{"m$_\@example.com"}, "$_ exists") for (1..$ndoc);
  60
  61         delete $ibx->{search}; # release old handles
  62
  63         # ensure docids in Xapian match NNTP article numbers
  64         my $tot = 0;
  65         my %tmp = %nums;
  66         foreach my $d (@new_shards) {
  67                 my $xdb = Search::Xapian::Database->new($d);
  68                 $tot += $xdb->get_doccount;
  69                 my $it = $xdb->postlist_begin('');
  70                 my $end = $xdb->postlist_end('');
  71                 for (; $it != $end; $it++) {
  72                         my $docid = $it->get_docid;
  73                         if ($xdb->get_document($docid)) {
  74                                 ok(delete($tmp{$docid}), "saw #$docid");
  75                         }
  76                 }
  77         }
  78         is(scalar keys %tmp, 0, 'all docids seen');
  79 }
  80
  81 done_testing();
  82 1;