lib/PublicInbox/LeiMirror.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "lei add-external --mirror" support (also "public-inbox-clone");
   5 package PublicInbox::LeiMirror;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::IPC);
   9 use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
  10 use IO::Compress::Gzip qw(gzip $GzipError);
  11 use PublicInbox::Spawn qw(popen_rd spawn run_die);
  12 use File::Path ();
  13 use File::Temp ();
  14 use File::Spec ();
  15 use Fcntl qw(SEEK_SET O_CREAT O_EXCL O_WRONLY);
  16 use Carp qw(croak);
  17 use URI;
  18 use PublicInbox::Config;
  19 use PublicInbox::Inbox;
  20 use PublicInbox::LeiCurl;
  21 use PublicInbox::OnDestroy;
  22
  23 our $LIVE; # pid => callback
  24
  25 sub _wq_done_wait { # dwaitpid callback (via wq_eof)
  26         my ($arg, $pid) = @_;
  27         my ($mrr, $lei) = @$arg;
  28         my $f = "$mrr->{dst}/mirror.done";
  29         if ($?) {
  30                 $lei->child_error($?);
  31         } elsif (!$mrr->{dry_run} && !unlink($f)) {
  32                 warn("unlink($f): $!\n") unless $!{ENOENT};
  33         } else {
  34                 if (!$mrr->{dry_run} && $lei->{cmd} ne 'public-inbox-clone') {
  35                         # calls _finish_add_external
  36                         $lei->lazy_cb('add-external', '_finish_'
  37                                         )->($lei, $mrr->{dst});
  38                 }
  39                 $lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
  40         }
  41         $lei->dclose;
  42 }
  43
  44 # for old installations without manifest.js.gz
  45 sub try_scrape {
  46         my ($self) = @_;
  47         my $uri = URI->new($self->{src});
  48         my $lei = $self->{lei};
  49         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
  50         my $cmd = $curl->for_uri($lei, $uri, '--compressed');
  51         my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
  52         my $fh = popen_rd($cmd, undef, $opt);
  53         my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
  54         close($fh) or return $lei->child_error($?, "@$cmd failed");
  55
  56         # we grep with URL below, we don't want Subject/From headers
  57         # making us clone random URLs
  58         my @html = split(/<hr>/, $html);
  59         my @urls = ($html[-1] =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
  60         my $url = $uri->as_string;
  61         chop($url) eq '/' or die "BUG: $uri not canonicalized";
  62
  63         # since this is for old instances w/o manifest.js.gz, try v1 first
  64         return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
  65         if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
  66                 my %v2_epochs = map {
  67                         my ($n) = (m!/([0-9]+)\z!);
  68                         $n => [ URI->new($_), '' ]
  69                 } @v2_urls; # uniq
  70                 clone_v2($self, \%v2_epochs);
  71                 reap_live() while keys(%$LIVE);
  72                 return;
  73         }
  74
  75         # filter out common URLs served by WWW (e.g /$MSGID/T/)
  76         if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
  77                         grep(m!\A\Q$url\E/*\z!, @urls)) {
  78                 die <<"";
  79 E: confused by scraping <$uri>, did you mean <$url>?
  80
  81         }
  82         @urls and die <<"";
  83 E: confused by scraping <$uri>, got ambiguous results:
  84 @urls
  85
  86         die "E: scraping <$uri> revealed nothing\n";
  87 }
  88
  89 sub clone_cmd {
  90         my ($lei, $opt) = @_;
  91         my @cmd = qw(git);
  92         $opt->{$_} = $lei->{$_} for (0..2);
  93         # we support "-c $key=$val" for arbitrary git config options
  94         # e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
  95         push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
  96         push @cmd, qw(clone --mirror);
  97         push @cmd, '-q' if $lei->{opt}->{quiet} ||
  98                         ($lei->{opt}->{jobs} // 1) > 1;
  99         push @cmd, '-v' if $lei->{opt}->{verbose};
 100         # XXX any other options to support?
 101         # --reference is tricky with multiple epochs...
 102         @cmd;
 103 }
 104
 105 sub ft_rename ($$$) {
 106         my ($ft, $dst, $open_mode) = @_;
 107         my $fn = $ft->filename;
 108         my @st = stat($dst);
 109         my $mode = @st ? ($st[2] & 07777) : ($open_mode & ~umask);
 110         chmod($mode, $ft) or croak "E: chmod $fn: $!";
 111         require File::Copy;
 112         File::Copy::mv($fn, $dst) or croak "E: mv($fn => $ft): $!";
 113         $ft->unlink_on_destroy(0);
 114 }
 115
 116 sub _get_txt_start { # non-fatal
 117         my ($self, $endpoint, $fini) = @_;
 118         my $uri = URI->new($self->{cur_src} // $self->{src});
 119         my $lei = $self->{lei};
 120         my $path = $uri->path;
 121         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 122         $uri->path("$path/$endpoint");
 123         my $f = (split(m!/!, $endpoint))[-1];
 124         my $ft = File::Temp->new(TEMPLATE => "$f-XXXX", TMPDIR => 1);
 125         my $opt = { 0 => $lei->{0}, 1 => $lei->{1}, 2 => $lei->{2} };
 126         my $cmd = $self->{curl}->for_uri($lei, $uri, qw(--compressed -R -o),
 127                                         $ft->filename);
 128         my $jobs = $lei->{opt}->{jobs} // 1;
 129         reap_live() while keys(%$LIVE) >= $jobs;
 130         $lei->qerr("# @$cmd");
 131         return if $self->{dry_run};
 132         $self->{"-get_txt.$endpoint"} = [ $ft, $cmd, $uri ];
 133         $LIVE->{spawn($cmd, undef, $opt)} =
 134                         [ \&_get_txt_done, $self, $endpoint, $fini ];
 135 }
 136
 137 sub _get_txt_done { # returns true on error (non-fatal), undef on success
 138         my ($self, $endpoint) = @_;
 139         my ($fh, $cmd, $uri) = @{delete $self->{"-get_txt.$endpoint"}};
 140         my $cerr = $?;
 141         $? = 0; # don't influence normal lei exit
 142         return warn("$uri missing\n") if ($cerr >> 8) == 22;
 143         return warn("# @$cmd failed (non-fatal)\n") if $cerr;
 144         seek($fh, SEEK_SET, 0) or die "seek: $!";
 145         $self->{"mtime.$endpoint"} = (stat($fh))[9];
 146         local $/;
 147         $self->{"txt.$endpoint"} = <$fh>;
 148         undef; # success
 149 }
 150
 151 sub _write_inbox_config {
 152         my ($self) = @_;
 153         my $buf = delete($self->{'txt._/text/config/raw'}) // return;
 154         my $dst = $self->{cur_dst} // $self->{dst};
 155         my $f = "$dst/inbox.config.example";
 156         open my $fh, '>', $f or die "open($f): $!";
 157         print $fh $buf or die "print: $!";
 158         chmod(0444 & ~umask, $fh) or die "chmod($f): $!";
 159         my $mtime = delete $self->{'mtime._/text/config/raw'};
 160         $fh->flush or die "flush($f): $!";
 161         if (defined $mtime) {
 162                 utime($mtime, $mtime, $fh) or die "utime($f): $!";
 163         }
 164         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{lei}->{2});
 165         my $ibx = $self->{ibx} = {};
 166         for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
 167                 for (qw(address newsgroup nntpmirror)) {
 168                         $ibx->{$_} = $cfg->{"$sec.$_"};
 169                 }
 170         }
 171 }
 172
 173 sub set_description ($) {
 174         my ($self) = @_;
 175         my $dst = $self->{cur_dst} // $self->{dst};
 176         my $f = "$dst/description";
 177         open my $fh, '+>>', $f or die "open($f): $!";
 178         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 179         my $d = do { local $/; <$fh> } // die "read($f): $!";
 180         my $orig = $d;
 181         while (defined($d) && ($d =~ m!^\(\$INBOX_DIR/description missing\)! ||
 182                         $d =~ /^Unnamed repository/ || $d !~ /\S/)) {
 183                 $d = delete($self->{'txt.description'});
 184         }
 185         $d //= 'mirror of '.($self->{cur_src} // $self->{src})."\n";
 186         return if $d eq $orig;
 187         seek($fh, 0, SEEK_SET) or die "seek($f): $!";
 188         truncate($fh, 0) or die "truncate($f): $!";
 189         print $fh $d or die "print($f): $!";
 190         close $fh or die "close($f): $!";
 191 }
 192
 193 sub index_cloned_inbox {
 194         my ($self, $iv) = @_;
 195         my $lei = $self->{lei};
 196         eval { set_description($self) };
 197         warn $@ if $@;
 198
 199         # n.b. public-inbox-clone works w/o (SQLite || Xapian)
 200         # lei is useless without Xapian + SQLite
 201         if ($lei->{cmd} ne 'public-inbox-clone') {
 202                 require PublicInbox::InboxWritable;
 203                 require PublicInbox::Admin;
 204                 my $ibx = delete($self->{ibx}) // {
 205                         address => [ 'lei@example.com' ],
 206                         version => $iv,
 207                 };
 208                 $ibx->{inboxdir} = $self->{cur_dst} // $self->{dst};
 209                 PublicInbox::Inbox->new($ibx);
 210                 PublicInbox::InboxWritable->new($ibx);
 211                 my $opt = {};
 212                 for my $sw ($lei->index_opt) {
 213                         my ($k) = ($sw =~ /\A([\w-]+)/);
 214                         $opt->{$k} = $lei->{opt}->{$k};
 215                 }
 216                 # force synchronous dwaitpid for v2:
 217                 local $PublicInbox::DS::in_loop = 0;
 218                 my $cfg = PublicInbox::Config->new(undef, $lei->{2});
 219                 my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
 220                 local %ENV = (%ENV, %$env) if $env;
 221                 PublicInbox::Admin::progress_prepare($opt, $lei->{2});
 222                 PublicInbox::Admin::index_inbox($ibx, undef, $opt);
 223         }
 224         return if defined $self->{cur_dst};
 225         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 226 }
 227
 228 sub run_reap {
 229         my ($lei, $cmd, $opt) = @_;
 230         $lei->qerr("# @$cmd");
 231         waitpid(spawn($cmd, undef, $opt), 0) // die "waitpid: $!";
 232         my $ret = $?;
 233         $? = 0; # don't let it influence normal exit
 234         $ret;
 235 }
 236
 237 sub start_clone {
 238         my ($self, $cmd, $opt, $fini) = @_;
 239         my $jobs = $self->{lei}->{opt}->{jobs} // 1;
 240         reap_live() while keys(%$LIVE) >= $jobs;
 241         $self->{lei}->qerr("# @$cmd");
 242         return if $self->{dry_run};
 243         $LIVE->{spawn($cmd, undef, $opt)} = [ \&reap_clone, $self, $cmd, $fini ]
 244 }
 245
 246 sub clone_v1 {
 247         my ($self, $nohang) = @_;
 248         my $lei = $self->{lei};
 249         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 250         my $uri = URI->new($self->{cur_src} // $self->{src});
 251         defined($lei->{opt}->{epoch}) and
 252                 die "$uri is a v1 inbox, --epoch is not supported\n";
 253         my $pfx = $curl->torsocks($lei, $uri) or return;
 254         my $dst = $self->{cur_dst} // $self->{dst};
 255         my $fini = PublicInbox::OnDestroy->new($$, \&v1_done, $self);
 256         my $cmd = [ @$pfx, clone_cmd($lei, my $opt = {}), "$uri", $dst ];
 257         my $ref = $self->{-ent} ? $self->{-ent}->{reference} : undef;
 258         defined($ref) && -e "$self->{dst}$ref" and
 259                 push @$cmd, '--reference', "$self->{dst}$ref";
 260         start_clone($self, $cmd, $opt, $fini);
 261
 262         _get_txt_start($self, '_/text/config/raw', $fini);
 263         my $d = $self->{-ent} ? $self->{-ent}->{description} : undef;
 264         defined($d) ? ($self->{'txt.description'} = $d) :
 265                 _get_txt_start($self, 'description', $fini);
 266
 267         reap_live() until ($nohang || !keys(%$LIVE)); # for non-manifest clone
 268 }
 269
 270 sub parse_epochs ($$) {
 271         my ($opt_epochs, $v2_epochs) = @_; # $epochs "LOW..HIGH"
 272         $opt_epochs // return; # undef => all epochs
 273         my ($lo, $dotdot, $hi, @extra) = split(/(\.\.)/, $opt_epochs);
 274         undef($lo) if ($lo // '') eq '';
 275         my $re = qr/\A~?[0-9]+\z/;
 276         if (@extra || (($lo // '0') !~ $re) ||
 277                         (($hi // '0') !~ $re) ||
 278                         !(grep(defined, $lo, $hi))) {
 279                 die <<EOM;
 280 --epoch=$opt_epochs not in the form of `LOW..HIGH', `LOW..', nor `..HIGH'
 281 EOM
 282         }
 283         my @n = sort { $a <=> $b } keys %$v2_epochs;
 284         for (grep(defined, $lo, $hi)) {
 285                 if (/\A[0-9]+\z/) {
 286                         $_ > $n[-1] and die
 287 "`$_' exceeds maximum available epoch ($n[-1])\n";
 288                         $_ < $n[0] and die
 289 "`$_' is lower than minimum available epoch ($n[0])\n";
 290                 } elsif (/\A~([0-9]+)/) {
 291                         my $off = -$1 - 1;
 292                         $n[$off] // die "`$_' is out of range\n";
 293                         $_ = $n[$off];
 294                 } else { die "`$_' not understood\n" }
 295         }
 296         defined($lo) && defined($hi) && $lo > $hi and die
 297 "low value (`$lo') exceeds high (`$hi')\n";
 298         $lo //= $n[0] if $dotdot;
 299         $hi //= $n[-1] if $dotdot;
 300         $hi //= $lo;
 301         my $want = {};
 302         for ($lo..$hi) {
 303                 if (defined $v2_epochs->{$_}) {
 304                         $want->{$_} = 1;
 305                 } else {
 306                         warn
 307 "# epoch $_ is not available (non-fatal, $lo..$hi)\n";
 308                 }
 309         }
 310         $want
 311 }
 312
 313 sub init_placeholder ($$$) {
 314         my ($src, $edst, $ent) = @_;
 315         PublicInbox::Import::init_bare($edst);
 316         my $f = "$edst/config";
 317         open my $fh, '>>', $f or die "open($f): $!";
 318         print $fh <<EOM or die "print($f): $!";
 319 [remote "origin"]
 320         url = $src
 321         fetch = +refs/*:refs/*
 322         mirror = true
 323
 324 ; This git epoch was created read-only and "public-inbox-fetch"
 325 ; will not fetch updates for it unless write permission is added.
 326 ; Hint: chmod +w $edst
 327 EOM
 328         if (defined($ent->{owner})) {
 329                 print $fh <<EOM or die "print($f): $!";
 330 [gitweb]
 331         owner = $ent->{owner}
 332 EOM
 333         }
 334         close $fh or die "close($f): $!";
 335         if (defined $ent->{head}) {
 336                 $f = "$edst/HEAD";
 337                 open $fh, '>', $f or die "open($f): $!";
 338                 print $fh $ent->{head}, "\n" or die "print($f): $!";
 339                 close $fh or die "close($f): $!";
 340         }
 341 }
 342
 343 sub reap_clone { # async, called via SIGCHLD
 344         my ($self, $cmd) = @_;
 345         my $cerr = $?;
 346         $? = 0; # don't let it influence normal exit
 347         if ($cerr) {
 348                 kill('TERM', keys %$LIVE);
 349                 $self->{lei}->child_error($cerr, "@$cmd failed");
 350         }
 351 }
 352
 353 sub v1_done { # called via OnDestroy
 354         my ($self) = @_;
 355         return if $self->{dry_run} || !$LIVE;
 356         _write_inbox_config($self);
 357         my $dst = $self->{cur_dst} // $self->{dst};
 358         if (defined(my $o = $self->{-ent} ? $self->{-ent}->{owner} : undef)) {
 359                 run_die([qw(git config -f), "$dst/config", 'gitweb.owner', $o]);
 360         }
 361         my $o = "$dst/objects";
 362         if (open(my $fh, '<', "$o/info/alternates")) {
 363                 chomp(my @l = <$fh>);
 364                 for (@l) { $_ = File::Spec->abs2rel($_, $o)."\n" }
 365                 my $f = File::Temp->new(TEMPLATE => '.XXXX', DIR => "$o/info");
 366                 print $f @l;
 367                 $f->flush or die "flush($f): $!";
 368                 rename($f->filename, "$o/info/alternates") or
 369                         die "rename($f, $o/info/alternates): $!";
 370                 $f->unlink_on_destroy(0);
 371         }
 372         write_makefile($dst, 1);
 373         index_cloned_inbox($self, 1);
 374 }
 375
 376 sub v2_done { # called via OnDestroy
 377         my ($self) = @_;
 378         return if $self->{dry_run} || !$LIVE;
 379         _write_inbox_config($self);
 380         require PublicInbox::MultiGit;
 381         my $dst = $self->{cur_dst} // $self->{dst};
 382         my $mg = PublicInbox::MultiGit->new($dst, 'all.git', 'git');
 383         $mg->fill_alternates;
 384         for my $i ($mg->git_epochs) { $mg->epoch_cfg_set($i) }
 385         my $edst_owner = delete($self->{-owner}) // [];
 386         while (@$edst_owner) {
 387                 my ($edst, $o) = splice(@$edst_owner);
 388                 run_die [qw(git config -f), "$edst/config", 'gitweb.owner', $o];
 389         }
 390         for my $edst (@{delete($self->{-read_only}) // []}) {
 391                 my @st = stat($edst) or die "stat($edst): $!";
 392                 chmod($st[2] & 0555, $edst) or die "chmod(a-w, $edst): $!";
 393         }
 394         write_makefile($dst, 2);
 395         delete $self->{-locked} // die "BUG: $dst not locked"; # unlock
 396         index_cloned_inbox($self, 2);
 397 }
 398
 399 sub reap_live {
 400         my $pid = waitpid(-1, 0) // die "waitpid(-1): $!";
 401         if (my $x = delete $LIVE->{$pid}) {
 402                 my $cb = shift @$x;
 403                 $cb->(@$x);
 404         } else {
 405                 warn "reaped unknown PID=$pid ($?)\n";
 406         }
 407 }
 408
 409 sub clone_v2 ($$;$) {
 410         my ($self, $v2_epochs, $m) = @_; # $m => manifest.js.gz hashref
 411         my $lei = $self->{lei};
 412         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 413         my $first_uri = (map { $_->[0] } values %$v2_epochs)[0];
 414         my $pfx = $curl->torsocks($lei, $first_uri) or return;
 415         my $dst = $self->{cur_dst} // $self->{dst};
 416         my $want = parse_epochs($lei->{opt}->{epoch}, $v2_epochs);
 417         my $task = $m ? bless { %$self }, __PACKAGE__ : $self;
 418         my (@src_edst, @skip);
 419         for my $nr (sort { $a <=> $b } keys %$v2_epochs) {
 420                 my ($uri, $key) = @{$v2_epochs->{$nr}};
 421                 my $src = $uri->as_string;
 422                 my $edst = $dst;
 423                 $src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
 424 failed to extract epoch number from $src
 425
 426                 $1 + 0 == $nr or die "BUG: <$uri> miskeyed $1 != $nr";
 427                 $edst .= "/git/$nr.git";
 428                 $m->{$key} // die "BUG: `$key' not in manifest.js.gz";
 429                 if (!$want || $want->{$nr}) {
 430                         push @src_edst, $src, $edst;
 431                         my $o = $m->{$key}->{owner};
 432                         push(@{$task->{-owner}}, $edst, $o) if defined($o);
 433                 } else { # create a placeholder so users only need to chmod +w
 434                         init_placeholder($src, $edst, $m->{$key});
 435                         push @{$task->{-read_only}}, $edst;
 436                         push @skip, $key;
 437                 }
 438         }
 439         # filter out the epochs we skipped
 440         $self->{-culled_manifest} = 1 if delete(@$m{@skip});
 441
 442         (!$self->{dry_run} && !-d $dst) and File::Path::mkpath($dst);
 443
 444         require PublicInbox::Lock;
 445         my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
 446         my $fini = PublicInbox::OnDestroy->new($$, \&v2_done, $task);
 447
 448         _get_txt_start($task, '_/text/config/raw', $fini);
 449         _get_txt_start($self, 'description', $fini);
 450
 451         $task->{-locked} = $lk->lock_for_scope($$) if !$self->{dry_run};
 452         my @cmd = clone_cmd($lei, my $opt = {});
 453         while (@src_edst && !$lei->{child_error}) {
 454                 my $cmd = [ @$pfx, @cmd, splice(@src_edst, 0, 2) ];
 455                 start_clone($self, $cmd, $opt, $fini);
 456         }
 457 }
 458
 459 sub decode_manifest ($$$) {
 460         my ($fh, $fn, $uri) = @_;
 461         my $js;
 462         my $gz = do { local $/; <$fh> } // die "slurp($fn): $!";
 463         gunzip(\$gz => \$js, MultiStream => 1) or
 464                 die "gunzip($uri): $GunzipError\n";
 465         my $m = eval { PublicInbox::Config->json->decode($js) };
 466         die "$uri: error decoding `$js': $@\n" if $@;
 467         ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);
 468         $m;
 469 }
 470
 471 sub multi_inbox ($$$) {
 472         my ($self, $path, $m) = @_;
 473         my $incl = $self->{lei}->{opt}->{include};
 474         my $excl = $self->{lei}->{opt}->{exclude};
 475
 476         # assuming everything not v2 is v1, for now
 477         my @v1 = sort grep(!m!.+/git/[0-9]+\.git\z!, keys %$m);
 478         my @v2_epochs = sort grep(m!.+/git/[0-9]+\.git\z!, keys %$m);
 479         my $v2 = {};
 480
 481         for (@v2_epochs) {
 482                 m!\A(/.+)/git/[0-9]+\.git\z! or die "BUG: $_";
 483                 push @{$v2->{$1}}, $_;
 484         }
 485         my $n = scalar(keys %$v2) + scalar(@v1);
 486         my @orig = defined($incl // $excl) ? (keys %$v2, @v1) : ();
 487         if (defined $incl) {
 488                 my $re = '(?:'.join('|', map {
 489                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E\z/
 490                         } @$incl).')';
 491                 my @gone = delete @$v2{grep(!/$re/, keys %$v2)};
 492                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 493                 delete @$m{grep(!/$re/, @v1)} and $self->{-culled_manifest} = 1;
 494                 @v1 = grep(/$re/, @v1);
 495         }
 496         if (defined $excl) {
 497                 my $re = '(?:'.join('|', map {
 498                                 $self->{lei}->glob2re($_) // qr/\A\Q$_\E\z/
 499                         } @$excl).')';
 500                 my @gone = delete @$v2{grep(/$re/, keys %$v2)};
 501                 delete @$m{map { @$_ } @gone} and $self->{-culled_manifest} = 1;
 502                 delete @$m{grep(/$re/, @v1)} and $self->{-culled_manifest} = 1;
 503                 @v1 = grep(!/$re/, @v1);
 504         }
 505         my $ret; # { v1 => [ ... ], v2 => { "/$inbox_name" => [ epochs ] }}
 506         $ret->{v1} = \@v1 if @v1;
 507         $ret->{v2} = $v2 if keys %$v2;
 508         $ret //= @orig ? "Nothing to clone, available repositories:\n\t".
 509                                 join("\n\t", sort @orig)
 510                         : "Nothing available to clone\n";
 511         my $path_pfx = '';
 512
 513         # PSGI mount prefixes and manifest.js.gz prefixes don't always align...
 514         if (@v2_epochs) {
 515                 until (grep(m!\A\Q$$path\E/git/[0-9]+\.git\z!,
 516                                 @v2_epochs) == @v2_epochs) {
 517                         $$path =~ s!\A(/[^/]+)/!/! or last;
 518                         $path_pfx .= $1;
 519                 }
 520         } elsif (@v1) {
 521                 while (!defined($m->{$$path}) && $$path =~ s!\A(/[^/]+)/!/!) {
 522                         $path_pfx .= $1;
 523                 }
 524         }
 525         ($path_pfx, $n, $ret);
 526 }
 527
 528 sub clone_all {
 529         my ($self, $todo, $m) = @_;
 530         # handle no-dependency repos, first
 531         for (@{delete($todo->{''}) // []}) {
 532                 clone_v1($_, 1);
 533                 return if $self->{lei}->{child_error};
 534         }
 535         # resolve references, deepest, first:
 536         while (scalar keys %$todo) {
 537                 for my $x (keys %$todo) {
 538                         # resolve multi-level references
 539                         while (defined($m->{$x}->{reference})) {
 540                                 $x = $m->{$x}->{reference};
 541                         }
 542                         my $y = delete $todo->{$x} // next; # already done
 543                         for (@$y) {
 544                                 clone_v1($_, 1);
 545                                 return if $self->{lei}->{child_error};
 546                         }
 547                         last; # restart %$todo iteration
 548                 }
 549         }
 550 }
 551
 552 # FIXME: this gets confused by single inbox instance w/ global manifest.js.gz
 553 sub try_manifest {
 554         my ($self) = @_;
 555         my $uri = URI->new($self->{src});
 556         my $lei = $self->{lei};
 557         my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
 558         my $path = $uri->path;
 559         chop($path) eq '/' or die "BUG: $uri not canonicalized";
 560         $uri->path($path . '/manifest.js.gz');
 561         my $ft = File::Temp->new(TEMPLATE => '.manifest-XXXX',
 562                                 UNLINK => 1, TMPDIR => 1, SUFFIX => '.tmp');
 563         my $fn = $ft->filename;
 564         my $cmd = $curl->for_uri($lei, $uri, '-R', '-o', $fn);
 565         my %opt = map { $_ => $lei->{$_} } (0..2);
 566         my $cerr = run_reap($lei, $cmd, \%opt);
 567         local $LIVE;
 568         if ($cerr) {
 569                 return try_scrape($self) if ($cerr >> 8) == 22; # 404 missing
 570                 return $lei->child_error($cerr, "@$cmd failed");
 571         }
 572         my $m = eval { decode_manifest($ft, $fn, $uri) };
 573         if ($@) {
 574                 warn $@;
 575                 return try_scrape($self);
 576         }
 577         my ($path_pfx, $n, $multi) = multi_inbox($self, \$path, $m);
 578         return $lei->child_error(1, $multi) if !ref($multi);
 579         if (my $v2 = delete $multi->{v2}) {
 580                 for my $name (sort keys %$v2) {
 581                         my $epochs = delete $v2->{$name};
 582                         my %v2_epochs = map {
 583                                 $uri->path($n > 1 ? $path_pfx.$path.$_
 584                                                 : $path_pfx.$_);
 585                                 my ($e) = ("$uri" =~ m!/([0-9]+)\.git\z!);
 586                                 $e // die "no [0-9]+\.git in `$uri'";
 587                                 $e => [ $uri->clone, $_ ];
 588                         } @$epochs;
 589                         ("$uri" =~ m!\A(.+/)git/[0-9]+\.git\z!) or
 590                                 die "BUG: `$uri' !~ m!/git/[0-9]+.git!";
 591                         local $self->{cur_src} = $1;
 592                         local $self->{cur_dst} = $self->{dst};
 593                         if ($n > 1 && $uri->path =~ m!\A\Q$path_pfx$path\E/(.+)/
 594                                                         git/[0-9]+\.git\z!x) {
 595                                 $self->{cur_dst} .= "/$1";
 596                         }
 597                         index($self->{cur_dst}, "\n") >= 0 and die <<EOM;
 598 E: `$self->{cur_dst}' must not contain newline
 599 EOM
 600                         clone_v2($self, \%v2_epochs, $m);
 601                         return if $self->{lei}->{child_error};
 602                 }
 603         }
 604         if (my $v1 = delete $multi->{v1}) {
 605                 my $p = $path_pfx.$path;
 606                 chop($p) if substr($p, -1, 1) eq '/';
 607                 $uri->path($p);
 608                 my $todo = {};
 609                 my %want = map { $_ => 1 } @$v1;
 610                 for my $name (@$v1) {
 611                         my $task = bless { %$self }, __PACKAGE__;
 612                         $task->{-ent} = $m->{$name} //
 613                                         die("BUG: no `$name' in manifest");
 614                         $task->{cur_src} = "$uri";
 615                         $task->{cur_dst} = $task->{dst};
 616                         if ($n > 1) {
 617                                 $task->{cur_dst} .= $name;
 618                                 $task->{cur_src} .= $name;
 619                         }
 620                         index($task->{cur_dst}, "\n") >= 0 and die <<EOM;
 621 E: `$task->{cur_dst}' must not contain newline
 622 EOM
 623                         $task->{cur_src} .= '/';
 624                         my $dep = $task->{-ent}->{reference} // '';
 625                         $dep = '' if !$want{$dep};
 626                         push @{$todo->{$dep}}, $task;
 627                 }
 628                 clone_all($self, $todo, $m);
 629         }
 630         reap_live() while keys(%$LIVE);
 631         return if $self->{lei}->{child_error} || $self->{dry_run};
 632
 633         if (delete $self->{-culled_manifest}) { # set by clone_v2/-I/--exclude
 634                 # write the smaller manifest if epochs were skipped so
 635                 # users won't have to delete manifest if they +w an
 636                 # epoch they no longer want to skip
 637                 my $json = PublicInbox::Config->json->encode($m);
 638                 my $mtime = (stat($fn))[9];
 639                 gzip(\$json => $fn) or die "gzip: $GzipError";
 640                 utime($mtime, $mtime, $fn) or die "utime(..., $fn): $!";
 641         }
 642         ft_rename($ft, "$self->{dst}/manifest.js.gz", 0666);
 643         open my $x, '>', "$self->{dst}/mirror.done"; # for _wq_done_wait
 644 }
 645
 646 sub start_clone_url {
 647         my ($self) = @_;
 648         return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
 649         die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
 650 }
 651
 652 sub do_mirror { # via wq_io_do
 653         my ($self) = @_;
 654         my $lei = $self->{lei};
 655         umask($lei->{client_umask}) if defined $lei->{client_umask};
 656         eval {
 657                 my $iv = $lei->{opt}->{'inbox-version'};
 658                 if (defined $iv) {
 659                         local $LIVE;
 660                         return clone_v1($self) if $iv == 1;
 661                         return try_scrape($self) if $iv == 2;
 662                         die "bad --inbox-version=$iv\n";
 663                 }
 664                 return start_clone_url($self) if $self->{src} =~ m!://!;
 665                 die "TODO: cloning local directories not supported, yet";
 666         };
 667         $lei->fail($@) if $@;
 668 }
 669
 670 sub start {
 671         my ($cls, $lei, $src, $dst) = @_;
 672         my $self = bless { src => $src, dst => $dst }, $cls;
 673         $lei->request_umask;
 674         my ($op_c, $ops) = $lei->workers_start($self, 1);
 675         $lei->{wq1} = $self;
 676         $self->wq_io_do('do_mirror', []);
 677         $self->wq_close;
 678         $lei->wait_wq_events($op_c, $ops);
 679 }
 680
 681 sub ipc_atfork_child {
 682         my ($self) = @_;
 683         $self->{lei}->_lei_atfork_child;
 684         $self->SUPER::ipc_atfork_child;
 685 }
 686
 687 sub write_makefile {
 688         my ($dir, $ibx_ver) = @_;
 689         my $f = "$dir/Makefile";
 690         if (sysopen my $fh, $f, O_CREAT|O_EXCL|O_WRONLY) {
 691                 print $fh <<EOM or die "print($f) $!";
 692 # This is a v$ibx_ver public-inbox, see the public-inbox-v$ibx_ver-format(5)
 693 # manpage for more information on the format.  This Makefile is
 694 # intended as a familiar wrapper for users unfamiliar with
 695 # public-inbox-* commands.
 696 #
 697 # See the respective manpages for public-inbox-fetch(1),
 698 # public-inbox-index(1), etc for more information on
 699 # some of the commands used by this Makefile.
 700 #
 701 # This Makefile will not be modified nor read by public-inbox,
 702 # so you may edit it freely with your own convenience targets
 703 # and notes.  public-inbox-fetch will recreate it if removed.
 704 EOM
 705                 print $fh <<'EOM' or die "print($f): $!";
 706 # the default target:
 707 help :
 708         @echo Common targets:
 709         @echo '    make fetch        - fetch from remote git repostorie(s)'
 710         @echo '    make update       - fetch and update index '
 711         @echo
 712         @echo Rarely needed targets:
 713         @echo '    make reindex      - may be needed for new features/bugfixes'
 714         @echo '    make compact      - rewrite Xapian storage to save space'
 715
 716 fetch :
 717         public-inbox-fetch
 718 update :
 719         @if ! public-inbox-fetch --exit-code; \
 720         then \
 721                 c=$$?; \
 722                 test $$c -eq 127 && exit 0; \
 723                 exit $$c; \
 724         elif test -f msgmap.sqlite3 || test -f public-inbox/msgmap.sqlite3; \
 725         then \
 726                 public-inbox-index; \
 727         else \
 728                 echo 'public-inbox index not initialized'; \
 729                 echo 'see public-inbox-index(1) man page'; \
 730         fi
 731 reindex :
 732         public-inbox-index --reindex
 733 compact :
 734         public-inbox-compact
 735
 736 .PHONY : help fetch update reindex compact
 737 EOM
 738                 close $fh or die "close($f): $!";
 739         } else {
 740                 die "open($f): $!" unless $!{EEXIST};
 741         }
 742 }
 743
 744 1;