xt/mem-msgview.t

   1 #!perl -w
   2 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use IO::Handle; # ->flush
   6 use Fcntl qw(SEEK_SET);
   7 use PublicInbox::TestCommon;
   8 use PublicInbox::Tmpfile;
   9 use PublicInbox::WWW;
  10 use Test::More;
  11 my @mods = qw(DBD::SQLite BSD::Resource);
  12 require_mods(@mods);
  13 use_ok($_) for @mods;
  14 my $lines = $ENV{NR_LINES} // 100000;
  15 my ($tmpdir, $for_destroy) = tmpdir();
  16 my $inboxname = 'big';
  17 my $inboxdir = "$tmpdir/big";
  18 local $ENV{PI_CONFIG} = "$tmpdir/cfg";
  19 my $mid = 'test@example.com';
  20
  21 { # setup
  22         open my $fh, '>', "$tmpdir/cfg" or die;
  23         print $fh <<EOF or die;
  24 [publicinboxmda]
  25         spamcheck = none
  26 EOF
  27         close $fh or die;
  28
  29         my $addr = 'n@example.com';
  30         ok(run_script([qw(-init -V2 --indexlevel=basic), $inboxname, $inboxdir,
  31                         "http://example.com/$inboxname", $addr]),
  32                 'inbox initialized');
  33
  34         $fh = tmpfile('big.eml', undef, my $append = 1) or die;
  35         printf($fh <<'EOF', $addr, $mid) or die;
  36 From: Dr. X <x@example.com>
  37 To: Nikki <%s>
  38 Date: Tue, 3 May 1988 00:00:00 +0000
  39 Subject: todo
  40 Message-ID: <%s>
  41
  42 EOF
  43         for (0..$lines) { print $fh 'x' x 72, "\n" or die }
  44         $fh->flush or die;
  45         sysseek($fh, 0, SEEK_SET) or die;
  46         my $env = { ORIGINAL_RECIPIENT => $addr };
  47         my $err = '';
  48         my $opt = { 0 => $fh, 2 => \$err, run_mode => 0 };
  49         ok(run_script([qw(-mda --no-precheck)], $env, $opt),
  50                 '1st message delivered');
  51
  52         # resend the message with same mid but different content
  53         print $fh "mindcrime\n" or die;
  54         $fh->flush or die;
  55         sysseek($fh, 0, SEEK_SET) or die;
  56         ok(run_script([qw(-mda --no-precheck)], $env, $opt),
  57                 '2nd message delivered');
  58 }
  59
  60 my $www = PublicInbox::WWW->new;
  61 my $env = {
  62         PATH_INFO => "/$inboxname/$mid/",
  63         REQUEST_URI => "/$inboxname/$mid/",
  64         SCRIPT_NAME => '',
  65         QUERY_STRING => '',
  66         REQUEST_METHOD => 'GET',
  67         HTTP_HOST => 'example.com',
  68         'psgi.errors' => \*STDERR,
  69         'psgi.url_scheme' => 'http',
  70 };
  71 my $ru_before = BSD::Resource::getrusage();
  72 my $res = $www->call($env);
  73 my $body = $res->[2];
  74 while (defined(my $x = $body->getline)) {
  75 }
  76 $body->close;
  77 my $ru_after = BSD::Resource::getrusage();
  78 my $diff = $ru_after->maxrss - $ru_before->maxrss;
  79 diag "before: ${\$ru_before->maxrss} => ${\$ru_after->maxrss} diff=$diff kB";
  80 done_testing();