lib/PublicInbox/View.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use v5.10.1;
   9 use List::Util qw(max);
  10 use Text::Wrap qw(wrap); # stdlib, we need Perl 5.6+ for $huge
  11 use PublicInbox::MsgTime qw(msg_datestamp);
  12 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href
  13                         ts2str fmt_ts);
  14 use PublicInbox::Linkify;
  15 use PublicInbox::MID qw(id_compress mids mids_for_index references
  16                         $MID_EXTRACT);
  17 use PublicInbox::MsgIter;
  18 use PublicInbox::Address;
  19 use PublicInbox::WwwStream qw(html_oneshot);
  20 use PublicInbox::Reply;
  21 use PublicInbox::ViewDiff qw(flush_diff);
  22 use PublicInbox::Eml;
  23 use POSIX qw(strftime);
  24 use Time::Local qw(timegm);
  25 use PublicInbox::Smsg qw(subject_normalized);
  26 use PublicInbox::ContentHash qw(content_hash);
  27 use constant COLS => 72;
  28 use constant INDENT => '  ';
  29 use constant TCHILD => '` ';
  30 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  31
  32 sub msg_page_i {
  33         my ($ctx, $eml) = @_;
  34         if ($eml) { # called by WwwStream::async_eml or getline
  35                 my $smsg = $ctx->{smsg};
  36                 my $over = $ctx->{ibx}->over;
  37                 $ctx->{smsg} = $over ? $over->next_by_mid(@{$ctx->{next_arg}})
  38                                 : $ctx->gone('over');
  39                 $ctx->{mhref} = ($ctx->{nr} || $ctx->{smsg}) ?
  40                                 "../${\mid_href($smsg->{mid})}/" : '';
  41                 if (_msg_page_prepare_obuf($eml, $ctx)) {
  42                         multipart_text_as_html($eml, $ctx);
  43                         ${$ctx->{obuf}} .= '</pre><hr>';
  44                 }
  45                 html_footer($ctx, $ctx->{first_hdr}) if !$ctx->{smsg};
  46                 delete($ctx->{obuf}) // \'';
  47         } else { # called by WwwStream::async_next or getline
  48                 $ctx->{smsg}; # may be undef
  49         }
  50 }
  51
  52 # /$INBOX/$MSGID/ for unindexed v1 inboxes
  53 sub no_over_html ($) {
  54         my ($ctx) = @_;
  55         my $bref = $ctx->{ibx}->msg_by_mid($ctx->{mid}) or return; # 404
  56         my $eml = PublicInbox::Eml->new($bref);
  57         $ctx->{mhref} = '';
  58         PublicInbox::WwwStream::init($ctx);
  59         if (_msg_page_prepare_obuf($eml, $ctx)) { # sets {-title_html}
  60                 multipart_text_as_html($eml, $ctx);
  61                 ${$ctx->{obuf}} .= '</pre><hr>';
  62         }
  63         html_footer($ctx, $eml);
  64         $ctx->html_done;
  65 }
  66
  67 # public functions: (unstable)
  68
  69 sub msg_page {
  70         my ($ctx) = @_;
  71         my $ibx = $ctx->{ibx};
  72         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  73         my $over = $ibx->over or return no_over_html($ctx);
  74         my ($id, $prev);
  75         my $next_arg = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  76
  77         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$next_arg) or
  78                 return; # undef == 404
  79
  80         # allow user to easily browse the range around this message if
  81         # they have ->over
  82         $ctx->{-t_max} = $smsg->{ts};
  83         PublicInbox::WwwStream::aresponse($ctx, \&msg_page_i);
  84 }
  85
  86 # /$INBOX/$MESSAGE_ID/#R
  87 sub msg_reply ($$) {
  88         my ($ctx, $hdr) = @_;
  89         my $se_url =
  90          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  91         my $p_url =
  92          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  93
  94         my $info = '';
  95         my $ibx = $ctx->{ibx};
  96         if (my $url = $ibx->{infourl}) {
  97                 $url = prurl($ctx->{env}, $url);
  98                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  99         }
 100
 101         my ($arg, $link, $reply_to_all) =
 102                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 103         if (ref($arg) eq 'SCALAR') {
 104                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 105         }
 106
 107         # mailto: link only works if address obfuscation is disabled
 108         if ($link) {
 109                 $link = <<EOF;
 110
 111 * If your mail client supports setting the <b>In-Reply-To</b> header
 112   via mailto: links, try the <a
 113 href="$link">mailto: link</a>
 114 EOF
 115         }
 116
 117         push @$arg, '/path/to/YOUR_REPLY';
 118         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 119         <<EOF
 120 <hr><pre
 121 id=R><b>Reply instructions:</b>
 122
 123 You may reply publicly to <a
 124 href=#t>this message</a> via plain-text email
 125 using any one of the following methods:
 126
 127 * Save the following mbox file, import it into your mail client,
 128   and $reply_to_all from there: <a
 129 href=raw>mbox</a>
 130
 131   Avoid top-posting and favor interleaved quoting:
 132   <a
 133 href="$p_url">$p_url</a>
 134 $info
 135 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 136   switches of git-send-email(1):
 137
 138   git send-email$arg
 139
 140   <a
 141 href="$se_url">$se_url</a>
 142 $link</pre>
 143
 144   Be sure your reply has a <b>Subject:</b> header at the top and a blank line
 145   before the message body.
 146 EOF
 147 }
 148
 149 sub in_reply_to {
 150         my ($hdr) = @_;
 151         my $refs = references($hdr);
 152         $refs->[-1];
 153 }
 154
 155 sub fold_addresses ($) {
 156         return $_[0] if length($_[0]) <= COLS;
 157         # try to fold on commas after non-word chars before $lim chars,
 158         # Try to get the "," preceded by ">" or ")", but avoid folding
 159         # on the comma where somebody uses "Lastname, Firstname".
 160         # We also try to keep the last and penultimate addresses in
 161         # the list on the same line if possible, hence the extra \z
 162         # Fall back to folding on spaces at $lim + 1 chars
 163         my $lim = COLS - 8; # 8 = "\t" display width
 164         my $too_long = $lim + 1;
 165         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 166         $_[0] = join("\n\t",
 167                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 168                                 .{1,$lim}(?:,|\z)|
 169                                 .{1,$lim}|
 170                                 .{$too_long,}?)(?:\s|\z)/xgo));
 171 }
 172
 173 sub _hdr_names_html ($$) {
 174         my ($hdr, $field) = @_;
 175         my @vals = $hdr->header($field) or return '';
 176         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 177 }
 178
 179 sub nr_to_s ($$$) {
 180         my ($nr, $singular, $plural) = @_;
 181         return "0 $plural" if $nr == 0;
 182         $nr == 1 ? "$nr $singular" : "$nr $plural";
 183 }
 184
 185 # Displays the text of of the message for /$INBOX/$MSGID/[Tt]/ endpoint
 186 # this is already inside a <pre>
 187 sub eml_entry {
 188         my ($ctx, $eml) = @_;
 189         my $smsg = delete $ctx->{smsg};
 190         my $subj = delete $smsg->{subject};
 191         my $mid_raw = $smsg->{mid};
 192         my $id = id_compress($mid_raw, 1);
 193         my $id_m = 'm'.$id;
 194         my $root_anchor = $ctx->{root_anchor} || '';
 195         my $irt;
 196         my $obfs_ibx = $ctx->{-obfs_ibx};
 197
 198         $subj = '(no subject)' if $subj eq '';
 199         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 200         $subj = '<b>'.ascii_html($subj).'</b>';
 201         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 202         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 203         $rv .= $subj . "\n";
 204         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 205         my @tocc;
 206         my $ds = delete $smsg->{ds}; # for v1 non-Xapian/SQLite users
 207
 208         # Deleting these fields saves about 400K as we iterate across 1K msgs
 209         delete @$smsg{qw(ts blob)};
 210
 211         my $from = _hdr_names_html($eml, 'From');
 212         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 213         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 214         my $upfx = $ctx->{-upfx};
 215         my $mhref = $upfx . mid_href($mid_raw) . '/';
 216         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 217         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 218         my $to = fold_addresses(_hdr_names_html($eml, 'To'));
 219         my $cc = fold_addresses(_hdr_names_html($eml, 'Cc'));
 220         my ($tlen, $clen) = (length($to), length($cc));
 221         my $to_cc = '';
 222         if (($tlen + $clen) > COLS) {
 223                 $to_cc .= '  To: '.$to."\n" if $tlen;
 224                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 225         } else {
 226                 if ($tlen) {
 227                         $to_cc .= '  To: '.$to;
 228                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 229                 } else {
 230                         $to_cc .= '  Cc: '.$cc if $clen;
 231                 }
 232                 $to_cc .= "\n";
 233         }
 234         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 235         $rv .= $to_cc;
 236
 237         my $mapping = $ctx->{mapping};
 238         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($eml)))) {
 239                 my $href = $upfx . mid_href($irt) . '/';
 240                 my $html = ascii_html($irt);
 241                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 242         }
 243         $rv .= "\n";
 244
 245         # scan through all parts, looking for displayable text
 246         $ctx->{mhref} = $mhref;
 247         $ctx->{changed_href} = "#e$id"; # for diffstat "files? changed,"
 248         $ctx->{obuf} = \$rv;
 249         $eml->each_part(\&add_text_body, $ctx, 1); # expensive
 250         $ctx->zmore; # TODO: remove once add_text_body is updated
 251
 252         # add the footer
 253         $rv = "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 254                 "<a\nhref=\"$mhref\">permalink</a>" .
 255                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 256                 " <a\nhref=\"${mhref}#R\">reply</a>";
 257
 258         delete($ctx->{-qry}) and
 259                 $rv .= qq[ <a\nhref="${mhref}#related">related</a>];
 260
 261         my $hr;
 262         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 263                 $rv .= "\t[relevance $pct%]";
 264                 $hr = 1;
 265         } elsif ($mapping) {
 266                 my $nested = 'nested';
 267                 my $flat = 'flat';
 268                 if ($ctx->{flat}) {
 269                         $hr = 1;
 270                         $flat = "<b>$flat</b>";
 271                 } else {
 272                         $nested = "<b>$nested</b>";
 273                 }
 274                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 275                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 276                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 277         } else {
 278                 $hr = $ctx->{-hr};
 279         }
 280
 281         # do we have more messages? start a new <pre> if so
 282         $rv .= scalar(@{$ctx->{msgs}}) ? '</pre><hr><pre>' : '</pre>' if $hr;
 283         $rv;
 284 }
 285
 286 sub pad_link ($$;$) {
 287         my ($mid, $level, $s) = @_;
 288         $s ||= '...';
 289         my $href = defined($mid) ?
 290                 ("<a\nhref=#r".id_compress($mid, 1).">($s)</a>\n") :
 291                 "($s)\n";
 292         (' 'x19).indent_for($level).th_pfx($level).$href;
 293 }
 294
 295 sub _skel_hdr {
 296         # my ($mapping, $mid) = @_;
 297         ($_[0]->{$_[1] // \'bogus'} // [ "(?)\n" ])->[0];
 298 }
 299
 300 sub _th_index_lite {
 301         my ($mid_raw, $irt, $id, $ctx) = @_;
 302         my $rv = '';
 303         my $mapping = $ctx->{mapping} or return $rv;
 304         my $pad = '  ';
 305         my $mid_map = $mapping->{$mid_raw};
 306         defined $mid_map or
 307                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 308         my ($attr, $node, $idx, $level) = @$mid_map;
 309         my $children = $node->{children};
 310         my $nr_c = scalar @$children;
 311         my $nr_s = 0;
 312         my $siblings;
 313         # delete saves about 200KB on a 1K message thread
 314         if (my $refs = delete $node->{references}) {
 315                 ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 316         }
 317         my $irt_map = $mapping->{$$irt} if defined $$irt;
 318         if (defined $irt_map) {
 319                 $siblings = $irt_map->[1]->{children};
 320                 $nr_s = scalar(@$siblings) - 1;
 321                 $rv .= $pad . $irt_map->[0];
 322                 if ($idx > 0) {
 323                         my $prev = $siblings->[$idx - 1];
 324                         my $pmid = $prev->{mid};
 325                         if ($idx > 2) {
 326                                 my $s = ($idx - 1). ' preceding siblings ...';
 327                                 $rv .= pad_link($pmid, $level, $s);
 328                         } elsif ($idx == 2) {
 329                                 $rv .= $pad . _skel_hdr($mapping,
 330                                                 $siblings->[0] ?
 331                                                 $siblings->[0]->{mid} : undef);
 332                         }
 333                         $rv .= $pad . _skel_hdr($mapping, $pmid);
 334                 }
 335         }
 336         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 337         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 338         $attr =~ s!\n\z!</b>\n!s;
 339         $attr =~ s!<a\nhref.*</a> (?:&#34; )?!!s; # no point in dup subject
 340         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 341         $rv .= "<b>@ $attr";
 342         if ($nr_c) {
 343                 my $cmid = $children->[0] ? $children->[0]->{mid} : undef;
 344                 $rv .= $pad . _skel_hdr($mapping, $cmid);
 345                 if ($nr_c > 2) {
 346                         my $s = ($nr_c - 1). ' more replies';
 347                         $rv .= pad_link($cmid, $level + 1, $s);
 348                 } elsif (my $cn = $children->[1]) {
 349                         $rv .= $pad . _skel_hdr($mapping, $cn->{mid});
 350                 }
 351         }
 352
 353         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 354         if ($next) {
 355                 my $nmid = $next->{mid};
 356                 $rv .= $pad . _skel_hdr($mapping, $nmid);
 357                 my $nnext = $nr_s - $idx;
 358                 if ($nnext > 2) {
 359                         my $s = ($nnext - 1).' subsequent siblings';
 360                         $rv .= pad_link($nmid, $level, $s);
 361                 } elsif (my $nn = $siblings->[$idx + 2]) {
 362                         $rv .= $pad . _skel_hdr($mapping, $nn->{mid});
 363                 }
 364         }
 365         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 366 }
 367
 368 # non-recursive thread walker
 369 sub walk_thread ($$$) {
 370         my ($rootset, $ctx, $cb) = @_;
 371         my @q = map { (0, $_, -1) } @$rootset;
 372         while (@q) {
 373                 my ($level, $node, $i) = splice(@q, 0, 3);
 374                 defined $node or next;
 375                 $cb->($ctx, $level, $node, $i) or return;
 376                 ++$level;
 377                 $i = 0;
 378                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 379         }
 380 }
 381
 382 sub pre_thread  { # walk_thread callback
 383         my ($ctx, $level, $node, $idx) = @_;
 384         $ctx->{mapping}->{$node->{mid}} = [ '', $node, $idx, $level ];
 385         skel_dump($ctx, $level, $node);
 386 }
 387
 388 sub thread_eml_entry {
 389         my ($ctx, $eml) = @_;
 390         my ($beg, $end) = thread_adj_level($ctx, $ctx->{level});
 391         $ctx->zmore($beg.'<pre>');
 392         eml_entry($ctx, $eml) . '</pre>' . $end;
 393 }
 394
 395 sub next_in_queue ($$) {
 396         my ($q, $ghost_ok) = @_;
 397         while (@$q) {
 398                 my ($level, $smsg) = splice(@$q, 0, 2);
 399                 my $cl = $level + 1;
 400                 unshift @$q, map { ($cl, $_) } @{$smsg->{children}};
 401                 return ($level, $smsg) if $ghost_ok || exists($smsg->{blob});
 402         }
 403         undef;
 404 }
 405
 406 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 407         my ($ctx, $eml) = @_;
 408         return thread_eml_entry($ctx, $eml) if $eml;
 409         return unless exists($ctx->{skel});
 410         my $ghost_ok = $ctx->{nr}++;
 411         while (1) {
 412                 my ($lvl, $smsg) = next_in_queue($ctx->{-queue}, $ghost_ok);
 413                 if ($smsg) {
 414                         if (exists $smsg->{blob}) { # next message for cat-file
 415                                 $ctx->{level} = $lvl;
 416                                 if (!$ghost_ok) { # first non-ghost
 417                                         $ctx->{-title_html} =
 418                                                 ascii_html($smsg->{subject});
 419                                         $ctx->zmore($ctx->html_top);
 420                                 }
 421                                 return $smsg;
 422                         }
 423                         # buffer the ghost entry and loop
 424                         $ctx->zmore(ghost_index_entry($ctx, $lvl, $smsg));
 425                 } else { # all done
 426                         $ctx->zmore(join('', thread_adj_level($ctx, 0)));
 427                         $ctx->zmore(${delete($ctx->{skel})});
 428                         return;
 429                 }
 430         }
 431 }
 432
 433 sub stream_thread ($$) {
 434         my ($rootset, $ctx) = @_;
 435         @{$ctx->{-queue}} = map { (0, $_) } @$rootset;
 436         PublicInbox::WwwStream::aresponse($ctx, \&stream_thread_i);
 437 }
 438
 439 # /$INBOX/$MSGID/t/ and /$INBOX/$MSGID/T/
 440 sub thread_html {
 441         my ($ctx) = @_;
 442         $ctx->{-upfx} = '../../';
 443         my $mid = $ctx->{mid};
 444         my $ibx = $ctx->{ibx};
 445         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 446         return missing_thread($ctx) if $nr == 0;
 447
 448         # link $INBOX_DIR/description text to "index_topics" view around
 449         # the newest message in this thread
 450         my $t = ts2str($ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs));
 451         my $t_fmt = fmt_ts($ctx->{-t_max});
 452
 453         my $skel = '<hr><pre>';
 454         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 455         $skel .= <<EOF;
 456 , other threads:[<a
 457 href="../../?t=$t">~$t_fmt UTC</a> | <a
 458 href="../../">newest</a>]
 459
 460 EOF
 461         $skel .= "<b\nid=t>Thread overview:</b> ";
 462         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 463         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 464         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 465         $skel .= "-- links below jump to the message on this page --\n";
 466         $ctx->{cur_level} = 0;
 467         $ctx->{skel} = \$skel;
 468         $ctx->{prev_attr} = '';
 469         $ctx->{prev_level} = 0;
 470         $ctx->{root_anchor} = 'm' . id_compress($mid, 1);
 471         $ctx->{mapping} = {}; # mid -> [ header_summary, node, idx, level ]
 472         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 473                        .' in thread';
 474
 475         my $rootset = thread_results($ctx, $msgs);
 476
 477         # reduce hash lookups in pre_thread->skel_dump
 478         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 479         walk_thread($rootset, $ctx, \&pre_thread);
 480
 481         $skel .= '</pre>';
 482         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 483
 484         # flat display: lazy load the full message from smsg
 485         $ctx->{msgs} = $msgs;
 486         $ctx->{-html_tip} = '<pre>';
 487         PublicInbox::WwwStream::aresponse($ctx, \&thread_html_i);
 488 }
 489
 490 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 491         my ($ctx, $eml) = @_;
 492         if ($eml) {
 493                 my $smsg = $ctx->{smsg};
 494                 if (exists $ctx->{-html_tip}) {
 495                         $ctx->{-title_html} = ascii_html($smsg->{subject});
 496                         $ctx->zmore($ctx->html_top);
 497                 }
 498                 return eml_entry($ctx, $eml);
 499         } else {
 500                 while (my $smsg = shift @{$ctx->{msgs}}) {
 501                         return $smsg if exists($smsg->{blob});
 502                 }
 503                 my $skel = delete($ctx->{skel}) or return; # all done
 504                 $ctx->zmore($$skel);
 505                 undef;
 506         }
 507 }
 508
 509 sub multipart_text_as_html {
 510         # ($mime, $ctx) = @_; # each_part may do "$_[0] = undef"
 511
 512         # scan through all parts, looking for displayable text
 513         $_[0]->each_part(\&add_text_body, $_[1], 1);
 514 }
 515
 516 sub submsg_hdr ($$) {
 517         my ($ctx, $eml) = @_;
 518         my $obfs_ibx = $ctx->{-obfs_ibx};
 519         my $rv = $ctx->{obuf};
 520         $$rv .= "\n";
 521         for my $h (qw(From To Cc Subject Date Message-ID X-Alt-Message-ID)) {
 522                 my @v = $eml->header($h);
 523                 for my $v (@v) {
 524                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 525                         $v = ascii_html($v);
 526                         $$rv .= "$h: $v\n";
 527                 }
 528         }
 529 }
 530
 531 sub attach_link ($$$$;$) {
 532         my ($ctx, $ct, $p, $fn, $err) = @_;
 533         my ($part, $depth, $idx) = @$p;
 534
 535         # Eml iteration clobbers multipart ->{bdy}, so do not offer
 536         # downloads for 0-byte multipart attachments
 537         return unless $part->{bdy};
 538
 539         my $nl = $idx eq '1' ? '' : "\n"; # like join("\n", ...)
 540         my $size = length($part->body);
 541         delete $part->{bdy}; # save memory
 542
 543         # hide attributes normally, unless we want to aid users in
 544         # spotting MUA problems:
 545         $ct =~ s/;.*// unless $err;
 546         $ct = ascii_html($ct);
 547         my $sfn;
 548         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 549                 $sfn = $fn;
 550         } elsif ($ct eq 'text/plain') {
 551                 $sfn = 'a.txt';
 552         } else {
 553                 $sfn = 'a.bin';
 554         }
 555         my $rv = $ctx->{obuf};
 556         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 557         if ($err) {
 558                 $$rv .= <<EOF;
 559 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 560 EOF
 561         }
 562         $$rv .= "[-- Attachment #$idx: ";
 563         my $ts = "Type: $ct, Size: $size bytes";
 564         my $desc = $part->header('Content-Description') // $fn // '';
 565         $desc = ascii_html($desc);
 566         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 567         $$rv .= "</a>\n";
 568
 569         submsg_hdr($ctx, $part) if $part->{is_submsg};
 570
 571         undef;
 572 }
 573
 574 sub add_text_body { # callback for each_part
 575         my ($p, $ctx) = @_;
 576         my $upfx = $ctx->{mhref};
 577         my $ibx = $ctx->{ibx};
 578         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 579         # $p - from each_part: [ Email::MIME-like, depth, $idx ]
 580         my ($part, $depth, $idx) = @$p;
 581         my $ct = $part->content_type || 'text/plain';
 582         my $fn = $part->filename;
 583         my ($s, $err) = msg_part_text($part, $ct);
 584         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 585
 586         my $rv = $ctx->{obuf};
 587         if ($part->{is_submsg}) {
 588                 submsg_hdr($ctx, $part);
 589                 $$rv .= "\n";
 590         }
 591
 592         # makes no difference to browsers, and don't screw up filename
 593         # link generation in diffs with the extra '%0D'
 594         $s =~ s/\r+\n/\n/sg;
 595
 596         # will be escaped to `&#8226;' in HTML
 597         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 598
 599         # always support diff-highlighting, but we can't linkify hunk
 600         # headers for solver unless some coderepo are configured:
 601         my $diff;
 602         if ($s =~ /^--- [^\n]+\n\+{3} [^\n]+\n@@ /ms) {
 603                 # diffstat anchors do not link across attachments or messages,
 604                 # -apfx is just a stable prefix for making diffstat anchors
 605                 # linkable to the first diff hunk w/o crossing attachments
 606                 $idx =~ tr!.!/!; # compatibility with previous versions
 607                 $ctx->{-apfx} = $upfx . $idx;
 608
 609                 # do attr => filename mappings for diffstats in git diffs:
 610                 $ctx->{-anchors} = {} if $s =~ /^diff --git /sm;
 611                 $diff = 1;
 612                 delete $ctx->{-long_path};
 613                 my $spfx;
 614                 # absolute URL (Atom feeds)
 615                 if ($ibx->{coderepo}) {
 616                         if (index($upfx, '//') >= 0) {
 617                                 $spfx = $upfx;
 618                                 $spfx =~ s!/([^/]*)/\z!/!;
 619                         } else {
 620                                 my $n_slash = $upfx =~ tr!/!/!;
 621                                 if ($n_slash == 0) {
 622                                         $spfx = '../';
 623                                 } elsif ($n_slash == 1) {
 624                                         $spfx = '';
 625                                 } else { # nslash == 2
 626                                         $spfx = '../../';
 627                                 }
 628                         }
 629                 }
 630                 $ctx->{-spfx} = $spfx;
 631         };
 632
 633         # split off quoted and unquoted blocks:
 634         my @sections = PublicInbox::MsgIter::split_quotes($s);
 635         undef $s; # free memory
 636         if (defined($fn) || ($depth > 0 && !$part->{is_submsg}) || $err) {
 637                 # badly-encoded message with $err? tell the world about it!
 638                 attach_link($ctx, $ct, $p, $fn, $err);
 639                 $$rv .= "\n";
 640         }
 641         delete $part->{bdy}; # save memory
 642         foreach my $cur (@sections) {
 643                 if ($cur =~ /\A>/) {
 644                         # we use a <span> here to allow users to specify
 645                         # their own color for quoted text
 646                         $$rv .= qq(<span\nclass="q">);
 647                         $$rv .= $l->to_html($cur);
 648                         $$rv .= '</span>';
 649                 } elsif ($diff) {
 650                         flush_diff($ctx, \$cur);
 651                 } else {
 652                         # regular lines, OK
 653                         $$rv .= $l->to_html($cur);
 654                 }
 655                 undef $cur; # free memory
 656         }
 657 }
 658
 659 sub _msg_page_prepare_obuf {
 660         my ($eml, $ctx) = @_;
 661         my $have_over = !!$ctx->{ibx}->over;
 662         my $obfs_ibx = $ctx->{-obfs_ibx};
 663         $ctx->{obuf} = \(my $rv = '');
 664         my $mids = mids_for_index($eml);
 665         my $nr = $ctx->{nr}++;
 666         if ($nr) { # unlikely
 667                 if ($ctx->{chash} eq content_hash($eml)) {
 668                         warn "W: BUG? @$mids not deduplicated properly\n";
 669                         return;
 670                 }
 671                 $rv .=
 672 "<pre>WARNING: multiple messages have this Message-ID\n</pre><pre>";
 673         } else {
 674                 $ctx->{first_hdr} = $eml->header_obj;
 675                 $ctx->{chash} = content_hash($eml) if $ctx->{smsg}; # reused MID
 676                 $rv .= "<pre\nid=b>"; # anchor for body start
 677         }
 678         $ctx->{-upfx} = '../';
 679         my @title; # (Subject[0], From[0])
 680         for my $v ($eml->header('From')) {
 681                 my @n = PublicInbox::Address::names($v);
 682                 $v = ascii_html($v);
 683                 $title[1] //= ascii_html(join(', ', @n));
 684                 if ($obfs_ibx) {
 685                         obfuscate_addrs($obfs_ibx, $v);
 686                         obfuscate_addrs($obfs_ibx, $title[1]);
 687                 }
 688                 $rv .= "From: $v\n" if $v ne '';
 689         }
 690         foreach my $h (qw(To Cc)) {
 691                 for my $v ($eml->header($h)) {
 692                         fold_addresses($v);
 693                         $v = ascii_html($v);
 694                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 695                         $rv .= "$h: $v\n" if $v ne '';
 696                 }
 697         }
 698         my @subj = $eml->header('Subject');
 699         if (@subj) {
 700                 my $v = ascii_html(shift @subj);
 701                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 702                 $rv .= 'Subject: ';
 703                 $rv .= $have_over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 704                 $title[0] = $v;
 705                 for $v (@subj) { # multi-Subject message :<
 706                         $v = ascii_html($v);
 707                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 708                         $rv .= "Subject: $v\n";
 709                 }
 710         } else { # dummy anchor for thread skeleton at bottom of page
 711                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $have_over;
 712                 $title[0] = '(no subject)';
 713         }
 714         for my $v ($eml->header('Date')) {
 715                 $v = ascii_html($v);
 716                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 717                 $rv .= qq{Date: $v\n};
 718         }
 719         # [thread overview] link is typically added after Date,
 720         # but added after Subject, or even nothing.
 721         if ($have_over) {
 722                 chop $rv; # drop "\n", or noop if $rv eq ''
 723                 $rv .= qq{\t<a\nhref="#r">[thread overview]</a>\n};
 724         }
 725         if (!$nr) { # first (and only) message, common case
 726                 $ctx->{-title_html} = join(' - ', @title);
 727                 $rv = $ctx->html_top . $rv;
 728         }
 729
 730         $ctx->{-linkify} //= PublicInbox::Linkify->new;
 731         if (scalar(@$mids) == 1) { # common case
 732                 my $mhtml = ascii_html($mids->[0]);
 733                 $rv .= qq[Message-ID: &lt;$mhtml&gt; (<a href="raw">raw</a>)\n];
 734         } else {
 735                 # X-Alt-Message-ID can happen if a message is injected from
 736                 # public-inbox-nntpd because of multiple Message-ID headers.
 737                 my $s = '';
 738                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 739                         $s .= "$h: $_\n" for ($eml->header_raw($h));
 740                 }
 741                 $ctx->{-linkify}->linkify_mids('..', \$s, 1);
 742                 $rv .= $s;
 743         }
 744         $rv .= _parent_headers($ctx, $eml);
 745         1;
 746 }
 747
 748 sub SKEL_EXPAND () {
 749         qq(expand[<a\nhref="T/#u">flat</a>) .
 750                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 751                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 752                 qq(<a\nhref="t.atom">Atom feed</a>);
 753 }
 754
 755 sub thread_skel ($$$) {
 756         my ($skel, $ctx, $hdr) = @_;
 757         my $mid = mids($hdr)->[0];
 758         my $ibx = $ctx->{ibx};
 759         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 760         my $parent = in_reply_to($hdr);
 761         $$skel .= "\n<b>Thread overview: </b>";
 762         if ($nr <= 1) {
 763                 if (defined $parent) {
 764                         $$skel .= SKEL_EXPAND."\n ";
 765                         $$skel .= ghost_parent('../', $parent) . "\n";
 766                 } else {
 767                         $$skel .= "<a\nid=r>[no followups]</a> ".
 768                                         SKEL_EXPAND."\n";
 769                 }
 770                 $ctx->{next_msg} = undef;
 771                 $ctx->{parent_msg} = $parent;
 772                 return;
 773         }
 774
 775         $$skel .= $nr;
 776         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 777
 778         # nb: mutt only shows the first Subject in the index pane
 779         # when multiple Subject: headers are present, so we follow suit:
 780         my $subj = $hdr->header('Subject') // '';
 781         $subj = '(no subject)' if $subj eq '';
 782         $ctx->{cur} = $mid;
 783         $ctx->{prev_attr} = '';
 784         $ctx->{prev_level} = 0;
 785         $ctx->{skel} = $skel;
 786
 787         # reduce hash lookups in skel_dump
 788         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 789         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 790
 791         $ctx->{parent_msg} = $parent;
 792 }
 793
 794 sub _parent_headers {
 795         my ($ctx, $hdr) = @_;
 796         my @irt = $hdr->header_raw('In-Reply-To');
 797         my $refs;
 798         my $s = '';
 799         if (!@irt) {
 800                 $refs = references($hdr);
 801                 $irt[0] = pop(@$refs) if scalar @$refs;
 802         }
 803         $s .= "In-Reply-To: $_\n" for @irt;
 804
 805         # do not display References: if search is present,
 806         # we show the thread skeleton at the bottom, instead.
 807         if (!$ctx->{ibx}->over) {
 808                 $refs //= references($hdr);
 809                 $s .= 'References: <'.join(">\n\t<", @$refs).">\n" if @$refs;
 810         }
 811         $ctx->{-linkify}->linkify_mids('..', \$s); # escapes HTML
 812         $s .= "\n";
 813 }
 814
 815 # appends to obuf
 816 sub html_footer {
 817         my ($ctx, $hdr) = @_;
 818         my $upfx = '../';
 819         my ($related, $skel);
 820         my $qry = delete $ctx->{-qry};
 821         if ($qry && $ctx->{ibx}->isrch) {
 822                 my $q = ''; # search for either ancestor or descendent patches
 823                 for (@{$qry->{dfpre}}, @{$qry->{dfpost}}) {
 824                         chop if length > 7; # include 1 abbrev "older" patches
 825                         $q .= "dfblob:$_ ";
 826                 }
 827                 chop $q; # omit trailing SP
 828                 local $Text::Wrap::columns = COLS;
 829                 local $Text::Wrap::huge = 'overflow';
 830                 $q = wrap('', '', $q);
 831                 my $rows = ($q =~ tr/\n/\n/) + 1;
 832                 $q = ascii_html($q);
 833                 $related = <<EOM;
 834 <form id=related
 835 action=$upfx
 836 ><pre>find likely ancestor, descendant, or conflicting patches for <a
 837 href=#t>this message</a>:
 838 <textarea name=q cols=${\COLS} rows=$rows>$q</textarea>
 839 <input type=submit value=search
 840 />\t(<a href=${upfx}_/text/help/#search>help</a>)</pre></form>
 841 EOM
 842         }
 843         if ($ctx->{ibx}->over) {
 844                 my $t = ts2str($ctx->{-t_max});
 845                 my $t_fmt = fmt_ts($ctx->{-t_max});
 846                 my $fallback = $related ? "\t" : "<a id=related>\t</a>";
 847                 $skel = <<EOF;
 848 ${fallback}other threads:[<a
 849 href="$upfx?t=$t">~$t_fmt UTC</a>|<a
 850 href="$upfx">newest</a>]
 851 EOF
 852
 853                 thread_skel(\$skel, $ctx, $hdr);
 854                 my ($next, $prev);
 855                 my $parent = '       ';
 856                 $next = $prev = '    ';
 857
 858                 if (my $n = $ctx->{next_msg}) {
 859                         $n = mid_href($n);
 860                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 861                 }
 862                 my $u;
 863                 my $par = $ctx->{parent_msg};
 864                 if ($par) {
 865                         $u = mid_href($par);
 866                         $u = "$upfx$u/";
 867                 }
 868                 if (my $p = $ctx->{prev_msg}) {
 869                         $prev = mid_href($p);
 870                         if ($p && $par && $p eq $par) {
 871                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 872                                         'rel=prev>prev parent</a>';
 873                                 $parent = '';
 874                         } else {
 875                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 876                                         'rel=prev>prev</a>';
 877                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 878                         }
 879                 } elsif ($u) { # unlikely
 880                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 881                 }
 882                 ${$ctx->{obuf}} .= "<pre>$next $prev$parent ";
 883         } else { # unindexed inboxes w/o over
 884                 ${$ctx->{obuf}} .= '<pre>';
 885                 $skel = qq( <a\nhref="$upfx">latest</a>);
 886         }
 887         ${$ctx->{obuf}} .= qq(<a\nhref="#R">reply</a>);
 888         # $skel may be big for big threads, don't append it to obuf
 889         $skel .= '</pre>' . ($related // '');
 890         $ctx->zmore($skel .= msg_reply($ctx, $hdr)); # flushes obuf
 891 }
 892
 893 sub ghost_parent {
 894         my ($upfx, $mid) = @_;
 895
 896         my $href = mid_href($mid);
 897         my $html = ascii_html($mid);
 898         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 899 }
 900
 901 sub indent_for {
 902         my ($level) = @_;
 903         $level ? INDENT x ($level - 1) : '';
 904 }
 905
 906 sub find_mid_root {
 907         my ($ctx, $level, $node, $idx) = @_;
 908         ++$ctx->{root_idx} if $level == 0;
 909         if ($node->{mid} eq $ctx->{mid}) {
 910                 $ctx->{found_mid_at} = $ctx->{root_idx};
 911                 return 0; # stop iterating
 912         }
 913         1;
 914 }
 915
 916 sub strict_loose_note ($) {
 917         my ($nr) = @_;
 918         my $msg =
 919 "  -- strict thread matches above, loose matches on Subject: below --\n";
 920
 921         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 922                 $msg .=
 923 "  -- use mbox.gz link to download all $nr messages --\n";
 924         }
 925         $msg;
 926 }
 927
 928 sub thread_results {
 929         my ($ctx, $msgs) = @_;
 930         require PublicInbox::SearchThread;
 931         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 932
 933         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 934         # and preserved in the future.  This bug is hidden by `sid' matches
 935         # in get_thread, so we never noticed it until now.  And even when
 936         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 937         # bump since reindexing is expensive and users may not do it
 938
 939         # loose threading could've returned too many results,
 940         # put the root the message we care about at the top:
 941         my $mid = $ctx->{mid};
 942         if (defined($mid) && scalar(@$rootset) > 1) {
 943                 $ctx->{root_idx} = -1;
 944                 my $nr = scalar @$msgs;
 945                 walk_thread($rootset, $ctx, \&find_mid_root);
 946                 my $idx = $ctx->{found_mid_at};
 947                 if (defined($idx) && $idx != 0) {
 948                         my $tip = splice(@$rootset, $idx, 1);
 949                         @$rootset = reverse @$rootset;
 950                         unshift @$rootset, $tip;
 951                         $ctx->{sl_note} = strict_loose_note($nr);
 952                 }
 953         }
 954         $rootset
 955 }
 956
 957 sub missing_thread {
 958         my ($ctx) = @_;
 959         require PublicInbox::ExtMsg;
 960         PublicInbox::ExtMsg::ext_msg($ctx);
 961 }
 962
 963 sub dedupe_subject {
 964         my ($prev_subj, $subj, $val) = @_;
 965
 966         my $omit; # '"' denotes identical text omitted
 967         my (@prev_pop, @curr_pop);
 968         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 969                 push(@prev_pop, pop(@$prev_subj));
 970                 push(@curr_pop, pop(@$subj));
 971                 $omit //= $val;
 972         }
 973         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 974         if (scalar(@curr_pop) == 1) {
 975                 $omit = undef;
 976                 push @$prev_subj, @prev_pop;
 977                 push @$subj, @curr_pop;
 978         }
 979         $omit // '';
 980 }
 981
 982 sub skel_dump { # walk_thread callback
 983         my ($ctx, $level, $smsg) = @_;
 984         $smsg->{blob} or return _skel_ghost($ctx, $level, $smsg);
 985
 986         my $skel = $ctx->{skel};
 987         my $cur = $ctx->{cur};
 988         my $mid = $smsg->{mid};
 989
 990         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 991                 $$skel .= delete($ctx->{sl_note}) || '';
 992         }
 993
 994         my $f = ascii_html(delete $smsg->{from_name});
 995         my $obfs_ibx = $ctx->{-obfs_ibx};
 996         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 997
 998         my $d = fmt_ts($smsg->{ds});
 999         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
1000         if (exists $ctx->{searchview}) {
1001                 if (defined(my $pct = $smsg->{pct})) {
1002                         $d .= (sprintf(' % 2u', $pct) . '%');
1003                 } else {
1004                         $unmatched = 1;
1005                         $d .= '    ';
1006                 }
1007         }
1008         $d .= ' ' . indent_for($level) . th_pfx($level);
1009         my $attr = $f;
1010         $ctx->{first_level} ||= $level;
1011
1012         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
1013                 $ctx->{prev_attr} = $attr;
1014         }
1015         $ctx->{prev_level} = $level;
1016
1017         if ($cur) {
1018                 if ($cur eq $mid) {
1019                         delete $ctx->{cur};
1020                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
1021                                  "$attr [this message]</a></b>\n";
1022                         return 1;
1023                 } else {
1024                         $ctx->{prev_msg} = $mid;
1025                 }
1026         } else {
1027                 $ctx->{next_msg} ||= $mid;
1028         }
1029
1030         # Subject is never undef, this mail was loaded from
1031         # our Xapian which would've resulted in '' if it were
1032         # really missing (and Filter rejects empty subjects)
1033         my @subj = split(/ /, subject_normalized($smsg->{subject}));
1034         # remove common suffixes from the subject if it matches the previous,
1035         # so we do not show redundant text at the end.
1036         my $prev_subj = $ctx->{prev_subj} || [];
1037         $ctx->{prev_subj} = [ @subj ];
1038         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
1039         my $end;
1040         if (@subj) {
1041                 my $subj = join(' ', @subj);
1042                 $subj = ascii_html($subj);
1043                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1044                 $end = "$subj</a> $omit$f\n"
1045         } else {
1046                 $end = "$f</a>\n";
1047         }
1048         my $m;
1049         my $id = '';
1050         my $mapping = $unmatched ? undef : $ctx->{mapping};
1051         if ($mapping) {
1052                 my $map = $mapping->{$mid};
1053                 $id = id_compress($mid, 1);
1054                 $m = '#m'.$id;
1055                 $map->[0] = "$d<a\nhref=\"$m\">$end";
1056                 $id = "\nid=r".$id;
1057         } else {
1058                 $m = $ctx->{-upfx}.mid_href($mid).'/';
1059         }
1060         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
1061         1;
1062 }
1063
1064 sub _skel_ghost {
1065         my ($ctx, $level, $node) = @_;
1066
1067         my $mid = $node->{mid};
1068         my $d = '     [not found] ';
1069         $d .= '    '  if exists $ctx->{searchview};
1070         $d .= indent_for($level) . th_pfx($level);
1071         my $upfx = $ctx->{-upfx};
1072         my $href = $upfx . mid_href($mid) . '/';
1073         my $html = ascii_html($mid);
1074
1075         my $mapping = $ctx->{mapping};
1076         my $map = $mapping->{$mid} if $mapping;
1077         if ($map) {
1078                 my $id = id_compress($mid, 1);
1079                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1080                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1081         } else {
1082                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1083         }
1084         ${$ctx->{skel}} .= $d;
1085         1;
1086 }
1087
1088 sub sort_ds {
1089         @{$_[0]} = sort {
1090                 (eval { $a->topmost->{ds} } || 0) <=>
1091                 (eval { $b->topmost->{ds} } || 0)
1092         } @{$_[0]};
1093 }
1094
1095 # accumulate recent topics if search is supported
1096 # returns 200 if done, 404 if not
1097 sub acc_topic { # walk_thread callback
1098         my ($ctx, $level, $smsg) = @_;
1099         my $mid = $smsg->{mid};
1100         my $has_blob = $smsg->{blob} // do {
1101                 if (my $by_mid = $ctx->{ibx}->smsg_by_mid($mid)) {
1102                         %$smsg = (%$smsg, %$by_mid);
1103                         1;
1104                 }
1105         };
1106         if ($has_blob) {
1107                 my $subj = subject_normalized($smsg->{subject});
1108                 $subj = '(no subject)' if $subj eq '';
1109                 my $ds = $smsg->{ds};
1110                 if ($level == 0) { # new, top-level topic
1111                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1112                         $ctx->{-cur_topic} = $topic;
1113                         push @{$ctx->{order}}, $topic;
1114                         return 1;
1115                 }
1116
1117                 # continue existing topic
1118                 my $topic = $ctx->{-cur_topic}; # should never be undef
1119                 $topic->[0] = $ds if $ds > $topic->[0];
1120                 $topic->[1]++; # bump N+ message counter
1121                 my $seen = $topic->[2];
1122                 if (scalar(@$topic) == 3) { # parent was a ghost
1123                         push @$topic, $subj;
1124                 } elsif (!defined($seen->{$subj})) {
1125                         push @$topic, $level, $subj; # @extra messages
1126                 }
1127                 $seen->{$subj} = $mid; # latest for subject
1128         } else { # ghost message
1129                 return 1 if $level != 0; # ignore child ghosts
1130                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1131                 push @{$ctx->{order}}, $topic;
1132         }
1133         1;
1134 }
1135
1136 sub dump_topics {
1137         my ($ctx) = @_;
1138         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1139         unless ($order) {
1140                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1141                 return 404;
1142         }
1143
1144         my @out;
1145         my $obfs_ibx = $ctx->{ibx}->{obfuscate} ? $ctx->{ibx} : undef;
1146         if (my $note = delete $ctx->{t_note}) {
1147                 push @out, $note; # "messages from ... to ..."
1148         }
1149         # sort by recency, this allows new posts to "bump" old topics...
1150         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1151                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1152                 @$topic = ();
1153                 next unless defined $top_subj;  # ghost topic
1154                 my $mid = delete $seen->{$top_subj};
1155                 my $href = mid_href($mid);
1156                 my $prev_subj = [ split(/ /, $top_subj) ];
1157                 $top_subj = ascii_html($top_subj);
1158                 $ds = fmt_ts($ds);
1159
1160                 # $n isn't the total number of posts on the topic,
1161                 # just the number of posts in the current results window
1162                 my $anchor;
1163                 if ($n == 1) {
1164                         $n = '';
1165                         $anchor = '#u'; # top of only message
1166                 } else {
1167                         $n = " ($n+ messages)";
1168                         $anchor = '#t'; # thread skeleton
1169                 }
1170
1171                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1172                         " $ds UTC $n\n";
1173                 while (@extra) {
1174                         my $level = shift @extra;
1175                         my $subj = shift @extra; # already normalized
1176                         $mid = delete $seen->{$subj};
1177                         my @subj = split(/ /, $subj);
1178                         my @next_prev = @subj; # full copy
1179                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1180                         $prev_subj = \@next_prev;
1181                         $subj = join(' ', @subj);
1182                         $subj = ascii_html($subj);
1183                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1184                         $href = mid_href($mid);
1185                         $s .= indent_for($level) . TCHILD;
1186                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1187                 }
1188                 push @out, $s;
1189         }
1190         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1191         200;
1192 }
1193
1194 sub str2ts ($) {
1195         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1196         timegm($ss || 0, $mm || 0, $hh || 0, $dd, $mon - 1, $yyyy);
1197 }
1198
1199 sub pagination_footer ($$) {
1200         my ($ctx, $latest) = @_;
1201         my $next = $ctx->{next_page} || '';
1202         my $prev = $ctx->{prev_page} || '';
1203         if ($prev) {  # aligned padding for: 'next (older) | '
1204                 $next = $next ? "$next | " : '             | ';
1205                 $prev .= qq[ | <a\nhref="$latest">latest</a>];
1206         }
1207         ($next || $prev) ? "<hr><pre id=nav>page: $next$prev</pre>" : '';
1208 }
1209
1210 sub paginate_recent ($$) {
1211         my ($ctx, $lim) = @_;
1212         my $t = $ctx->{qp}->{t} || '';
1213         my $opts = { limit => $lim };
1214         my ($after, $before);
1215
1216         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1217         # if only $after exists "YYYYMMDD.." because "." could be skipped
1218         # if interpreted as an end-of-sentence
1219         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1220         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1221
1222         my $msgs = $ctx->{ibx}->over->recent($opts, $after, $before);
1223         if (defined($after) && scalar(@$msgs) < $lim) {
1224                 $after = $before = undef;
1225                 $msgs = $ctx->{ibx}->over->recent($opts);
1226         }
1227         my $more = scalar(@$msgs) == $lim;
1228         my ($newest, $oldest);
1229         if (@$msgs) {
1230                 $newest = $msgs->[0]->{ts};
1231                 $oldest = $msgs->[-1]->{ts};
1232                 # if we only had $after, our SQL query in ->recent ordered
1233                 if ($newest < $oldest) {
1234                         ($oldest, $newest) = ($newest, $oldest);
1235                         $more = undef if defined($after) && $after < $oldest;
1236                 }
1237                 if (defined($after // $before)) {
1238                         my $n = strftime('%Y-%m-%d %H:%M:%S', gmtime($newest));
1239                         my $o = strftime('%Y-%m-%d %H:%M:%S', gmtime($oldest));
1240                         $ctx->{t_note} = <<EOM;
1241  messages from $o to $n UTC [<a href="#nav">more...</a>]
1242 EOM
1243                         my $s = ts2str($newest);
1244                         $ctx->{prev_page} = qq[<a\nhref="?t=$s-"\nrel=prev>] .
1245                                                 'prev (newer)</a>';
1246                 }
1247         }
1248         if (defined($oldest) && $more) {
1249                 my $s = ts2str($oldest);
1250                 $ctx->{next_page} = qq[<a\nhref="?t=$s"\nrel=next>] .
1251                                         'next (older)</a>';
1252         }
1253         $msgs;
1254 }
1255
1256 # GET /$INBOX - top-level inbox view for indexed inboxes
1257 sub index_topics {
1258         my ($ctx) = @_;
1259         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1260         walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic) if @$msgs;
1261         html_oneshot($ctx, dump_topics($ctx), pagination_footer($ctx, '.'));
1262 }
1263
1264 sub thread_adj_level {
1265         my ($ctx, $level) = @_;
1266
1267         my $max = $ctx->{cur_level};
1268         if ($level <= 0) {
1269                 return ('', '') if $max == 0; # flat output
1270
1271                 # reset existing lists
1272                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1273                 $ctx->{cur_level} = 0;
1274                 ("$beg</ul>", '');
1275         } elsif ($level == $max) { # continue existing list
1276                 qw(<li> </li>);
1277         } elsif ($level < $max) {
1278                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1279                 $ctx->{cur_level} = $level;
1280                 ("$beg<li>", '</li>');
1281         } else { # ($level > $max) # start a new level
1282                 $ctx->{cur_level} = $level;
1283                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1284                 ($beg, '</li>');
1285         }
1286 }
1287
1288 sub ghost_index_entry {
1289         my ($ctx, $level, $node) = @_;
1290         my ($beg, $end) = thread_adj_level($ctx,  $level);
1291         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{mid} // '?')
1292                 . '</pre>' . $end;
1293 }
1294
1295 1;