xt/net_writer-imap.t

   1 #!perl -w
   2 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use Sys::Hostname qw(hostname);
   6 use POSIX qw(strftime);
   7 use PublicInbox::OnDestroy;
   8 use PublicInbox::URIimap;
   9 use PublicInbox::Config;
  10 use PublicInbox::DS;
  11 use PublicInbox::InboxIdle;
  12 use Fcntl qw(O_EXCL O_WRONLY O_CREAT);
  13 my $imap_url = $ENV{TEST_IMAP_WRITE_URL} or
  14         plan skip_all => 'TEST_IMAP_WRITE_URL unset';
  15 my $uri = PublicInbox::URIimap->new($imap_url);
  16 defined($uri->path) and
  17         plan skip_all => "$imap_url should not be a mailbox (just host:port)";
  18 require_mods('Mail::IMAPClient');
  19 require_ok 'PublicInbox::NetWriter';
  20 my $host = (split(/\./, hostname))[0];
  21 my ($base) = ($0 =~ m!\b([^/]+)\.[^\.]+\z!);
  22 my $SEP = $ENV{IMAP_SEPARATOR} || '.';
  23 my $folder = "INBOX$SEP$base-$host-".strftime('%Y%m%d%H%M%S', gmtime(time)).
  24                 "-$$-".sprintf('%x', int(rand(0xffffffff)));
  25 my $nwr = PublicInbox::NetWriter->new;
  26 chop($imap_url) if substr($imap_url, -1) eq '/';
  27 my $folder_url = "$imap_url/$folder";
  28 my $folder_uri = PublicInbox::URIimap->new($folder_url);
  29 is($folder_uri->mailbox, $folder, 'folder correct') or
  30                 BAIL_OUT "BUG: bad $$uri";
  31 $nwr->add_url($$folder_uri);
  32 is($nwr->errors, undef, 'no errors');
  33 $nwr->{pi_cfg} = bless {}, 'PublicInbox::Config';
  34
  35 my $set_cred_helper = sub {
  36         my ($f, $cred_set) = @_;
  37         sysopen(my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) or BAIL_OUT "open $f: $!";
  38         print $fh <<EOF or BAIL_OUT "print $f: $!";
  39 [credential]
  40         helper = $cred_set
  41 EOF
  42         close $fh or BAIL_OUT "close $f: $!";
  43 };
  44
  45 # allow testers with git-credential-store configured to reuse
  46 # stored credentials inside test_lei(sub {...}) when $ENV{HOME}
  47 # is overridden and localized.
  48 my ($cred_set, @cred_link, $tmpdir, $for_destroy);
  49 chomp(my $cred_helper = `git config credential.helper 2>/dev/null`);
  50 if ($cred_helper eq 'store') {
  51         my $config = $ENV{XDG_CONFIG_HOME} // "$ENV{HOME}/.config";
  52         for my $f ("$ENV{HOME}/.git-credentials", "$config/git/credentials") {
  53                 next unless -f $f;
  54                 @cred_link = ($f, '/.git-credentials');
  55                 last;
  56         }
  57         $cred_set = qq("$cred_helper");
  58 } elsif ($cred_helper =~ /\Acache(?:[ \t]|\z)/) {
  59         my $cache = $ENV{XDG_CACHE_HOME} // "$ENV{HOME}/.cache";
  60         for my $d ("$ENV{HOME}/.git-credential-cache",
  61                         "$cache/git/credential") {
  62                 next unless -d $d;
  63                 @cred_link = ($d, '/.git-credential-cache');
  64                 $cred_set = qq("$cred_helper");
  65                 last;
  66         }
  67 } elsif (!$cred_helper) { # make the test less painful if no creds configured
  68         ($tmpdir, $for_destroy) = tmpdir;
  69         my $d = "$tmpdir/.git-credential-cache";
  70         mkdir($d, 0700) or BAIL_OUT $!;
  71         $cred_set = "cache --timeout=60";
  72         @cred_link = ($d, '/.git-credential-cache');
  73 } else {
  74         diag "credential.helper=$cred_helper will not be used for this test";
  75 }
  76
  77 my $mics = do {
  78         local $ENV{HOME} = $tmpdir // $ENV{HOME};
  79         if ($tmpdir && $cred_set) {
  80                 $set_cred_helper->("$ENV{HOME}/.gitconfig", $cred_set)
  81         }
  82         $nwr->imap_common_init;
  83 };
  84 my $mic = (values %$mics)[0];
  85 my $cleanup = PublicInbox::OnDestroy->new($$, sub {
  86         my $mic = $nwr->mic_get($uri);
  87         $mic->delete($folder) or fail "delete $folder <$folder_uri>: $@";
  88         if ($tmpdir && -f "$tmpdir/.gitconfig") {
  89                 local $ENV{HOME} = $tmpdir;
  90                 system(qw(git credential-cache exit));
  91         }
  92 });
  93 my $imap_append = $nwr->can('imap_append');
  94 my $smsg = bless { kw => [ 'seen' ] }, 'PublicInbox::Smsg';
  95 $imap_append->($mic, $folder, undef, $smsg, eml_load('t/plack-qp.eml'));
  96 $nwr->{quiet} = 1;
  97 my $imap_slurp_all = sub {
  98         my ($url, $uid, $kw, $eml, $res) = @_;
  99         push @$res, [ $kw, $eml ];
 100 };
 101 $nwr->imap_each($folder_uri, $imap_slurp_all, my $res = []);
 102 is(scalar(@$res), 1, 'got appended message');
 103 my $plack_qp_eml = eml_load('t/plack-qp.eml');
 104 is_deeply($res, [ [ [ 'seen' ], $plack_qp_eml ] ],
 105         'uploaded message read back');
 106 $res = $mic = $mics = undef;
 107
 108 test_lei(sub {
 109         my ($ro_home, $cfg_path) = setup_public_inboxes;
 110         my $cfg = PublicInbox::Config->new($cfg_path);
 111         $cfg->each_inbox(sub {
 112                 my ($ibx) = @_;
 113                 lei_ok qw(add-external -q), $ibx->{inboxdir} or BAIL_OUT;
 114         });
 115
 116         # cred_link[0] may be on a different (hopefully encrypted) FS,
 117         # we only symlink to it here, so we don't copy any sensitive data
 118         # into the temporary directory
 119         if (@cred_link && !symlink($cred_link[0], $ENV{HOME}.$cred_link[1])) {
 120                 diag "symlink @cred_link: $! (non-fatal)";
 121                 $cred_set = undef;
 122         }
 123         $set_cred_helper->("$ENV{HOME}/.gitconfig", $cred_set) if $cred_set;
 124
 125         # don't combine these two:
 126         $ENV{TEST_IMAP_COMPRESS} and lei_ok qw(config imap.compress true);
 127         $ENV{TEST_IMAP_DEBUG} and lei_ok qw(config imap.debug true);
 128         my $proxy = $ENV{TEST_IMAP_PROXY};
 129         lei_ok(qw(config imap.proxy), $proxy) if $proxy;
 130
 131         lei_ok qw(q f:qp@example.com -o), $folder_url;
 132         $nwr->imap_each($folder_uri, $imap_slurp_all, my $res = []);
 133         is(scalar(@$res), 1, 'got one deduped result') or diag explain($res);
 134         is_deeply($res->[0]->[1], $plack_qp_eml,
 135                         'lei q wrote expected result');
 136
 137         lei_ok qw(q f:matz -a -o), $folder_url;
 138         $nwr->imap_each($folder_uri, $imap_slurp_all, my $aug = []);
 139         is(scalar(@$aug), 2, '2 results after augment') or diag explain($aug);
 140         my $exp = $res->[0]->[1]->as_string;
 141         is(scalar(grep { $_->[1]->as_string eq $exp } @$aug), 1,
 142                         'original remains after augment');
 143         $exp = eml_load('t/iso-2202-jp.eml')->as_string;
 144         is(scalar(grep { $_->[1]->as_string eq $exp } @$aug), 1,
 145                         'new result shown after augment');
 146
 147         lei_ok qw(q s:thisbetternotgiveanyresult -o), $folder_url;
 148         $nwr->imap_each($folder_uri, $imap_slurp_all, my $empty = []);
 149         is(scalar(@$empty), 0, 'no results w/o augment');
 150
 151         my $f = 't/utf8.eml'; # <testmessage@example.com>
 152         $exp = eml_load($f);
 153         lei_ok qw(convert -F eml -o), $folder_url, $f;
 154         my (@uid, @res);
 155         $nwr->imap_each($folder_uri, sub {
 156                 my ($u, $uid, $kw, $eml) = @_;
 157                 push @uid, $uid;
 158                 push @res, [ $kw, $eml ];
 159         });
 160         is_deeply(\@res, [ [ [], $exp ] ], 'converted to IMAP destination');
 161         is(scalar(@uid), 1, 'got one UID back');
 162         lei_ok qw(q -o /dev/stdout m:testmessage@example.com --no-external);
 163         is_deeply(json_utf8->decode($lei_out), [undef],
 164                 'no results before import');
 165
 166         lei_ok qw(import -F eml), $f, \'import local copy w/o keywords';
 167
 168         lei_ok 'import', $folder_url; # populate mail_sync.sqlite3
 169         lei_ok qw(tag +kw:seen +kw:answered +kw:flagged), $f;
 170         lei_ok 'ls-mail-sync';
 171         my @ls = split(/\n/, $lei_out);
 172         is(scalar(@ls), 1, 'only one folder in ls-mail-sync') or xbail(\@ls);
 173         for my $l (@ls) {
 174                 like($l, qr/;UIDVALIDITY=\d+\z/, 'UIDVALIDITY');
 175         }
 176         lei_ok 'export-kw', $folder_url;
 177         $mic = $nwr->mic_for_folder($folder_uri);
 178         my $flags = $mic->flags($uid[0]);
 179         is_deeply([sort @$flags], [ qw(\\Answered \\Flagged \\Seen) ],
 180                 'IMAP flags set by export-kw') or diag explain($flags);
 181
 182         # ensure this imap_set_kw clobbers
 183         $nwr->imap_set_kw($mic, $uid[0], [ 'seen' ])->expunge or
 184                 BAIL_OUT "expunge $@";
 185         $mic = undef;
 186         @res = ();
 187         $nwr->imap_each($folder_uri, $imap_slurp_all, \@res);
 188         is_deeply(\@res, [ [ ['seen'], $exp ] ], 'seen flag set') or
 189                 diag explain(\@res);
 190
 191         lei_ok qw(q s:thisbetternotgiveanyresult -o), $folder_url,
 192                 \'clobber folder but import flag';
 193         $nwr->imap_each($folder_uri, $imap_slurp_all, $empty = []);
 194         is_deeply($empty, [], 'clobbered folder');
 195         lei_ok qw(q -o /dev/stdout m:testmessage@example.com --no-external);
 196         $res = json_utf8->decode($lei_out)->[0];
 197         is_deeply([@$res{qw(m kw)}], ['testmessage@example.com', ['seen']],
 198                 'kw set');
 199
 200         # prepare messages for watch
 201         $mic = $nwr->mic_for_folder($folder_uri);
 202         for my $kw (qw(Deleted Seen Answered Draft forwarded)) {
 203                 my $buf = <<EOM;
 204 From: x\@example.com
 205 Message-ID: <$kw\@test.example.com>
 206
 207 EOM
 208                 my $f = $kw eq 'forwarded' ? '$Forwarded' : "\\$kw";
 209                 $mic->append_string($folder_uri->mailbox, $buf, $f)
 210                         or BAIL_OUT "append $kw $@";
 211         }
 212         $mic->disconnect;
 213
 214         my $inboxdir = "$ENV{HOME}/wtest";
 215         my @cmd = (qw(-init -Lbasic wtest), $inboxdir,
 216                         qw(https://example.com/wtest wtest@example.com));
 217         run_script(\@cmd) or BAIL_OUT "init wtest";
 218         xsys(qw(git config), "--file=$ENV{HOME}/.public-inbox/config",
 219                         'publicinbox.wtest.watch',
 220                         $folder_url) == 0 or BAIL_OUT "git config $?";
 221         my $watcherr = "$ENV{HOME}/watch.err";
 222         open my $err_wr, '>>', $watcherr or BAIL_OUT $!;
 223         my $pub_cfg = PublicInbox::Config->new;
 224         PublicInbox::DS->Reset;
 225         my $ii = PublicInbox::InboxIdle->new($pub_cfg);
 226         my $cb = sub { PublicInbox::DS->SetPostLoopCallback(sub {}) };
 227         my $obj = bless \$cb, 'PublicInbox::TestCommon::InboxWakeup';
 228         $pub_cfg->each_inbox(sub { $_[0]->subscribe_unlock('ident', $obj) });
 229         my $w = start_script(['-watch'], undef, { 2 => $err_wr });
 230         diag 'waiting for initial fetch...';
 231         PublicInbox::DS::event_loop();
 232         my $ibx = $pub_cfg->lookup_name('wtest');
 233         my $mm = $ibx->mm;
 234         ok(defined($mm->num_for('Seen@test.example.com')),
 235                 '-watch takes seen message');
 236         ok(defined($mm->num_for('Answered@test.example.com')),
 237                 '-watch takes answered message');
 238         ok(!defined($mm->num_for('Deleted@test.example.com')),
 239                 '-watch ignored \\Deleted');
 240         ok(!defined($mm->num_for('Draft@test.example.com')),
 241                 '-watch ignored \\Draft');
 242         ok(defined($mm->num_for('forwarded@test.example.com')),
 243                 '-watch takes forwarded message');
 244         undef $w; # done with watch
 245         lei_ok qw(import), $folder_url;
 246         lei_ok qw(q m:forwarded@test.example.com);
 247         is_deeply(json_utf8->decode($lei_out)->[0]->{kw}, ['forwarded'],
 248                 'forwarded kw imported from IMAP');
 249
 250         lei_ok qw(q m:testmessage --no-external -o), $folder_url;
 251         lei_ok qw(up), $folder_url;
 252         lei_ok qw(up --all=remote);
 253 });
 254
 255 undef $cleanup; # remove temporary folder
 256 done_testing;