xt/pop3d-mpop.t

   1 #!perl -w
   2 # Copyright (C) all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # ensure mpop compatibility
   5 use v5.12;
   6 use File::Path qw(make_path);
   7 use PublicInbox::TestCommon;
   8 use PublicInbox::Spawn qw(spawn);
   9 my $inboxdir = $ENV{GIANT_INBOX_DIR};
  10 (defined($inboxdir) && -d $inboxdir) or
  11         plan skip_all => "GIANT_INBOX_DIR not defined for $0";
  12 plan skip_all => "bad characters in $inboxdir" if $inboxdir =~ m![^\w\.\-/]!;
  13 my $uuidgen = require_cmd('uuidgen');
  14 my $mpop = require_cmd('mpop');
  15 require_mods(qw(DBD::SQLite));
  16 require_git('2.6'); # for v2
  17 require_mods(qw(File::FcntlLock)) if $^O !~ /\A(?:linux|freebsd)\z/;
  18
  19 my ($tmpdir, $for_destroy) = tmpdir();
  20 my $cfg = "$tmpdir/cfg";
  21 my $newsgroup = 'inbox.test';
  22 my %pids;
  23 {
  24         open my $fh, '>', $cfg or xbail "open: $!";
  25         print $fh <<EOF or xbail "print: $!";
  26 [publicinbox]
  27         pop3state = $tmpdir/p3s
  28 [publicinbox "test"]
  29         newsgroup = $newsgroup
  30         address = mpop-test\@example.com
  31         inboxdir = $inboxdir
  32 EOF
  33         close $fh or xbail "close: $!";
  34 }
  35 my ($out, $err) = ("$tmpdir/stdout.log", "$tmpdir/stderr.log");
  36 my $sock = tcp_server();
  37 my $cmd = [ '-pop3d', '-W0', "--stdout=$out", "--stderr=$err" ];
  38 my $env = { PI_CONFIG => $cfg };
  39 my $td = start_script($cmd, $env, { 3 => $sock }) or xbail "-xbail $?";
  40 chomp(my $uuid = xqx([$uuidgen]));
  41
  42 make_path("$tmpdir/home/.config/mpop",
  43         map { "$tmpdir/md/$_" } qw(new cur tmp));
  44
  45 {
  46         open my $fh, '>', "$tmpdir/home/.config/mpop/config"
  47                 or xbail "open $!";
  48         chmod 0600, $fh;
  49         print $fh <<EOM or xbail "print $!";
  50 defaults
  51 tls off
  52 delivery maildir $tmpdir/md
  53 account default
  54 host ${\$sock->sockhost}
  55 port ${\$sock->sockport}
  56 user $uuid\@$newsgroup
  57 auth user
  58 password anonymous
  59 received_header off
  60 EOM
  61         close $fh or xbail "close $!";
  62         delete local $ENV{XDG_CONFIG_HOME}; # mpop uses this
  63         local $ENV{HOME} = "$tmpdir/home";
  64         my $cmd = [ $mpop, '-q' ];
  65         my $pid = spawn($cmd, undef, { 1 => 2 });
  66         $pids{$pid} = $cmd;
  67 }
  68
  69 while (scalar keys %pids) {
  70         my $pid = waitpid(-1, 0) or next;
  71         my $cmd = delete $pids{$pid} or next;
  72         is($?, 0, join(' ', @$cmd, 'done'));
  73 }
  74 $td->kill;
  75 $td->join;
  76 is($?, 0, 'no error on -pop3d exit');
  77 done_testing;