lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the unmaintained Danga::Socket (1.61) with
   7 # significant changes.  See Documentation/technical/ds.txt in our
   8 # source for details.
   9 #
  10 # Do not expect this to be a stable API like Danga::Socket,
  11 # but it will evolve to suite our needs and to take advantage of
  12 # newer Linux and *BSD features.
  13 # Bugs encountered were reported to bug-Danga-Socket@rt.cpan.org,
  14 # fixed in Danga::Socket 1.62 and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 #
  17 # fields:
  18 # sock: underlying socket
  19 # rbuf: scalarref, usually undef
  20 # wbuf: arrayref of coderefs or tmpio (autovivified))
  21 #        (tmpio = [ GLOB, offset, [ length ] ])
  22 package PublicInbox::DS;
  23 use strict;
  24 use v5.10.1;
  25 use parent qw(Exporter);
  26 use bytes qw(length substr); # FIXME(?): needed for PublicInbox::NNTP
  27 use POSIX qw(WNOHANG sigprocmask SIG_SETMASK);
  28 use Fcntl qw(SEEK_SET :DEFAULT O_APPEND);
  29 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  30 use Scalar::Util qw(blessed);
  31 use PublicInbox::Syscall qw(:epoll);
  32 use PublicInbox::Tmpfile;
  33 use Errno qw(EAGAIN EINVAL);
  34 use Carp qw(carp croak);
  35 our @EXPORT_OK = qw(now msg_more dwaitpid add_timer add_uniq_timer);
  36
  37 my %Stack;
  38 my $nextq; # queue for next_tick
  39 my $wait_pids; # list of [ pid, callback, callback_arg ]
  40 my $reap_armed;
  41 my $ToClose; # sockets to close when event loop is done
  42 our (
  43      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  44      $Epoll,                     # Global epoll fd (or DSKQXS ref)
  45      $ep_io,                     # IO::Handle for Epoll
  46
  47      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  48
  49      $LoopTimeout,               # timeout of event loop in milliseconds
  50      @Timers,                    # timers
  51      %UniqTimer,
  52      $in_loop,
  53      );
  54
  55 Reset();
  56
  57 #####################################################################
  58 ### C L A S S   M E T H O D S
  59 #####################################################################
  60
  61 =head2 C<< CLASS->Reset() >>
  62
  63 Reset all state
  64
  65 =cut
  66 sub Reset {
  67         do {
  68                 $in_loop = undef; # first in case DESTROY callbacks use this
  69                 %DescriptorMap = ();
  70                 @Timers = ();
  71                 %UniqTimer = ();
  72                 $PostLoopCallback = undef;
  73
  74                 # we may be iterating inside one of these on our stack
  75                 my @q = delete @Stack{keys %Stack};
  76                 for my $q (@q) { @$q = () }
  77                 $wait_pids = $nextq = $ToClose = undef;
  78                 $ep_io = undef; # closes real $Epoll FD
  79                 $Epoll = undef; # may call DSKQXS::DESTROY
  80         } while (@Timers || keys(%Stack) || $nextq || $wait_pids ||
  81                 $ToClose || keys(%DescriptorMap) ||
  82                 $PostLoopCallback || keys(%UniqTimer));
  83
  84         $reap_armed = undef;
  85         $LoopTimeout = -1;  # no timeout by default
  86 }
  87
  88 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  89
  90 Set the loop timeout for the event loop to some value in milliseconds.
  91
  92 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
  93 immediately.
  94
  95 =cut
  96 sub SetLoopTimeout { $LoopTimeout = $_[1] + 0 }
  97
  98 sub _add_named_timer {
  99         my ($name, $secs, $coderef, @args) = @_;
 100         my $fire_time = now() + $secs;
 101         my $timer = [$fire_time, $name, $coderef, @args];
 102
 103         if (!@Timers || $fire_time >= $Timers[-1][0]) {
 104                 push @Timers, $timer;
 105                 return $timer;
 106         }
 107
 108         # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 109         # but it was compared against calendar queues, heaps, naive push/sort,
 110         # and a bunch of other versions, and found to be fastest with a large
 111         # variety of datasets.)
 112         for (my $i = 0; $i < @Timers; $i++) {
 113                 if ($Timers[$i][0] > $fire_time) {
 114                         splice(@Timers, $i, 0, $timer);
 115                         return $timer;
 116                 }
 117         }
 118         die "Shouldn't get here.";
 119 }
 120
 121 sub add_timer { _add_named_timer(undef, @_) }
 122
 123 sub add_uniq_timer { # ($name, $secs, $coderef, @args) = @_;
 124         $UniqTimer{$_[0]} //= _add_named_timer(@_);
 125 }
 126
 127 # caller sets return value to $Epoll
 128 sub _InitPoller () {
 129         if (PublicInbox::Syscall::epoll_defined())  {
 130                 my $fd = epoll_create();
 131                 die "epoll_create: $!" if $fd < 0;
 132                 open($ep_io, '+<&=', $fd) or return;
 133                 my $fl = fcntl($ep_io, F_GETFD, 0);
 134                 fcntl($ep_io, F_SETFD, $fl | FD_CLOEXEC);
 135                 $fd;
 136         } else {
 137                 my $cls;
 138                 for (qw(DSKQXS DSPoll)) {
 139                         $cls = "PublicInbox::$_";
 140                         last if eval "require $cls";
 141                 }
 142                 $cls->import(qw(epoll_ctl epoll_wait));
 143                 $cls->new;
 144         }
 145 }
 146
 147 sub now () { clock_gettime(CLOCK_MONOTONIC) }
 148
 149 sub next_tick () {
 150         my $q = $nextq or return;
 151         $nextq = undef;
 152         $Stack{cur_runq} = $q;
 153         for my $obj (@$q) {
 154                 # avoid "ref" on blessed refs to workaround a Perl 5.16.3 leak:
 155                 # https://rt.perl.org/Public/Bug/Display.html?id=114340
 156                 if (blessed($obj)) {
 157                         $obj->event_step;
 158                 } else {
 159                         $obj->();
 160                 }
 161         }
 162         delete $Stack{cur_runq};
 163 }
 164
 165 # runs timers and returns milliseconds for next one, or next event loop
 166 sub RunTimers {
 167         next_tick();
 168
 169         return (($nextq || $ToClose) ? 0 : $LoopTimeout) unless @Timers;
 170
 171         my $now = now();
 172
 173         # Run expired timers
 174         while (@Timers && $Timers[0][0] <= $now) {
 175                 my $to_run = shift(@Timers);
 176                 delete $UniqTimer{$to_run->[1] // ''};
 177                 $to_run->[2]->(@$to_run[3..$#$to_run]);
 178         }
 179
 180         # timers may enqueue into nextq:
 181         return 0 if ($nextq || $ToClose);
 182
 183         return $LoopTimeout unless @Timers;
 184
 185         # convert time to an even number of milliseconds, adding 1
 186         # extra, otherwise floating point fun can occur and we'll
 187         # call RunTimers like 20-30 times, each returning a timeout
 188         # of 0.0000212 seconds
 189         my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 190
 191         # -1 is an infinite timeout, so prefer a real timeout
 192         ($LoopTimeout < 0 || $LoopTimeout >= $timeout) ? $timeout : $LoopTimeout
 193 }
 194
 195 sub sig_setmask { sigprocmask(SIG_SETMASK, @_) or die "sigprocmask: $!" }
 196
 197 sub block_signals () {
 198         my $oldset = POSIX::SigSet->new;
 199         my $newset = POSIX::SigSet->new;
 200         $newset->fillset or die "fillset: $!";
 201         sig_setmask($newset, $oldset);
 202         $oldset;
 203 }
 204
 205 # We can't use waitpid(-1) safely here since it can hit ``, system(),
 206 # and other things.  So we scan the $wait_pids list, which is hopefully
 207 # not too big.  We keep $wait_pids small by not calling dwaitpid()
 208 # until we've hit EOF when reading the stdout of the child.
 209
 210 sub reap_pids {
 211         $reap_armed = undef;
 212         my $tmp = $wait_pids or return;
 213         $wait_pids = undef;
 214         $Stack{reap_runq} = $tmp;
 215         my $oldset = block_signals();
 216         foreach my $ary (@$tmp) {
 217                 my ($pid, $cb, $arg) = @$ary;
 218                 my $ret = waitpid($pid, WNOHANG);
 219                 if ($ret == 0) {
 220                         push @$wait_pids, $ary; # autovivifies @$wait_pids
 221                 } elsif ($ret == $pid) {
 222                         if ($cb) {
 223                                 eval { $cb->($arg, $pid) };
 224                                 warn "E: dwaitpid($pid) in_loop: $@" if $@;
 225                         }
 226                 } else {
 227                         warn "waitpid($pid, WNOHANG) = $ret, \$!=$!, \$?=$?";
 228                 }
 229         }
 230         sig_setmask($oldset);
 231         delete $Stack{reap_runq};
 232 }
 233
 234 # reentrant SIGCHLD handler (since reap_pids is not reentrant)
 235 sub enqueue_reap () { $reap_armed //= requeue(\&reap_pids) }
 236
 237 sub in_loop () { $in_loop }
 238
 239 # Internal function: run the post-event callback, send read events
 240 # for pushed-back data, and close pending connections.  returns 1
 241 # if event loop should continue, or 0 to shut it all down.
 242 sub PostEventLoop () {
 243         # now we can close sockets that wanted to close during our event
 244         # processing.  (we didn't want to close them during the loop, as we
 245         # didn't want fd numbers being reused and confused during the event
 246         # loop)
 247         if (my $close_now = $ToClose) {
 248                 $ToClose = undef; # will be autovivified on push
 249                 @$close_now = map { fileno($_) } @$close_now;
 250
 251                 # ->DESTROY methods may populate ToClose
 252                 delete @DescriptorMap{@$close_now};
 253         }
 254
 255         # by default we keep running, unless a postloop callback cancels it
 256         $PostLoopCallback ? $PostLoopCallback->(\%DescriptorMap) : 1;
 257 }
 258
 259 # Start processing IO events. In most daemon programs this never exits. See
 260 # C<PostLoopCallback> for how to exit the loop.
 261 sub event_loop (;$$) {
 262         my ($sig, $oldset) = @_;
 263         $Epoll //= _InitPoller();
 264         require PublicInbox::Sigfd if $sig;
 265         my $sigfd = PublicInbox::Sigfd->new($sig, 1) if $sig;
 266         local @SIG{keys %$sig} = values(%$sig) if $sig && !$sigfd;
 267         local $SIG{PIPE} = 'IGNORE';
 268         if (!$sigfd && $sig) {
 269                 # wake up every second to accept signals if we don't
 270                 # have signalfd or IO::KQueue:
 271                 sig_setmask($oldset);
 272                 PublicInbox::DS->SetLoopTimeout(1000);
 273         }
 274         $_[0] = $sigfd = $sig = undef; # $_[0] == sig
 275         local $in_loop = 1;
 276         my @events;
 277         do {
 278                 my $timeout = RunTimers();
 279
 280                 # get up to 1000 events
 281                 epoll_wait($Epoll, 1000, $timeout, \@events);
 282                 for my $fd (@events) {
 283                         # it's possible epoll_wait returned many events,
 284                         # including some at the end that ones in the front
 285                         # triggered unregister-interest actions.  if we can't
 286                         # find the %sock entry, it's because we're no longer
 287                         # interested in that event.
 288
 289                         # guard stack-not-refcounted w/ Carp + @DB::args
 290                         my $obj = $DescriptorMap{$fd};
 291                         $obj->event_step;
 292                 }
 293         } while (PostEventLoop());
 294 }
 295
 296 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 297
 298 Sets post loop callback function.  Pass a subref and it will be
 299 called every time the event loop finishes.
 300
 301 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 302 and it will exit.
 303
 304 The callback function will be passed two parameters: \%DescriptorMap
 305
 306 =cut
 307 sub SetPostLoopCallback {
 308     my ($class, $ref) = @_;
 309
 310     # global callback
 311     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 312 }
 313
 314 #####################################################################
 315 ### PublicInbox::DS-the-object code
 316 #####################################################################
 317
 318 =head2 OBJECT METHODS
 319
 320 =head2 C<< CLASS->new( $socket ) >>
 321
 322 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 323 react to events on it during the C<event_loop>.
 324
 325 This is normally (always?) called from your subclass via:
 326
 327   $class->SUPER::new($socket);
 328
 329 =cut
 330 sub new {
 331     my ($self, $sock, $ev) = @_;
 332     $self->{sock} = $sock;
 333     my $fd = fileno($sock);
 334
 335     $Epoll //= _InitPoller();
 336 retry:
 337     if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 338         if ($! == EINVAL && ($ev & EPOLLEXCLUSIVE)) {
 339             $ev &= ~EPOLLEXCLUSIVE;
 340             goto retry;
 341         }
 342         die "EPOLL_CTL_ADD $self/$sock/$fd: $!";
 343     }
 344     croak("FD:$fd in use by $DescriptorMap{$fd} (for $self/$sock)")
 345         if defined($DescriptorMap{$fd});
 346
 347     $DescriptorMap{$fd} = $self;
 348 }
 349
 350
 351 #####################################################################
 352 ### I N S T A N C E   M E T H O D S
 353 #####################################################################
 354
 355 sub requeue ($) { push @$nextq, $_[0] } # autovivifies
 356
 357 =head2 C<< $obj->close >>
 358
 359 Close the socket.
 360
 361 =cut
 362 sub close {
 363     my ($self) = @_;
 364     my $sock = delete $self->{sock} or return;
 365
 366     # we need to flush our write buffer, as there may
 367     # be self-referential closures (sub { $client->close })
 368     # preventing the object from being destroyed
 369     delete $self->{wbuf};
 370
 371     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 372     # notifications about it
 373     my $fd = fileno($sock);
 374     epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, 0) and
 375         croak("EPOLL_CTL_DEL($self/$sock): $!");
 376
 377     # we explicitly don't delete from DescriptorMap here until we
 378     # actually close the socket, as we might be in the middle of
 379     # processing an epoll_wait/etc that returned hundreds of fds, one
 380     # of which is not yet processed and is what we're closing.  if we
 381     # keep it in DescriptorMap, then the event harnesses can just
 382     # looked at $pob->{sock} == undef and ignore it.  but if it's an
 383     # un-accounted for fd, then it (understandably) freak out a bit
 384     # and emit warnings, thinking their state got off.
 385
 386     # defer closing the actual socket until the event loop is done
 387     # processing this round of events.  (otherwise we might reuse fds)
 388     push @$ToClose, $sock; # autovivifies $ToClose
 389
 390     return 0;
 391 }
 392
 393 # portable, non-thread-safe sendfile emulation (no pread, yet)
 394 sub send_tmpio ($$) {
 395     my ($sock, $tmpio) = @_;
 396
 397     sysseek($tmpio->[0], $tmpio->[1], SEEK_SET) or return;
 398     my $n = $tmpio->[2] // 65536;
 399     $n = 65536 if $n > 65536;
 400     defined(my $to_write = sysread($tmpio->[0], my $buf, $n)) or return;
 401     my $written = 0;
 402     while ($to_write > 0) {
 403         if (defined(my $w = syswrite($sock, $buf, $to_write, $written))) {
 404             $written += $w;
 405             $to_write -= $w;
 406         } else {
 407             return if $written == 0;
 408             last;
 409         }
 410     }
 411     $tmpio->[1] += $written; # offset
 412     $tmpio->[2] -= $written if defined($tmpio->[2]); # length
 413     $written;
 414 }
 415
 416 sub epbit ($$) { # (sock, default)
 417         $_[0]->can('stop_SSL') ? PublicInbox::TLS::epollbit() : $_[1];
 418 }
 419
 420 # returns 1 if done, 0 if incomplete
 421 sub flush_write ($) {
 422     my ($self) = @_;
 423     my $sock = $self->{sock} or return;
 424     my $wbuf = $self->{wbuf} or return 1;
 425
 426 next_buf:
 427     while (my $bref = $wbuf->[0]) {
 428         if (ref($bref) ne 'CODE') {
 429             while ($sock) {
 430                 my $w = send_tmpio($sock, $bref); # bref is tmpio
 431                 if (defined $w) {
 432                     if ($w == 0) {
 433                         shift @$wbuf;
 434                         goto next_buf;
 435                     }
 436                 } elsif ($! == EAGAIN) {
 437                     my $ev = epbit($sock, EPOLLOUT) or return $self->close;
 438                     epwait($sock, $ev | EPOLLONESHOT);
 439                     return 0;
 440                 } else {
 441                     return $self->close;
 442                 }
 443             }
 444         } else { #(ref($bref) eq 'CODE') {
 445             shift @$wbuf;
 446             my $before = scalar(@$wbuf);
 447             $bref->($self);
 448
 449             # bref may be enqueueing more CODE to call (see accept_tls_step)
 450             return 0 if (scalar(@$wbuf) > $before);
 451         }
 452     } # while @$wbuf
 453
 454     delete $self->{wbuf};
 455     1; # all done
 456 }
 457
 458 sub rbuf_idle ($$) {
 459     my ($self, $rbuf) = @_;
 460     if ($$rbuf eq '') { # who knows how long till we can read again
 461         delete $self->{rbuf};
 462     } else {
 463         $self->{rbuf} = $rbuf;
 464     }
 465 }
 466
 467 sub do_read ($$$;$) {
 468     my ($self, $rbuf, $len, $off) = @_;
 469     my $r = sysread(my $sock = $self->{sock}, $$rbuf, $len, $off // 0);
 470     return ($r == 0 ? $self->close : $r) if defined $r;
 471     # common for clients to break connections without warning,
 472     # would be too noisy to log here:
 473     if ($! == EAGAIN) {
 474         my $ev = epbit($sock, EPOLLIN) or return $self->close;
 475         epwait($sock, $ev | EPOLLONESHOT);
 476         rbuf_idle($self, $rbuf);
 477         0;
 478     } else {
 479         $self->close;
 480     }
 481 }
 482
 483 # drop the socket if we hit unrecoverable errors on our system which
 484 # require BOFH attention: ENOSPC, EFBIG, EIO, EMFILE, ENFILE...
 485 sub drop {
 486     my $self = shift;
 487     carp(@_);
 488     $self->close;
 489 }
 490
 491 sub tmpio ($$$) {
 492         my ($self, $bref, $off) = @_;
 493         my $fh = tmpfile('wbuf', $self->{sock}, O_APPEND) or
 494                 return drop($self, "tmpfile $!");
 495         $fh->autoflush(1);
 496         my $len = length($$bref) - $off;
 497         my $n = syswrite($fh, $$bref, $len, $off) //
 498                 return drop($self, "write ($len): $!");
 499         $n == $len or return drop($self, "wrote $n < $len bytes");
 500         [ $fh, 0 ] # [1] = offset, [2] = length, not set by us
 501 }
 502
 503 =head2 C<< $obj->write( $data ) >>
 504
 505 Write the specified data to the underlying handle.  I<data> may be scalar,
 506 scalar ref, code ref (to run when there).
 507 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 508 it returns 1, caller should stop waiting for 'writable' events)
 509
 510 =cut
 511 sub write {
 512     my ($self, $data) = @_;
 513
 514     # nobody should be writing to closed sockets, but caller code can
 515     # do two writes within an event, have the first fail and
 516     # disconnect the other side (whose destructor then closes the
 517     # calling object, but it's still in a method), and then the
 518     # now-dead object does its second write.  that is this case.  we
 519     # just lie and say it worked.  it'll be dead soon and won't be
 520     # hurt by this lie.
 521     my $sock = $self->{sock} or return 1;
 522     my $ref = ref $data;
 523     my $bref = $ref ? $data : \$data;
 524     my $wbuf = $self->{wbuf};
 525     if ($wbuf && scalar(@$wbuf)) { # already buffering, can't write more...
 526         if ($ref eq 'CODE') {
 527             push @$wbuf, $bref;
 528         } else {
 529             my $tmpio = $wbuf->[-1];
 530             if ($tmpio && !defined($tmpio->[2])) { # append to tmp file buffer
 531                 $tmpio->[0]->print($$bref) or return drop($self, "print: $!");
 532             } else {
 533                 my $tmpio = tmpio($self, $bref, 0) or return 0;
 534                 push @$wbuf, $tmpio;
 535             }
 536         }
 537         return 0;
 538     } elsif ($ref eq 'CODE') {
 539         $bref->($self);
 540         return 1;
 541     } else {
 542         my $to_write = length($$bref);
 543         my $written = syswrite($sock, $$bref, $to_write);
 544
 545         if (defined $written) {
 546             return 1 if $written == $to_write;
 547             requeue($self); # runs: event_step -> flush_write
 548         } elsif ($! == EAGAIN) {
 549             my $ev = epbit($sock, EPOLLOUT) or return $self->close;
 550             epwait($sock, $ev | EPOLLONESHOT);
 551             $written = 0;
 552         } else {
 553             return $self->close;
 554         }
 555
 556         # deal with EAGAIN or partial write:
 557         my $tmpio = tmpio($self, $bref, $written) or return 0;
 558
 559         # wbuf may be an empty array if we're being called inside
 560         # ->flush_write via CODE bref:
 561         push @{$self->{wbuf}}, $tmpio; # autovivifies
 562         return 0;
 563     }
 564 }
 565
 566 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 567
 568 sub msg_more ($$) {
 569     my $self = $_[0];
 570     my $sock = $self->{sock} or return 1;
 571     my $wbuf = $self->{wbuf};
 572
 573     if (MSG_MORE && (!defined($wbuf) || !scalar(@$wbuf)) &&
 574                 !$sock->can('stop_SSL')) {
 575         my $n = send($sock, $_[1], MSG_MORE);
 576         if (defined $n) {
 577             my $nlen = length($_[1]) - $n;
 578             return 1 if $nlen == 0; # all done!
 579             # queue up the unwritten substring:
 580             my $tmpio = tmpio($self, \($_[1]), $n) or return 0;
 581             push @{$self->{wbuf}}, $tmpio; # autovivifies
 582             epwait($sock, EPOLLOUT|EPOLLONESHOT);
 583             return 0;
 584         }
 585     }
 586
 587     # don't redispatch into NNTPdeflate::write
 588     PublicInbox::DS::write($self, \($_[1]));
 589 }
 590
 591 sub epwait ($$) {
 592     my ($sock, $ev) = @_;
 593     epoll_ctl($Epoll, EPOLL_CTL_MOD, fileno($sock), $ev) and
 594         croak("EPOLL_CTL_MOD($sock): $!");
 595 }
 596
 597 # return true if complete, false if incomplete (or failure)
 598 sub accept_tls_step ($) {
 599     my ($self) = @_;
 600     my $sock = $self->{sock} or return;
 601     return 1 if $sock->accept_SSL;
 602     return $self->close if $! != EAGAIN;
 603     my $ev = PublicInbox::TLS::epollbit() or return $self->close;
 604     epwait($sock, $ev | EPOLLONESHOT);
 605     unshift(@{$self->{wbuf}}, \&accept_tls_step); # autovivifies
 606     0;
 607 }
 608
 609 # return true if complete, false if incomplete (or failure)
 610 sub shutdn_tls_step ($) {
 611     my ($self) = @_;
 612     my $sock = $self->{sock} or return;
 613     return $self->close if $sock->stop_SSL(SSL_fast_shutdown => 1);
 614     return $self->close if $! != EAGAIN;
 615     my $ev = PublicInbox::TLS::epollbit() or return $self->close;
 616     epwait($sock, $ev | EPOLLONESHOT);
 617     unshift(@{$self->{wbuf}}, \&shutdn_tls_step); # autovivifies
 618     0;
 619 }
 620
 621 # don't bother with shutdown($sock, 2), we don't fork+exec w/o CLOEXEC
 622 # or fork w/o exec, so no inadvertent socket sharing
 623 sub shutdn ($) {
 624     my ($self) = @_;
 625     my $sock = $self->{sock} or return;
 626     if ($sock->can('stop_SSL')) {
 627         shutdn_tls_step($self);
 628     } else {
 629         $self->close;
 630     }
 631 }
 632
 633 sub dwaitpid ($;$$) {
 634         my ($pid, $cb, $arg) = @_;
 635         if ($in_loop) {
 636                 push @$wait_pids, [ $pid, $cb, $arg ];
 637                 # We could've just missed our SIGCHLD, cover it, here:
 638                 enqueue_reap();
 639         } else {
 640                 my $ret = waitpid($pid, 0);
 641                 if ($ret == $pid) {
 642                         if ($cb) {
 643                                 eval { $cb->($arg, $pid) };
 644                                 carp "E: dwaitpid($pid) !in_loop: $@" if $@;
 645                         }
 646                 } else {
 647                         carp "waitpid($pid, 0) = $ret, \$!=$!, \$?=$?";
 648                 }
 649         }
 650 }
 651
 652 1;
 653
 654 =head1 AUTHORS (Danga::Socket)
 655
 656 Brad Fitzpatrick <brad@danga.com> - author
 657
 658 Michael Granger <ged@danga.com> - docs, testing
 659
 660 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 661
 662 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits