t/perf-msgview: add test to check msg_html performance

This will be necessary to ensure we maintain reasonable
performance when we add diff-highlighting support.

diff --git a/MANIFEST b/MANIFEST
index e4f3df864a4d6f31c398e3d0bfc4fad21e50ce4c..dfd9e2775ece6108fb01122fb6d6ccb76c1b4fad 100644 (file)
--- a/MANIFEST
+++ b/MANIFEST
@@ -185,6 +185,7 @@ t/nntp.t
 t/nntpd.t
 t/nulsubject.t
 t/over.t
+t/perf-msgview.t
 t/perf-nntpd.t
 t/perf-threading.t
 t/plack.t

diff --git a/t/perf-msgview.t b/t/perf-msgview.t
new file mode 100644 (file)
index 0000000..adeb7aa
--- /dev/null
+++ b/t/perf-msgview.t
@@ -0,0 +1,50 @@
+# Copyright (C) 2019 all contributors <meta@public-inbox.org>
+# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
+use strict;
+use warnings;
+use Test::More;
+use Benchmark qw(:all);
+use PublicInbox::Inbox;
+use PublicInbox::View;
+require './t/common.perl';
+
+my @cat = qw(cat-file --buffer --batch-check --batch-all-objects);
+if (require_git(2.19, 1)) {
+       push @cat, '--unordered';
+} else {
+       warn
+"git <2.19, cat-file lacks --unordered, locality suffers\n";
+}
+
+my $pi_dir = $ENV{GIANT_PI_DIR};
+plan skip_all => "GIANT_PI_DIR not defined for $0" unless $pi_dir;
+
+my $ibx = PublicInbox::Inbox->new({ mainrepo => $pi_dir, name => 'name' });
+my $git = $ibx->git;
+my $fh = $git->popen(@cat);
+my $vec = '';
+vec($vec, fileno($fh), 1) = 1;
+select($vec, undef, undef, 60) or die "timed out waiting for --batch-check";
+
+my $ctx = {
+       env => { HTTP_HOST => 'example.com', 'psgi.url_scheme' => 'https' },
+       -inbox => $ibx,
+};
+my ($str, $mime, $res, $cmt, $type);
+my $n = 0;
+my $t = timeit(1, sub {
+       while (<$fh>) {
+               ($cmt, $type) = split / /;
+               next if $type ne 'blob';
+               ++$n;
+               $str = $git->cat_file($cmt);
+               $mime = PublicInbox::MIME->new($str);
+               $res = PublicInbox::View::msg_html($ctx, $mime);
+               $res = $res->[2];
+               while (defined($res->getline)) {}
+               $res->close;
+       }
+});
+diag 'msg_html took '.timestr($t)." for $n messages";
+ok 1;
+done_testing();