lib/PublicInbox/Daemon.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use File::Spec;
  14 use POSIX qw(WNOHANG :signal_h);
  15 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  16 STDOUT->autoflush(1);
  17 STDERR->autoflush(1);
  18 use PublicInbox::DS qw(now);
  19 use PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::Git;
  23 use PublicInbox::GitAsyncCat;
  24 use PublicInbox::Eml;
  25 our $SO_ACCEPTFILTER = 0x1000;
  26 my @CMD;
  27 my ($set_user, $oldset);
  28 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  29 my $worker_processes = 1;
  30 my @listeners;
  31 my (%pids, %logs);
  32 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL::SSL_Context->new
  33 my $reexec_pid;
  34 my ($uid, $gid);
  35 my ($default_cert, $default_key);
  36 my %KNOWN_TLS = (443 => 'https', 563 => 'nntps', 993 => 'imaps', 995 =>'pop3s');
  37 my %KNOWN_STARTTLS = (110 => 'pop3', 119 => 'nntp', 143 => 'imap');
  38 my %SCHEME2PORT = map { $KNOWN_TLS{$_} => $_ + 0 } keys %KNOWN_TLS;
  39 for (keys %KNOWN_STARTTLS) { $SCHEME2PORT{$KNOWN_STARTTLS{$_}} = $_ + 0 }
  40 $SCHEME2PORT{http} = 80;
  41
  42 sub listener_opt ($) {
  43         my ($str) = @_; # opt1=val1,opt2=val2 (opt may repeat for multi-value)
  44         my $o = {};
  45         # allow ',' as delimiter since '&' is shell-unfriendly
  46         for (split(/[,&]/, $str)) {
  47                 my ($k, $v) = split(/=/, $_, 2);
  48                 push @{$o->{$k}}, $v;
  49         }
  50
  51         # key may be a part of cert.  At least
  52         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  53         $o->{cert} //= [ $default_cert ] if defined($default_cert);
  54         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  55         $o;
  56 }
  57
  58 sub check_absolute ($$) {
  59         my ($var, $val) = @_;
  60         die <<EOM if index($val // '/', '/') != 0;
  61 $var must be an absolute path when using --daemonize: $val
  62 EOM
  63 }
  64
  65 sub accept_tls_opt ($) {
  66         my ($opt) = @_;
  67         my $o = ref($opt) eq 'HASH' ? $opt : listener_opt($opt);
  68         return if !defined($o->{cert});
  69         require PublicInbox::TLS;
  70         my @ctx_opt;
  71         # parse out hostname:/path/to/ mappings:
  72         for my $k (qw(cert key)) {
  73                 $o->{$k} // next;
  74                 push(@ctx_opt, "SSL_${k}_file", {});
  75                 foreach my $path (@{$o->{$k}}) {
  76                         my $host = '';
  77                         $path =~ s/\A([^:]+):// and $host = $1;
  78                         $ctx_opt[-1]->{$host} = $path;
  79                         check_absolute($k, $path) if $daemonize;
  80                 }
  81         }
  82         \@ctx_opt;
  83 }
  84
  85 sub do_chown ($) {
  86         $uid // return;
  87         my ($path) = @_;
  88         chown($uid, $gid, $path) or warn "chown $path: $!\n";
  89 }
  90
  91 sub open_log_path ($$) { # my ($fh, $path) = @_; # $_[0] is modified
  92         open $_[0], '>>', $_[1] or die "open(>> $_[1]): $!";
  93         $_[0]->autoflush(1);
  94         do_chown($_[1]);
  95         $_[0];
  96 }
  97
  98 sub load_mod ($;$$) {
  99         my ($scheme, $opt, $addr) = @_;
 100         my $modc = "PublicInbox::\U$scheme";
 101         $modc =~ s/S\z//;
 102         my $mod = $modc.'D';
 103         eval "require $mod"; # IMAPD|HTTPD|NNTPD|POP3D
 104         die $@ if $@;
 105         my %xn;
 106         my $tlsd = $xn{tlsd} = $mod->new;
 107         my %env = map {
 108                 substr($_, length('env.')) => $opt->{$_}->[-1];
 109         } grep(/\Aenv\./, keys %$opt);
 110         $xn{refresh} = sub {
 111                 my ($sig) = @_;
 112                 local @ENV{keys %env} = values %env;
 113                 $tlsd->refresh_groups($sig);
 114         };
 115         $xn{post_accept} = $tlsd->can('post_accept_cb') ?
 116                         $tlsd->post_accept_cb : sub { $modc->new($_[0], $tlsd) };
 117         my @paths = qw(out err);
 118         if ($modc eq 'PublicInbox::HTTP') {
 119                 @paths = qw(err);
 120                 $xn{af_default} = 'httpready';
 121                 if (my $p = $opt->{psgi}) {
 122                         die "multiple psgi= options specified\n" if @$p > 1;
 123                         check_absolute('psgi=', $p->[0]) if $daemonize;
 124                         $tlsd->{psgi} = $p->[0];
 125                         warn "# $scheme://$addr psgi=$p->[0]\n";
 126                 }
 127         }
 128         for my $f (@paths) {
 129                 my $p = $opt->{$f} or next;
 130                 die "multiple $f= options specified\n" if @$p > 1;
 131                 check_absolute("$f=", $p->[0]) if $daemonize;
 132                 $p = File::Spec->canonpath($p->[0]);
 133                 $tlsd->{$f} = $logs{$p} //= open_log_path(my $fh, $p);
 134                 warn "# $scheme://$addr $f=$p\n";
 135         }
 136         \%xn;
 137 }
 138
 139 sub daemon_prepare ($$) {
 140         my ($default_listen, $xnetd) = @_;
 141         my $listener_names = {}; # sockname => IO::Handle
 142         $oldset = PublicInbox::DS::block_signals();
 143         @CMD = ($0, @ARGV);
 144         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
 145         my $dh = defined($default_listen) ? " (default: $default_listen)" : '';
 146         my $help = <<EOF;
 147 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
 148
 149 options:
 150
 151   -l ADDRESS    address to listen on$dh
 152   --cert=FILE   default SSL/TLS certificate
 153   --key=FILE    default SSL/TLS certificate
 154   -W WORKERS    number of worker processes to spawn (default: 1)
 155
 156 See public-inbox-daemon(8) and $prog(1) man pages for more.
 157 EOF
 158         my %opt = (
 159                 'l|listen=s' => \@cfg_listen,
 160                 '1|stdout=s' => \$stdout,
 161                 '2|stderr=s' => \$stderr,
 162                 'W|worker-processes=i' => \$worker_processes,
 163                 'P|pid-file=s' => \$pid_file,
 164                 'u|user=s' => \$user,
 165                 'g|group=s' => \$group,
 166                 'D|daemonize' => \$daemonize,
 167                 'cert=s' => \$default_cert,
 168                 'key=s' => \$default_key,
 169                 'help|h' => \(my $show_help),
 170         );
 171         GetOptions(%opt) or die $help;
 172         if ($show_help) { print $help; exit 0 };
 173
 174         $_ = File::Spec->canonpath($_ // next) for ($stdout, $stderr);
 175         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 176                 die "--pid-file cannot end with '.oldbin'\n";
 177         }
 178         @listeners = inherit($listener_names);
 179
 180         # allow socket-activation users to set certs once and not
 181         # have to configure each socket:
 182         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 183
 184         # ignore daemonize when inheriting
 185         $daemonize = undef if scalar @listeners;
 186
 187         unless (@listeners || @cfg_listen) {
 188                 $default_listen // die "no listeners specified\n";
 189                 push @cfg_listen, $default_listen
 190         }
 191
 192         foreach my $l (@cfg_listen) {
 193                 my $orig = $l;
 194                 my $scheme = '';
 195                 my $port;
 196                 if ($l =~ s!\A([^:]+)://!!) { $scheme = $1 }
 197                 if ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9]+)/) {
 198                         $port = $1 + 0;
 199                         my $s = $KNOWN_TLS{$port} // $KNOWN_STARTTLS{$port};
 200                         $scheme //= $s if defined $s;
 201                 } elsif (index($l, '/') != 0) { # unix socket
 202                         $port //= $SCHEME2PORT{$scheme} if $scheme;
 203                         $port // die "no port in listen=$l\n";
 204                         $l =~ s!\A([^/]+)!$1:$port! or
 205                                 die "unable to add port=$port to $l\n";
 206                 }
 207                 my $opt; # non-TLS options
 208                 if ($l =~ s!/?\?(.+)\z!!) {
 209                         $opt = listener_opt($1);
 210                         $tls_opt{"$scheme://$l"} = accept_tls_opt($opt);
 211                 } elsif (defined($default_cert)) {
 212                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 213                 } elsif ($scheme =~ /\A(?:https|imaps|nntps|pop3s)\z/) {
 214                         die "$orig specified w/o cert=\n";
 215                 }
 216                 $scheme =~ /\A(?:http|imap|nntp|pop3)/ and
 217                         $xnetd->{$l} = load_mod($scheme, $opt, $l);
 218
 219                 next if $listener_names->{$l}; # already inherited
 220                 my (%o, $sock_pkg);
 221                 if (index($l, '/') == 0) {
 222                         $sock_pkg = 'IO::Socket::UNIX';
 223                         eval "use $sock_pkg";
 224                         die $@ if $@;
 225                         %o = (Type => SOCK_STREAM, Peer => $l);
 226                         if (-S $l) {
 227                                 my $c = $sock_pkg->new(%o);
 228                                 if (!defined($c) && $!{ECONNREFUSED}) {
 229                                         unlink $l or die
 230 "failed to unlink stale socket=$l: $!\n";
 231                                 } # else: let the bind fail
 232                         }
 233                         $o{Local} = delete $o{Peer};
 234                 } else {
 235                         # both work for IPv4, too
 236                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 237                                 $sock_pkg = $_;
 238                                 eval "use $sock_pkg";
 239                                 $@ or last;
 240                         }
 241                         die $@ if $@;
 242                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 243                 }
 244                 $o{Listen} = 1024;
 245                 my $prev = umask 0000;
 246                 my $s = eval { $sock_pkg->new(%o) };
 247                 warn "error binding $l: $! ($@)\n" unless $s;
 248                 umask $prev;
 249                 if ($s) {
 250                         $s->blocking(0);
 251                         my $k = sockname($s);
 252                         warn "# bound $scheme://$k\n";
 253                         $listener_names->{$k} = $s;
 254                         push @listeners, $s;
 255                 }
 256         }
 257
 258         # cert/key options in @cfg_listen takes precedence when inheriting,
 259         # but map well-known inherited ports if --listen isn't specified
 260         # at all
 261         for my $sockname (@inherited_names) {
 262                 $sockname =~ /:([0-9]+)\z/ or next;
 263                 if (my $scheme = $KNOWN_TLS{$1}) {
 264                         $xnetd->{$sockname} = load_mod($scheme);
 265                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 266                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 267                         $xnetd->{$sockname} = load_mod($scheme);
 268                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 269                         $tls_opt{''} ||= accept_tls_opt('');
 270                 }
 271         }
 272         my @d;
 273         while (my ($k, $v) = each %tls_opt) { push(@d, $k) if !defined($v) }
 274         delete @tls_opt{@d};
 275         die "No listeners bound\n" unless @listeners;
 276 }
 277
 278 sub daemonize () {
 279         if ($daemonize) {
 280                 require Cwd;
 281                 foreach my $i (0..$#ARGV) {
 282                         my $arg = $ARGV[$i];
 283                         next unless -e $arg;
 284                         $ARGV[$i] = Cwd::abs_path($arg);
 285                 }
 286                 check_absolute('--stdout', $stdout);
 287                 check_absolute('--stderr', $stderr);
 288                 check_absolute('--pid-file', $pid_file);
 289                 check_absolute('--cert', $default_cert);
 290                 check_absolute('--key', $default_key);
 291
 292                 chdir '/' or die "chdir failed: $!";
 293         }
 294         if (defined($pid_file) || defined($group) || defined($user)) {
 295                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 296 Net::Server required for --pid-file, --group, --user
 297 $@
 298 EOF
 299         }
 300         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 301         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 302         if (defined $group) {
 303                 $gid = Net::Server::Daemonize::get_gid($group);
 304                 $gid = (split /\s+/, $gid)[0];
 305         } elsif (defined $uid) {
 306                 $gid = (getpwuid($uid))[3];
 307         }
 308
 309         # We change users in the worker to ensure upgradability,
 310         # The upgrade will create the ".oldbin" pid file in the
 311         # same directory as the given pid file.
 312         $uid and $set_user = sub {
 313                 $set_user = undef;
 314                 Net::Server::Daemonize::set_user($uid, $gid);
 315         };
 316
 317         if ($daemonize) {
 318                 my $pid = fork // die "fork: $!";
 319                 exit if $pid;
 320
 321                 open(STDIN, '+<', '/dev/null') or
 322                                         die "redirect stdin failed: $!\n";
 323                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 324                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 325                 POSIX::setsid();
 326                 $pid = fork // die "fork: $!";
 327                 exit if $pid;
 328         }
 329         return unless defined $pid_file;
 330
 331         write_pid($pid_file);
 332         # for ->DESTROY:
 333         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 334 }
 335
 336 sub worker_quit { # $_[0] = signal name or number (unused)
 337         # killing again terminates immediately:
 338         exit unless @listeners;
 339
 340         $_->close foreach @listeners; # call PublicInbox::DS::close
 341         @listeners = ();
 342         my $proc_name;
 343         my $warn = 0;
 344         # drop idle connections and try to quit gracefully
 345         PublicInbox::DS->SetPostLoopCallback(sub {
 346                 my ($dmap, undef) = @_;
 347                 my $n = 0;
 348                 my $now = now();
 349                 for my $s (values %$dmap) {
 350                         $s->can('busy') or next;
 351                         if ($s->busy) {
 352                                 ++$n;
 353                         } else { # close as much as possible, early as possible
 354                                 $s->close;
 355                         }
 356                 }
 357                 if ($n) {
 358                         if (($warn + 5) < now()) {
 359                                 warn "$$ quitting, $n client(s) left\n";
 360                                 $warn = now();
 361                         }
 362                         unless (defined $proc_name) {
 363                                 $proc_name = (split(/\s+/, $0))[0];
 364                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 365                         }
 366                         $0 = "$proc_name quitting, $n client(s) left";
 367                 }
 368                 $n; # true: loop continues, false: loop breaks
 369         });
 370 }
 371
 372 sub reopen_logs {
 373         $logs{$stdout} //= \*STDOUT if defined $stdout;
 374         $logs{$stderr} //= \*STDERR if defined $stderr;
 375         while (my ($p, $fh) = each %logs) { open_log_path($fh, $p) }
 376 }
 377
 378 sub sockname ($) {
 379         my ($s) = @_;
 380         my $addr = getsockname($s) or return;
 381         my ($host, $port) = host_with_port($addr);
 382         if ($port == 0 && $host eq '127.0.0.1') {
 383                 my ($path) = Socket::sockaddr_un($addr);
 384                 return $path;
 385         }
 386         "$host:$port";
 387 }
 388
 389 sub unpack_ipv6 ($) {
 390         my ($addr) = @_;
 391         my ($port, $host);
 392
 393         # Socket.pm in Perl 5.14+ supports IPv6:
 394         eval {
 395                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 396                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 397         };
 398
 399         if ($@) {
 400                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 401                 # Socket6, so it may be installed on our system, already
 402                 # (otherwise die here):
 403                 require Socket6;
 404
 405                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 406                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 407         }
 408         ($host, $port);
 409 }
 410
 411 sub host_with_port ($) {
 412         my ($addr) = @_;
 413         my ($port, $host);
 414
 415         # this eval will die on Unix sockets:
 416         eval {
 417                 if (length($addr) >= 28) {
 418                         ($host, $port) = unpack_ipv6($addr);
 419                         $host = "[$host]";
 420                 } else {
 421                         ($port, $host) = Socket::sockaddr_in($addr);
 422                         $host = Socket::inet_ntoa($host);
 423                 }
 424         };
 425         $@ ? ('127.0.0.1', 0) : ($host, $port);
 426 }
 427
 428 sub inherit ($) {
 429         my ($listener_names) = @_;
 430         return () if ($ENV{LISTEN_PID} || 0) != $$;
 431         my $fds = $ENV{LISTEN_FDS} or return ();
 432         my $end = $fds + 2; # LISTEN_FDS_START - 1
 433         my @rv = ();
 434         foreach my $fd (3..$end) {
 435                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 436                 if (my $k = sockname($s)) {
 437                         my $prev_was_blocking = $s->blocking(0);
 438                         warn <<"" if $prev_was_blocking;
 439 Inherited socket ($k fd=$fd) is blocking, making it non-blocking.
 440 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 441 processes when multiple service instances start.
 442
 443                         $listener_names->{$k} = $s;
 444                         warn "# inherited $k fd=$fd\n";
 445                         push @rv, $s;
 446                 } else {
 447                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 448                 }
 449         }
 450         @rv
 451 }
 452
 453 sub upgrade { # $_[0] = signal name or number (unused)
 454         if ($reexec_pid) {
 455                 warn "upgrade in-progress: $reexec_pid\n";
 456                 return;
 457         }
 458         if (defined $pid_file) {
 459                 if ($pid_file =~ /\.oldbin\z/) {
 460                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 461                         return;
 462                 }
 463                 unlink_pid_file_safe_ish($$, $pid_file);
 464                 $pid_file .= '.oldbin';
 465                 write_pid($pid_file);
 466         }
 467         my $pid = fork;
 468         unless (defined $pid) {
 469                 warn "fork failed: $!\n";
 470                 return;
 471         }
 472         if ($pid == 0) {
 473                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 474                 $ENV{LISTEN_FDS} = scalar @listeners;
 475                 $ENV{LISTEN_PID} = $$;
 476                 foreach my $s (@listeners) {
 477                         # @listeners are globs with workers, PI::L w/o workers
 478                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 479
 480                         my $fl = fcntl($s, F_GETFD, 0);
 481                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 482                 }
 483                 exec @CMD;
 484                 die "Failed to exec: $!\n";
 485         }
 486         $reexec_pid = $pid;
 487 }
 488
 489 sub kill_workers ($) {
 490         my ($sig) = @_;
 491         kill $sig, keys(%pids);
 492 }
 493
 494 sub upgrade_aborted ($) {
 495         my ($p) = @_;
 496         warn "reexec PID($p) died with: $?\n";
 497         $reexec_pid = undef;
 498         return unless $pid_file;
 499
 500         my $file = $pid_file;
 501         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 502         unlink_pid_file_safe_ish($$, $pid_file);
 503         $pid_file = $file;
 504         eval { write_pid($pid_file) };
 505         warn $@, "\n" if $@;
 506 }
 507
 508 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 509         while (1) {
 510                 my $p = waitpid(-1, WNOHANG) or return;
 511                 if (defined $reexec_pid && $p == $reexec_pid) {
 512                         upgrade_aborted($p);
 513                 } elsif (defined(my $id = delete $pids{$p})) {
 514                         warn "worker[$id] PID($p) died with: $?\n";
 515                 } elsif ($p > 0) {
 516                         warn "unknown PID($p) reaped: $?\n";
 517                 } else {
 518                         return;
 519                 }
 520         }
 521 }
 522
 523 sub unlink_pid_file_safe_ish ($$) {
 524         my ($unlink_pid, $file) = @_;
 525         return unless defined $unlink_pid && $unlink_pid == $$;
 526
 527         open my $fh, '<', $file or return;
 528         local $/ = "\n";
 529         defined(my $read_pid = <$fh>) or return;
 530         chomp $read_pid;
 531         if ($read_pid == $unlink_pid) {
 532                 Net::Server::Daemonize::unlink_pid_file($file);
 533         }
 534 }
 535
 536 sub master_quit ($) {
 537         exit unless @listeners;
 538         @listeners = ();
 539         kill_workers($_[0]);
 540 }
 541
 542 sub master_loop {
 543         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 544         my $set_workers = $worker_processes;
 545         reopen_logs();
 546         my $ignore_winch;
 547         my $sig = {
 548                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 549                 USR2 => \&upgrade,
 550                 QUIT => \&master_quit,
 551                 INT => \&master_quit,
 552                 TERM => \&master_quit,
 553                 WINCH => sub {
 554                         return if $ignore_winch || !@listeners;
 555                         if (-t STDIN || -t STDOUT || -t STDERR) {
 556                                 $ignore_winch = 1;
 557                                 warn <<EOF;
 558 ignoring SIGWINCH since we are not daemonized
 559 EOF
 560                         } else {
 561                                 $worker_processes = 0;
 562                         }
 563                 },
 564                 HUP => sub {
 565                         return unless @listeners;
 566                         $worker_processes = $set_workers;
 567                         kill_workers($_[0]);
 568                 },
 569                 TTIN => sub {
 570                         return unless @listeners;
 571                         if ($set_workers > $worker_processes) {
 572                                 ++$worker_processes;
 573                         } else {
 574                                 $worker_processes = ++$set_workers;
 575                         }
 576                 },
 577                 TTOU => sub {
 578                         $worker_processes = --$set_workers if $set_workers > 0;
 579                 },
 580                 CHLD => \&reap_children,
 581         };
 582         my $sigfd = PublicInbox::Sigfd->new($sig);
 583         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 584         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 585         while (1) { # main loop
 586                 my $n = scalar keys %pids;
 587                 unless (@listeners) {
 588                         exit if $n == 0;
 589                         $set_workers = $worker_processes = $n = 0;
 590                 }
 591
 592                 if ($n > $worker_processes) {
 593                         while (my ($k, $v) = each %pids) {
 594                                 kill('TERM', $k) if $v >= $worker_processes;
 595                         }
 596                         $n = $worker_processes;
 597                 }
 598                 my $want = $worker_processes - 1;
 599                 if ($n <= $want) {
 600                         PublicInbox::DS::block_signals() if !$sigfd;
 601                         for my $i ($n..$want) {
 602                                 my $seed = rand(0xffffffff);
 603                                 my $pid = fork;
 604                                 if (!defined $pid) {
 605                                         warn "failed to fork worker[$i]: $!\n";
 606                                 } elsif ($pid == 0) {
 607                                         srand($seed);
 608                                         eval { Net::SSLeay::randomize() };
 609                                         $set_user->() if $set_user;
 610                                         return $p0; # run normal work code
 611                                 } else {
 612                                         warn "PID=$pid is worker[$i]\n";
 613                                         $pids{$pid} = $i;
 614                                 }
 615                         }
 616                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 617                 }
 618
 619                 if ($sigfd) { # Linux and IO::KQueue users:
 620                         $sigfd->wait_once;
 621                 } else { # wake up every second
 622                         sleep(1);
 623                 }
 624         }
 625         exit # never gets here, just for documentation
 626 }
 627
 628 sub tls_cb {
 629         my ($post_accept, $tlsd) = @_;
 630         sub {
 631                 my ($io, $addr, $srv) = @_;
 632                 $post_accept->(PublicInbox::TLS::start($io, $tlsd), $addr, $srv)
 633         }
 634 }
 635
 636 sub defer_accept ($$) {
 637         my ($s, $af_name) = @_;
 638         return unless defined $af_name;
 639         if ($^O eq 'linux') {
 640                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 641                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 642                 return unless defined $x; # may be Unix socket
 643                 my $sec = unpack('i', $x);
 644                 return if $sec > 0; # systemd users may set a higher value
 645                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 646         } elsif ($^O eq 'freebsd') {
 647                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 648                 return if defined $x; # don't change if set
 649                 my $accf_arg = pack('a16a240', $af_name, '');
 650                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 651         }
 652 }
 653
 654 sub daemon_loop ($) {
 655         my ($xnetd) = @_;
 656         my $refresh = sub {
 657                 my ($sig) = @_;
 658                 for my $xn (values %$xnetd) {
 659                         delete $xn->{tlsd}->{ssl_ctx}; # PublicInbox::TLS::start
 660                         eval { $xn->{refresh}->($sig) };
 661                         warn "refresh $@\n" if $@;
 662                 }
 663         };
 664         my %post_accept;
 665         while (my ($k, $ctx_opt) = each %tls_opt) {
 666                 my $l = $k;
 667                 $l =~ s!\A([^:]+)://!!;
 668                 my $scheme = $1 // '';
 669                 my $xn = $xnetd->{$l} // $xnetd->{''};
 670                 $xn->{tlsd}->{ssl_ctx_opt} //= $ctx_opt;
 671                 $scheme =~ m!\A(?:https|imaps|nntps|pop3s)! and
 672                         $post_accept{$l} = tls_cb(@$xn{qw(post_accept tlsd)});
 673         }
 674         my $sig = {
 675                 HUP => $refresh,
 676                 INT => \&worker_quit,
 677                 QUIT => \&worker_quit,
 678                 TERM => \&worker_quit,
 679                 TTIN => 'IGNORE',
 680                 TTOU => 'IGNORE',
 681                 USR1 => \&reopen_logs,
 682                 USR2 => 'IGNORE',
 683                 WINCH => 'IGNORE',
 684                 CHLD => \&PublicInbox::DS::enqueue_reap,
 685         };
 686         if ($worker_processes > 0) {
 687                 $refresh->(); # preload by default
 688                 my $fh = master_loop(); # returns if in child process
 689                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 690         } else {
 691                 reopen_logs();
 692                 $set_user->() if $set_user;
 693                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 694                 $refresh->();
 695         }
 696         $uid = $gid = undef;
 697         reopen_logs();
 698         @listeners = map {;
 699                 my $l = sockname($_);
 700                 my $tls_cb = $post_accept{$l};
 701                 my $xn = $xnetd->{$l} // $xnetd->{''};
 702
 703                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 704                 # IMAP, NNTP and POP3 are server-first
 705                 defer_accept($_, $tls_cb ? 'dataready' : $xn->{af_default});
 706
 707                 # this calls epoll_create:
 708                 PublicInbox::Listener->new($_, $tls_cb || $xn->{post_accept})
 709         } @listeners;
 710         PublicInbox::DS::event_loop($sig, $oldset);
 711 }
 712
 713 sub run {
 714         my ($default_listen) = @_;
 715         my $xnetd = {};
 716         if ($default_listen) {
 717                 $default_listen =~ /\A(http|imap|nntp|pop3)/ or
 718                         die "BUG: $default_listen";
 719                 $xnetd->{''} = load_mod($1);
 720         }
 721         daemon_prepare($default_listen, $xnetd);
 722         my $for_destroy = daemonize();
 723
 724         # localize GCF2C for tests:
 725         local $PublicInbox::GitAsyncCat::GCF2C;
 726         local $PublicInbox::Git::async_warn = 1;
 727         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 728
 729         daemon_loop($xnetd);
 730         PublicInbox::DS->Reset;
 731         # ->DESTROY runs when $for_destroy goes out-of-scope
 732 }
 733
 734 sub write_pid ($) {
 735         my ($path) = @_;
 736         Net::Server::Daemonize::create_pid_file($path);
 737         do_chown($path);
 738 }
 739
 740 sub DESTROY {
 741         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 742 }
 743
 744 1;