xt/imapd-mbsync-oimap.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # ensure mbsync and offlineimap compatibility
   5 use strict;
   6 use Test::More;
   7 use File::Path qw(mkpath);
   8 use PublicInbox::TestCommon;
   9 use PublicInbox::Spawn qw(which spawn);
  10 my $inboxdir = $ENV{GIANT_INBOX_DIR};
  11 (defined($inboxdir) && -d $inboxdir) or
  12         plan skip_all => "GIANT_INBOX_DIR not defined for $0";
  13 plan skip_all => "bad characters in $inboxdir" if $inboxdir =~ m![^\w\.\-/]!;
  14 my ($tmpdir, $for_destroy) = tmpdir();
  15 my $cfg = "$tmpdir/cfg";
  16 my $mailbox = 'inbox.test';
  17 {
  18         open my $fh, '>', $cfg or BAIL_OUT "open: $!";
  19         print $fh <<EOF or BAIL_OUT "print: $!";
  20 [publicinbox "test"]
  21         newsgroup = $mailbox
  22         address = oimap\@example.com
  23         inboxdir = $inboxdir
  24 EOF
  25         close $fh or BAIL_OUT "close: $!";
  26 }
  27 my ($out, $err) = ("$tmpdir/stdout.log", "$tmpdir/stderr.log");
  28 my $sock = tcp_server();
  29 my $cmd = [ '-imapd', '-W0', "--stdout=$out", "--stderr=$err" ];
  30 my $env = { PI_CONFIG => $cfg };
  31 my $td = start_script($cmd, $env, { 3 => $sock }) or BAIL_OUT "-imapd: $?";
  32 {
  33         my $c = tcp_connect($sock);
  34         like(readline($c), qr/CAPABILITY /, 'got greeting');
  35 }
  36 my ($host, $port) = ($sock->sockhost, $sock->sockport);
  37 my %pids;
  38
  39 SKIP: {
  40         mkpath([map { "$tmpdir/oimapdir/$_" } qw(cur new tmp)]);
  41         my $oimap = which('offlineimap') or skip 'no offlineimap(1)', 1;
  42         open my $fh, '>', "$tmpdir/.offlineimaprc" or BAIL_OUT "open: $!";
  43         print $fh <<EOF or BAIL_OUT "print: $!";
  44 [general]
  45 accounts = test
  46 socktimeout = 10
  47 fsync = false
  48
  49 [Account test]
  50 localrepository = l.test
  51 remoterepository = r.test
  52
  53 [Repository l.test]
  54 type = Maildir
  55 localfolders = ~/oimapdir
  56
  57 [Repository r.test]
  58 type = IMAP
  59 ssl = no
  60 remotehost = $host
  61 remoteport = $port
  62 remoteuser = anonymous
  63 remotepass = Hunter2
  64
  65 # python-imaplib2 times out on select/poll when compression is enabled
  66 # <https://bugs.debian.org/961713>
  67 usecompression = no
  68 EOF
  69         close $fh or BAIL_OUT "close: $!";
  70         my $cmd = [ $oimap, qw(-o -q -u quiet) ];
  71         my $pid = spawn($cmd, { HOME => $tmpdir }, { 1 => 2 });
  72         $pids{$pid} = $cmd;
  73 }
  74
  75 SKIP: {
  76         mkpath([map { "$tmpdir/mbsyncdir/test/$_" } qw(cur new tmp)]);
  77         my $mbsync = which('mbsync') or skip 'no mbsync(1)', 1;
  78         open my $fh, '>', "$tmpdir/.mbsyncrc" or BAIL_OUT "open: $!";
  79         print $fh <<EOF or BAIL_OUT "print: $!";
  80 Create Slave
  81 SyncState *
  82 Remove None
  83 FSync no
  84
  85 MaildirStore local
  86 Path ~/mbsyncdir/
  87 Inbox ~/mbsyncdir/test
  88 SubFolders verbatim
  89
  90 IMAPStore remote
  91 Host $host
  92 Port $port
  93 User anonymous
  94 Pass Hunter2
  95 SSLType None
  96 UseNamespace no
  97 # DisableExtension COMPRESS=DEFLATE
  98
  99 Channel "test"
 100 Master ":remote:inbox"
 101 Slave ":local:test"
 102 Expunge None
 103 Sync PullNew
 104 Patterns *
 105 EOF
 106         close $fh or BAIL_OUT "close: $!";
 107         my $cmd = [ $mbsync, qw(-aqq) ];
 108         my $pid = spawn($cmd, { HOME => $tmpdir }, { 1 => 2 });
 109         $pids{$pid} = $cmd;
 110 }
 111
 112 while (scalar keys %pids) {
 113         my $pid = waitpid(-1, 0) or next;
 114         my $cmd = delete $pids{$pid} or next;
 115         is($?, 0, join(' ', @$cmd, 'done'));
 116 }
 117
 118 if (my $sec = $ENV{TEST_PERSIST}) {
 119         diag "sleeping ${sec}s, imap://$host:$port/$mailbox available";
 120         diag "tmpdir=$tmpdir (Maildirs available)";
 121         diag "stdout=$out";
 122         diag "stderr=$err";
 123         diag "pid=$td->{pid}";
 124         sleep $sec;
 125 }
 126 $td->kill;
 127 $td->join;
 128 is($?, 0, 'no error on -imapd exit');
 129 done_testing;