lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Used for generating Atom feeds for web-accessible mailing list archives.
   5 package PublicInbox::Feed;
   6 use strict;
   7 use warnings;
   8 use Email::Address;
   9 use Email::MIME;
  10 use Date::Parse qw(strptime);
  11 use PublicInbox::Hval;
  12 use PublicInbox::Git;
  13 use PublicInbox::View;
  14 use PublicInbox::MID qw/mid_clean mid2path/;
  15 use POSIX qw/strftime/;
  16 use constant {
  17         DATEFMT => '%Y-%m-%dT%H:%M:%SZ', # Atom standard
  18         MAX_PER_PAGE => 25, # this needs to be tunable
  19 };
  20
  21 use Encode qw/find_encoding/;
  22 my $enc_utf8 = find_encoding('UTF-8');
  23
  24 # main function
  25 sub generate {
  26         my ($ctx) = @_;
  27         sub { emit_atom($_[0], $ctx) };
  28 }
  29
  30 sub generate_thread_atom {
  31         my ($ctx) = @_;
  32         sub { emit_atom_thread($_[0], $ctx) };
  33 }
  34
  35 sub generate_html_index {
  36         my ($ctx) = @_;
  37         sub { emit_html_index($_[0], $ctx) };
  38 }
  39
  40 # private subs
  41
  42 sub title_tag {
  43         my ($title) = @_;
  44         # try to avoid the type attribute in title:
  45         $title = PublicInbox::Hval->new_oneline($title)->as_html;
  46         my $type = index($title, '&') >= 0 ? "\ntype=\"html\"" : '';
  47         "<title$type>$title</title>";
  48 }
  49
  50 sub atom_header {
  51         my ($feed_opts, $title) = @_;
  52
  53         $title = title_tag($feed_opts->{description}) unless (defined $title);
  54
  55         qq(<?xml version="1.0" encoding="us-ascii"?>\n) .
  56         qq{<feed\nxmlns="http://www.w3.org/2005/Atom">} .
  57         qq{$title} .
  58         qq(<link\nrel="alternate"\ntype="text/html") .
  59                 qq(\nhref="$feed_opts->{url}"/>) .
  60         qq(<link\nrel="self"\nhref="$feed_opts->{atomurl}"/>) .
  61         qq(<id>mailto:$feed_opts->{id_addr}</id>);
  62 }
  63
  64 sub emit_atom {
  65         my ($cb, $ctx) = @_;
  66         my $fh = $cb->([ 200, ['Content-Type' => 'application/atom+xml']]);
  67         my $max = $ctx->{max} || MAX_PER_PAGE;
  68         my $feed_opts = get_feedopts($ctx);
  69         my $x = atom_header($feed_opts);
  70         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
  71         each_recent_blob($ctx, sub {
  72                 my ($path, undef, $ts) = @_;
  73                 if (defined $x) {
  74                         $fh->write($x . feed_updated(undef, $ts));
  75                         $x = undef;
  76                 }
  77                 add_to_feed($feed_opts, $fh, $path, $git);
  78         });
  79         end_feed($fh);
  80 }
  81
  82 sub _no_thread {
  83         my ($cb) = @_;
  84         my $fh = $cb->([404, ['Content-Type' => 'text/plain']]);
  85         $fh->write("No feed found for thread\n");
  86         $fh->close;
  87 }
  88
  89 sub end_feed {
  90         my ($fh) = @_;
  91         Email::Address->purge_cache;
  92         $fh->write('</feed>');
  93         $fh->close;
  94 }
  95
  96 sub emit_atom_thread {
  97         my ($cb, $ctx) = @_;
  98         my $res = $ctx->{srch}->get_thread($ctx->{mid});
  99         return _no_thread($cb) unless $res->{total};
 100         my $fh = $cb->([200, ['Content-Type' => 'application/atom+xml']]);
 101         my $feed_opts = get_feedopts($ctx);
 102
 103         my $html_url = $feed_opts->{atomurl} = $ctx->{self_url};
 104         $html_url =~ s!/t\.atom\z!/!;
 105         $feed_opts->{url} = $html_url;
 106         $feed_opts->{emit_header} = 1;
 107
 108         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
 109         foreach my $msg (@{$res->{msgs}}) {
 110                 add_to_feed($feed_opts, $fh, mid2path($msg->mid), $git);
 111         }
 112         end_feed($fh);
 113 }
 114
 115 sub emit_html_index {
 116         my ($cb, $ctx) = @_;
 117         my $fh = $cb->([200,['Content-Type'=>'text/html; charset=UTF-8']]);
 118
 119         my $max = $ctx->{max} || MAX_PER_PAGE;
 120         my $feed_opts = get_feedopts($ctx);
 121
 122         my $title = $feed_opts->{description} || '';
 123         $title = PublicInbox::Hval->new_oneline($title)->as_html;
 124         my ($footer, $param, $last);
 125         my $state = { ctx => $ctx, seen => {}, anchor_idx => 0 };
 126         my $srch = $ctx->{srch};
 127
 128         my $top = "<b>$title</b> (<a\nhref=\"new.atom\">Atom feed</a>)";
 129
 130         if ($srch) {
 131                 $top = qq{<form\naction=""><pre>$top} .
 132                           qq{ <input\nname=q\ntype=text />} .
 133                           qq{<input\ntype=submit\nvalue=search />} .
 134                           q{</pre></form><pre>}
 135         } else {
 136                 $top = '<pre>' . $top . "\n";
 137         }
 138
 139         $fh->write("<html><head><title>$title</title>" .
 140                    "<link\nrel=alternate\ntitle=\"Atom feed\"\n".
 141                    "href=\"new.atom\"\ntype=\"application/atom+xml\"/>" .
 142                    PublicInbox::Hval::STYLE .
 143                    "</head><body>$top");
 144
 145         # if the 'r' query parameter is given, it is a legacy permalink
 146         # which we must continue supporting:
 147         my $cgi = $ctx->{cgi};
 148         if ($cgi && !$cgi->param('r') && $srch) {
 149                 $state->{srch} = $srch;
 150                 $last = PublicInbox::View::emit_index_topics($state, $fh);
 151                 $param = 'o';
 152         } else {
 153                 $last = emit_index_nosrch($ctx, $state, $fh);
 154                 $param = 'r';
 155         }
 156         $footer = nav_footer($cgi, $last, $feed_opts, $state, $param);
 157         if ($footer) {
 158                 my $list_footer = $ctx->{footer};
 159                 $footer .= "\n\n" . $list_footer if $list_footer;
 160                 $footer = "<hr /><pre>$footer</pre>";
 161         }
 162         $fh->write("$footer</body></html>");
 163         $fh->close;
 164 }
 165
 166 sub emit_index_nosrch {
 167         my ($ctx, $state, $fh) = @_;
 168         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
 169         my (undef, $last) = each_recent_blob($ctx, sub {
 170                 my ($path, $commit, $ts, $u, $subj) = @_;
 171                 $state->{first} ||= $commit;
 172
 173                 my $mime = do_cat_mail($git, $path) or return 0;
 174                 PublicInbox::View::index_entry($fh, $mime, 0, $state);
 175                 1;
 176         });
 177         Email::Address->purge_cache;
 178         $last;
 179 }
 180
 181 sub nav_footer {
 182         my ($cgi, $last, $feed_opts, $state, $param) = @_;
 183         $cgi or return '';
 184         my $old_r = $cgi->param($param);
 185         my $head = '    ';
 186         my $next = '    ';
 187         my $first = $state->{first};
 188         my $anchor = $state->{anchor_idx};
 189
 190         if ($last) {
 191                 $next = qq!<a\nhref="?$param=$last">next</a>!;
 192         }
 193         if ($old_r) {
 194                 $head = $cgi->path_info;
 195                 $head = qq!<a\nhref="$head">head</a>!;
 196         }
 197         my $atom = "<a\nhref=\"$feed_opts->{atomurl}\">Atom feed</a>";
 198         "<a\nname=\"s$anchor\">page:</a> $next $head $atom";
 199 }
 200
 201 sub each_recent_blob {
 202         my ($ctx, $cb) = @_;
 203         my $max = $ctx->{max} || MAX_PER_PAGE;
 204         my $hex = '[a-f0-9]';
 205         my $addmsg = qr!^:000000 100644 \S+ \S+ A\t(${hex}{2}/${hex}{38})$!;
 206         my $delmsg = qr!^:100644 000000 \S+ \S+ D\t(${hex}{2}/${hex}{38})$!;
 207         my $refhex = qr/(?:HEAD|${hex}{4,40})(?:~\d+)?/;
 208         my $cgi = $ctx->{cgi};
 209
 210         # revision ranges may be specified
 211         my $range = 'HEAD';
 212         my $r = $cgi->param('r') if $cgi;
 213         if ($r && ($r =~ /\A(?:$refhex\.\.)?$refhex\z/o)) {
 214                 $range = $r;
 215         }
 216
 217         # get recent messages
 218         # we could use git log -z, but, we already know ssoma will not
 219         # leave us with filenames with spaces in them..
 220         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
 221         my $log = $git->popen(qw/log --no-notes --no-color --raw -r
 222                                 --abbrev=16 --abbrev-commit/,
 223                                 "--format=%h%x00%ct%x00%an%x00%s%x00",
 224                                 $range);
 225         my %deleted; # only an optimization at this point
 226         my $last;
 227         my $nr = 0;
 228         my ($cur_commit, $first_commit, $last_commit);
 229         my ($ts, $subj, $u);
 230         while (defined(my $line = <$log>)) {
 231                 if ($line =~ /$addmsg/o) {
 232                         my $add = $1;
 233                         next if $deleted{$add}; # optimization-only
 234                         $nr += $cb->($add, $cur_commit, $ts, $u, $subj);
 235                         if ($nr >= $max) {
 236                                 $last = 1;
 237                                 last;
 238                         }
 239                 } elsif ($line =~ /$delmsg/o) {
 240                         $deleted{$1} = 1;
 241                 } elsif ($line =~ /^${hex}{7,40}/o) {
 242                         ($cur_commit, $ts, $u, $subj) = split("\0", $line);
 243                         unless (defined $first_commit) {
 244                                 $first_commit = $cur_commit;
 245                         }
 246                 }
 247         }
 248
 249         if ($last) {
 250                 while (my $line = <$log>) {
 251                         if ($line =~ /^(${hex}{7,40})/o) {
 252                                 $last_commit = $1;
 253                                 last;
 254                         }
 255                 }
 256         }
 257
 258         # for pagination
 259         ($first_commit, $last_commit);
 260 }
 261
 262 # private functions below
 263 sub get_feedopts {
 264         my ($ctx) = @_;
 265         my $pi_config = $ctx->{pi_config};
 266         my $listname = $ctx->{listname};
 267         my $cgi = $ctx->{cgi};
 268         my %rv;
 269         if (open my $fh, '<', "$ctx->{git_dir}/description") {
 270                 chomp($rv{description} = <$fh>);
 271         } else {
 272                 $rv{description} = '($GIT_DIR/description missing)';
 273         }
 274
 275         if ($pi_config && defined $listname && $listname ne '') {
 276                 my $addr = $pi_config->get($listname, 'address') || "";
 277                 $rv{address} = $addr;
 278                 $addr = $addr->[0] if ref($addr);
 279                 $rv{id_addr} = $addr;
 280         }
 281         $rv{id_addr} ||= 'public-inbox@example.com';
 282
 283         my $url_base;
 284         if ($cgi) {
 285                 $url_base = $cgi->base->as_string . $listname;
 286                 if (my $mid = $ctx->{mid}) { # per-thread feed:
 287                         $rv{atomurl} = "$url_base/$mid/t.atom";
 288                 } else {
 289                         $rv{atomurl} = "$url_base/new.atom";
 290                 }
 291         } else {
 292                 $url_base = "http://example.com";
 293                 $rv{atomurl} = "$url_base/new.atom";
 294         }
 295         $rv{url} ||= "$url_base/";
 296         $rv{midurl} = "$url_base/";
 297
 298         \%rv;
 299 }
 300
 301 sub mime_header {
 302         my ($mime, $name) = @_;
 303         PublicInbox::Hval->new_oneline($mime->header($name))->raw;
 304 }
 305
 306 sub feed_updated {
 307         my ($date, $ts) = @_;
 308         my @t = eval { strptime($date) } if defined $date;
 309         @t = gmtime($ts || time) unless scalar @t;
 310
 311         '<updated>' . strftime(DATEFMT, @t) . '</updated>';
 312 }
 313
 314 # returns 0 (skipped) or 1 (added)
 315 sub add_to_feed {
 316         my ($feed_opts, $fh, $add, $git) = @_;
 317
 318         my $mime = do_cat_mail($git, $add) or return 0;
 319         my $url = $feed_opts->{url};
 320         my $midurl = $feed_opts->{midurl};
 321
 322         my $header_obj = $mime->header_obj;
 323         my $mid = $header_obj->header_raw('Message-ID');
 324         defined $mid or return 0;
 325         $mid = PublicInbox::Hval->new_msgid($mid);
 326         my $href = $mid->as_href;
 327         my $content = PublicInbox::View->feed_entry($mime, "$midurl$href/f/");
 328         defined($content) or return 0;
 329         $mime = undef;
 330
 331         my $date = $header_obj->header('Date');
 332         my $updated = feed_updated($date);
 333
 334         my $title = mime_header($header_obj, 'Subject') or return 0;
 335         $title = title_tag($title);
 336
 337         my $from = mime_header($header_obj, 'From') or return 0;
 338         my @from = Email::Address->parse($from) or return 0;
 339         my $name = PublicInbox::Hval->new_oneline($from[0]->name)->as_html;
 340         my $email = $from[0]->address;
 341         $email = PublicInbox::Hval->new_oneline($email)->as_html;
 342
 343         if (delete $feed_opts->{emit_header}) {
 344                 $fh->write(atom_header($feed_opts, $title) . $updated);
 345         }
 346         $fh->write("<entry><author><name>$name</name><email>$email</email>" .
 347                    "</author>$title$updated" .
 348                    qq{<content\ntype="xhtml">} .
 349                    qq{<div\nxmlns="http://www.w3.org/1999/xhtml">});
 350         $fh->write($content);
 351
 352         $add =~ tr!/!!d;
 353         my $h = '[a-f0-9]';
 354         my (@uuid5) = ($add =~ m!\A($h{8})($h{4})($h{4})($h{4})($h{12})!o);
 355         my $id = 'urn:uuid:' . join('-', @uuid5);
 356         $fh->write(qq!</div></content><link\nhref="$midurl$href/"/>!.
 357                    "<id>$id</id></entry>");
 358         1;
 359 }
 360
 361 sub do_cat_mail {
 362         my ($git, $path) = @_;
 363         my $mime = eval {
 364                 my $str = $git->cat_file("HEAD:$path");
 365                 Email::MIME->new($str);
 366         };
 367         $@ ? undef : $mime;
 368 }
 369
 370 1;