address: pairs: new helper for JMAP (and maybe lei)

Per JMAP RFC 8621 sec 4.1.2.3, we should be able to
denote the lack of a phrase/comment corresponding to an
email address with a JSON "null" (or Perl `undef').

  [
    { "name": "James Smythe", "email": "james@example.com" },
    { "name": null, "email": "jane@example.com" },
    { "name": "John Smith", "email": "john@example.com" }
  ]

The new "pairs" method just returns a 2 dimensional array
and the consumer will fill in the field names if necessary
(or not).

lei(1) may use the two dimensional array as-is for JSON output.

diff --git a/lib/PublicInbox/Address.pm b/lib/PublicInbox/Address.pm
index f5af4c23104554e8f553ea4924a4770e853f2ad1..a090fa432429cec5d4772e8f7f8083788a648d86 100644 (file)
--- a/lib/PublicInbox/Address.pm
+++ b/lib/PublicInbox/Address.pm
@@ -2,7 +2,9 @@
 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
 package PublicInbox::Address;
 use strict;
-use warnings;
+use v5.10.1;
+use parent 'Exporter';
+our @EXPORT_OK = qw(pairs);
 
 sub xs_emails {
        grep { defined } map { $_->address() } parse_email_addresses($_[0])
@@ -17,11 +19,18 @@ sub xs_names {
        } parse_email_addresses($_[0]);
 }
 
+sub xs_pairs { # for JMAP, RFC 8621 section 4.1.2.3
+       [ map { # LHS (name) may be undef
+               [ $_->phrase // $_->comment, $_->address ]
+       } parse_email_addresses($_[0]) ];
+}
+
 eval {
        require Email::Address::XS;
        Email::Address::XS->import(qw(parse_email_addresses));
        *emails = \&xs_emails;
        *names = \&xs_names;
+       *pairs = \&xs_pairs;
 };
 
 if ($@) {

diff --git a/lib/PublicInbox/AddressPP.pm b/lib/PublicInbox/AddressPP.pm
index c04de74b2fb202a0a4bba56ced739e26ada33ac9..6a3ae4fed766d7cb654b1f00ad53b1d798986246 100644 (file)
--- a/lib/PublicInbox/AddressPP.pm
+++ b/lib/PublicInbox/AddressPP.pm
@@ -13,6 +13,7 @@ sub emails {
 }
 
 sub names {
+       # split by address and post-address comment
        my @p = split(/<?([^@<>]+)\@[\w\.\-]+>?\s*(\(.*?\))?(?:,\s*|\z)/,
                        $_[0]);
        my @ret;
@@ -35,4 +36,24 @@ sub names {
        @ret;
 }
 
+sub pairs { # for JMAP, RFC 8621 section 4.1.2.3
+       my ($s) = @_;
+       [ map {
+               my $addr = $_;
+               if ($s =~ s/\A\s*(.*?)\s*<\Q$addr\E>\s*(.*?)\s*(?:,|\z)// ||
+                   $s =~ s/\A\s*(.*?)\s*\Q$addr\E\s*(.*?)\s*(?:,|\z)//) {
+                       my ($phrase, $comment) = ($1, $2);
+                       $phrase =~ tr/\r\n\t / /s;
+                       $phrase =~ s/\A['"\s]*//;
+                       $phrase =~ s/['"\s]*\z//;
+                       $phrase =~ s/\s*<*\s*\z//;
+                       $phrase = undef if $phrase !~ /\S/;
+                       $comment = ($comment =~ /\((.*?)\)/) ? $1 : undef;
+                       [ $phrase // $comment, $addr ]
+               } else {
+                       ();
+               }
+       } emails($s) ];
+}
+
 1;

diff --git a/t/address.t b/t/address.t
index 0adcf46d5b5f531c61e985849f6bbaca4798c399..6aa94628dc8f943cccf1bf626e39098b87d49ad5 100644 (file)
--- a/t/address.t
+++ b/t/address.t
@@ -7,26 +7,40 @@ use_ok 'PublicInbox::Address';
 
 sub test_pkg {
        my ($pkg) = @_;
-       my $emails = \&{"${pkg}::emails"};
-       my $names = \&{"${pkg}::names"};
+       my $emails = $pkg->can('emails');
+       my $names = $pkg->can('names');
+       my $pairs = $pkg->can('pairs');
 
        is_deeply([qw(e@example.com e@example.org)],
                [$emails->('User <e@example.com>, e@example.org')],
                'address extraction works as expected');
 
+       is_deeply($pairs->('User <e@example.com>, e@example.org'),
+                       [[qw(User e@example.com)], [undef, 'e@example.org']],
+               "pair extraction works ($pkg)");
+
        is_deeply(['user@example.com'],
                [$emails->('<user@example.com (Comment)>')],
                'comment after domain accepted before >');
+       is_deeply($pairs->('<user@example.com (Comment)>'),
+               [[qw(Comment user@example.com)]], "comment as name ($pkg)");
 
-       my @names = $names->(
-               'User <e@e>, e@e, "John A. Doe" <j@d>, <x@x>, <y@x> (xyz), '.
-               'U Ser <u@x> (do not use)');
+       my $s = 'User <e@e>, e@e, "John A. Doe" <j@d>, <x@x>, <y@x> (xyz), '.
+               'U Ser <u@x> (do not use)';
+       my @names = $names->($s);
        is_deeply(\@names, ['User', 'e', 'John A. Doe', 'x', 'xyz', 'U Ser'],
                'name extraction works as expected');
+       is_deeply($pairs->($s), [ [ 'User', 'e@e' ], [ undef, 'e@e' ],
+                       [ 'John A. Doe', 'j@d' ], [ undef, 'x@x' ],
+                       [ 'xyz', 'y@x' ], [ 'U Ser', 'u@x' ] ],
+               "pairs extraction works for $pkg");
 
        @names = $names->('"user@example.com" <user@example.com>');
        is_deeply(['user'], \@names,
                'address-as-name extraction works as expected');
+       is_deeply($pairs->('"user@example.com" <user@example.com>'),
+               [ [ 'user@example.com', 'user@example.com' ] ],
+               "pairs for $pkg");
 
        {
                my $backwards = 'u@example.com (John Q. Public)';
@@ -34,10 +48,17 @@ sub test_pkg {
                is_deeply(\@names, ['John Q. Public'], 'backwards name OK');
                my @emails = $emails->($backwards);
                is_deeply(\@emails, ['u@example.com'], 'backwards emails OK');
+
+               is_deeply($pairs->($backwards),
+                       [ [ 'John Q. Public', 'u@example.com' ] ],
+                       "backwards pairs $pkg");
        }
 
-       @names = $names->('"Quote Unneeded" <user@example.com>');
+       $s = '"Quote Unneeded" <user@example.com>';
+       @names = $names->($s);
        is_deeply(['Quote Unneeded'], \@names, 'extra quotes dropped');
+       is_deeply($pairs->($s), [ [ 'Quote Unneeded', 'user@example.com' ] ],
+               "extra quotes dropped in pairs $pkg");
 
        my @emails = $emails->('Local User <user>');
        is_deeply([], \@emails , 'no address for local address');