lib/PublicInbox/LEI.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use v5.12;
  10 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  11         PublicInbox::LeiQuery);
  12 use Getopt::Long ();
  13 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  14 use Errno qw(EPIPE EAGAIN ECONNREFUSED ENOENT ECONNRESET);
  15 use Cwd qw(getcwd);
  16 use POSIX qw(strftime);
  17 use IO::Handle ();
  18 use Fcntl qw(SEEK_SET);
  19 use PublicInbox::Config;
  20 use PublicInbox::Syscall qw(EPOLLIN);
  21 use PublicInbox::DS qw(dwaitpid);
  22 use PublicInbox::Spawn qw(spawn popen_rd);
  23 use PublicInbox::Lock;
  24 use PublicInbox::Eml;
  25 use PublicInbox::Import;
  26 use PublicInbox::ContentHash qw(git_sha);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 use Sys::Syslog qw(openlog syslog closelog);
  31 our $quit = \&CORE::exit;
  32 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  33         $recv_cmd, $send_cmd);
  34 my $GLP = Getopt::Long::Parser->new;
  35 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  36 my $GLP_PASS = Getopt::Long::Parser->new;
  37 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  38
  39 our %PATH2CFG; # persistent for socket daemon
  40 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  41
  42 # TBD: this is a documentation mechanism to show a subcommand
  43 # (may) pass options through to another command:
  44 sub pass_through { $GLP_PASS }
  45
  46 my $OPT;
  47 sub opt_dash ($$) {
  48         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  49         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  50         my $cb = sub { # Getopt::Long "<>" catch-all handler
  51                 my ($arg) = @_;
  52                 if ($arg =~ /\A-($re_str)\z/) {
  53                         $OPT->{$key} = $1;
  54                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  55                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  56                 # lone (single) dash is handled elsewhere
  57                 } elsif (substr($arg, 0, 1) eq '-') {
  58                         if ($OPT->{'--'}) {
  59                                 push @{$OPT->{-argv}}, $arg;
  60                         } else {
  61                                 die "bad argument: $arg\n";
  62                         }
  63                 } else {
  64                         push @{$OPT->{-argv}}, $arg;
  65                 }
  66         };
  67         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  68 }
  69
  70 # rel2abs preserves symlinks in parent, unlike abs_path
  71 sub rel2abs {
  72         my ($self, $p) = @_;
  73         if (index($p, '/') == 0) { # already absolute
  74                 $p =~ tr!/!/!s; # squeeze redundant slashes
  75                 chop($p) if substr($p, -1, 1) eq '/';
  76                 return $p;
  77         }
  78         my $pwd = $self->{env}->{PWD};
  79         if (defined $pwd) {
  80                 if (my @st_pwd = stat($pwd)) {
  81                         my @st_cwd = stat($self->{3}) or die "stat({3}): $!";
  82                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  83                                 $self->{env}->{PWD} = $pwd = undef;
  84                 } else { # PWD was invalid
  85                         $self->{env}->{PWD} = $pwd = undef;
  86                 }
  87         }
  88         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd: $!";
  89         File::Spec->rel2abs($p, $pwd);
  90 }
  91
  92 # abs_path resolves symlinks in parent iff all parents exist
  93 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  94
  95 sub canonpath_harder {
  96         my $p = $_[-1]; # $_[0] may be self
  97         $p = File::Spec->canonpath($p);
  98         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
  99 }
 100
 101 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 102         my ($self) = @_;
 103         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 104                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 105                 .'/lei');
 106 }
 107
 108 sub store_path ($) { share_path($_[0]) . '/store' }
 109
 110 sub _config_path ($) {
 111         my ($self) = @_;
 112         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 113                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 114                 .'/lei/config');
 115 }
 116
 117 sub cache_dir ($) {
 118         my ($self) = @_;
 119         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 120                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 121                 .'/lei');
 122 }
 123
 124 sub url_folder_cache {
 125         my ($self) = @_;
 126         require PublicInbox::SharedKV; # URI => updated_at_sec_
 127         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 128 }
 129
 130 sub ale {
 131         my ($self) = @_;
 132         $self->{ale} // do {
 133                 require PublicInbox::LeiALE;
 134                 my $cfg = $self->_lei_cfg(1);
 135                 $self->{ale} = $cfg->{ale} //= PublicInbox::LeiALE->new($self);
 136         };
 137 }
 138
 139 sub index_opt {
 140         # TODO: drop underscore variants everywhere, they're undocumented
 141         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 142         max_size|max-size=s sequential-shard
 143         batch_size|batch-size=s skip-docdata)
 144 }
 145
 146 my @c_opt = qw(c=s@ C=s@ quiet|q);
 147 my @net_opt = (qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt());
 148 my @lxs_opt = qw(remote! local! external! include|I=s@ exclude=s@ only|O=s@
 149         import-remote!);
 150
 151 # we don't support -C as an alias for --find-copies since it's already
 152 # used for chdir
 153 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 154         output-indicator-context=s indent-heuristic!
 155         minimal patience histogram anchored=s@ diff-algorithm=s
 156         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 157         word-diff:s word-diff-regex=s color-words:s no-renames
 158         rename-empty! check ws-error-highlight=s full-index binary
 159         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 160         find-copies-harder irreversible-delete|D l=i diff-filter=s
 161         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 162         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 163         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 164         inter-hunk-context=i function-context|W exit-code ext-diff
 165         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 166         line-prefix=s);
 167
 168 # we generate shell completion + help using %CMD and %OPTDESC,
 169 # see lei__complete() and PublicInbox::LeiHelp
 170 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 171 our %CMD = ( # sorted in order of importance/use:
 172 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 173         'stdin|', # /|\z/ must be first for lone dash
 174         @lxs_opt, @net_opt,
 175         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 176         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 177         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 178         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 179
 180 'up' => [ 'OUTPUT...|--all', 'update saved search',
 181         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ exclude=s@
 182         remote-fudge-time=s all:s remote! local! external!), @net_opt, @c_opt ],
 183
 184 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         # some of these options are ridiculous for lcat
 187         @lxs_opt, @net_opt,
 188         qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 189         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 190         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 191         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 192
 193 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 194         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 195         @lxs_opt, @net_opt, @c_opt ],
 196
 197 'rediff' => [ '--stdin|LOCATION...',
 198                 'regenerate a diff with different options',
 199         'stdin|', # /|\z/ must be first for lone dash
 200         qw(git-dir=s@ cwd! verbose|v+ color:s no-color drq:1 dequote-only:1),
 201         @diff_opt, @lxs_opt, @net_opt, @c_opt ],
 202
 203 'mail-diff' => [ '--stdin|LOCATION...', 'diff the contents of emails',
 204         'stdin|', # /|\z/ must be first for lone dash
 205         qw(verbose|v+ in-format|F=s color:s no-color raw-header),
 206         @diff_opt, @net_opt, @c_opt ],
 207
 208 'add-external' => [ 'LOCATION',
 209         'add/set priority of a publicinbox|extindex for extra matches',
 210         qw(boost=i mirror=s inbox-version=i epoch=s verbose|v+),
 211         @c_opt, index_opt(), @net_opt ],
 212 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 213         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 214 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 215 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 216                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 217 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 218                 qw(z|0 ascii l pretty url), @net_opt, @c_opt ],
 219 'forget-external' => [ 'LOCATION...|--prune',
 220         'exclude further results from a publicinbox|extindex',
 221         qw(prune), @c_opt ],
 222
 223 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 224                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 225 'forget-search' => [ 'OUTPUT...|--prune', 'forget a saved search',
 226                 qw(verbose|v+ prune:s), @c_opt ],
 227 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 228                         @c_opt ],
 229 'rm' => [ '--stdin|LOCATION...',
 230         'remove a message from the index and prevent reindexing',
 231         'stdin|', # /|\z/ must be first for lone dash
 232         qw(in-format|F=s lock=s@), @net_opt, @c_opt ],
 233 'plonk' => [ '--threads|--from=IDENT',
 234         'exclude mail matching From: or threads from non-Message-ID searches',
 235         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 236 'tag' => [ 'KEYWORDS...',
 237         'set/unset keywords and/or labels on message(s)',
 238         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 239         @net_opt, @c_opt, pass_through('-kw:foo for delete') ],
 240
 241 'purge-mailsource' => [ 'LOCATION|--all',
 242         'remove imported messages from IMAP, Maildirs, and MH',
 243         qw(exact! all jobs:i indexed), @c_opt ],
 244
 245 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 246         qw(poll-interval=s state=s recursive|r), @c_opt ],
 247 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 248         qw(recursive|r), @c_opt ],
 249 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 250                 qw(l z|0), @c_opt ],
 251 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 252 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 253 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 254         qw(prune), @c_opt ],
 255
 256 'reindex' => [ '', 'reindex all locally-indexed messages', @c_opt ],
 257
 258 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 259         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 260         verbose|v+ incremental!), @net_opt, # mainly for --proxy=
 261          @c_opt ],
 262 'import' => [ 'LOCATION...|--stdin',
 263         'one-time import/update from URL or filesystem',
 264         qw(stdin| offset=i recursive|r exclude=s include|I=s new-only
 265         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 266         @net_opt, @c_opt ],
 267 'forget-mail-sync' => [ 'LOCATION...',
 268         'forget sync information for a mail folder', @c_opt ],
 269 'refresh-mail-sync' => [ 'LOCATION...|--all',
 270         'prune dangling sync data for a mail folder', 'all:s',
 271                 @net_opt, @c_opt ],
 272 'export-kw' => [ 'LOCATION...|--all',
 273         'one-time export of keywords of sync sources',
 274         qw(all:s mode=s), @net_opt, @c_opt ],
 275 'convert' => [ 'LOCATION...|--stdin',
 276         'one-time conversion from URL or filesystem to another format',
 277         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 278         @net_opt, @c_opt ],
 279 'p2q' => [ 'LOCATION_OR_COMMIT...|--stdin',
 280         "use a patch to generate a query for `lei q --stdin'",
 281         qw(stdin| in-format|F=s want|w=s@ uri debug), @net_opt, @c_opt ],
 282 'config' => [ '[...]', sub {
 283                 'git-config(1) wrapper for '._config_path($_[0]);
 284         }, qw(config-file|system|global|file|f=s), # for conflict detection
 285          qw(edit|e c=s@ C=s@), pass_through('git config') ],
 286 'inspect' => [ 'ITEMS...|--stdin', 'inspect lei/store and/or local external',
 287         qw(stdin| pretty ascii dir|d=s), @c_opt ],
 288
 289 'init' => [ '[DIRNAME]', sub {
 290         "initialize storage, default: ".store_path($_[0]);
 291         }, @c_opt ],
 292 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 293         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 294         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 295 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 296 'help' => [ '[SUBCOMMAND]', 'show help' ],
 297
 298 # TODO
 299 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 300 #       'rewrite git history in an attempt to improve compression',
 301 #       qw(gc!), @c_opt ],
 302 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 303 #
 304 # internal commands are prefixed with '_'
 305 '_complete' => [ '[...]', 'internal shell completion helper',
 306                 pass_through('everything') ],
 307 ); # @CMD
 308
 309 # switch descriptions, try to keep consistent across commands
 310 # $spec: Getopt::Long option specification
 311 # $spec => [@ALLOWED_VALUES (default is first), $description],
 312 # $spec => $description
 313 # "$SUB_COMMAND TAB $spec" => as above
 314 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 315                         'specify message input format' ];
 316 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 317
 318 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 319 my %OPTDESC = (
 320 'help|h' => 'show this built-in help',
 321 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 322 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 323 'quiet|q' => 'be quiet',
 324 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 325         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 326
 327 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 328 'globoff|g' => "do not match locations using '*?' wildcards ".
 329                 "and\xa0'[]'\x{a0}ranges",
 330 'invert-match|v' => 'select non-matching lines',
 331 'color!' => 'disable color (for --format=text)',
 332 'verbose|v+' => 'be more verbose',
 333 'external!' => 'do not use externals',
 334 'mail!' => 'do not look in mail storage for OID',
 335 'cwd!' => 'do not look in git repo of current working directory',
 336 'oid-a|A=s' => 'pre-image OID',
 337 'path-a|a=s' => 'pre-image pathname associated with OID',
 338 'path-b|b=s' => 'post-image pathname associated with OID',
 339 'git-dir=s@' => 'additional git repository to scan',
 340 'dir|d=s        inspect' =>
 341         'specify a inboxdir, extindex topdir or Xapian shard',
 342 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 343         "proxy for (e.g. `socks5h://0:9050')" ],
 344 'torsocks=s' => ['VAL|auto|no|yes',
 345                 'whether or not to wrap git and curl commands with torsocks'],
 346 'no-torsocks' => 'alias for --torsocks=no',
 347 'save!' =>  "do not save a search for `lei up'",
 348 'import-remote!' => 'do not memoize remote messages into local store',
 349
 350 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 351
 352 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 353                 'deduplication strategy'],
 354 'threads|t+' =>
 355         'return all messages in the same threads as the actual match(es)',
 356
 357 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 358                 'search prefixes to extract (default: dfpost7)' ],
 359 'uri    p2q' => [ 'URI escape output' ],
 360
 361 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 362         'run command(s) or perform ops when done writing to output ' .
 363         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 364         'nothing otherwise)' ],
 365
 366 'augment|a' => 'augment --output destination instead of clobbering',
 367
 368 'output|mfolder|o=s' => [ 'MFOLDER',
 369         "destination (e.g.\xa0`/path/to/Maildir', ".
 370         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 371 'mua=s' => [ 'CMD',
 372         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 373 'new-only       import' => 'only import new messages from IMAP source',
 374
 375 'inbox-version=i' => [ 'NUM|1|2',
 376                 'force a public-inbox version with --mirror'],
 377 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 378
 379 # public-inbox-index options
 380 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 381 'compact' => 'run compact index after mirroring',
 382 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 383         "indexlevel with --mirror (default: full)" ],
 384 'max_size|max-size=s' => [ 'SIZE',
 385         'do not index messages larger than SIZE (default: infinity)' ],
 386 'batch_size|batch-size=s' => [ 'SIZE',
 387         'flush changes to OS after given number of bytes (default: 1m)' ],
 388 'sequential-shard' =>
 389         'index Xapian shards sequentially for slow storage',
 390 'skip-docdata' =>
 391         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 392
 393 'format|f=s     q' => [
 394         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 395                 'specify output format, default depends on --output'],
 396 'exclude=s@     q' => [ 'LOCATION',
 397                 'exclude specified external(s) from search' ],
 398 'include|I=s@   q' => [ 'LOCATION',
 399                 'include specified external(s) in search' ],
 400 'only|O=s@      q' => [ 'LOCATION',
 401                 'only use specified external(s) for search' ],
 402 'jobs|j=s' => [ 'JOBSPEC',
 403                 'control number of query and writer jobs' .
 404                 "integers delimited by `,', either of which may be omitted"
 405                 ],
 406 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 407
 408 'in-format|F=s' => $stdin_formats,
 409 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 410                         'listing output format' ],
 411 'l      ls-search' => 'long listing format',
 412 'l      ls-watch' => 'long listing format',
 413 'l      ls-mail-source' => 'long listing format',
 414 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 415 'format|f=s     ls-external' => $ls_format,
 416
 417 'prune:s        forget-search' =>
 418         ['TYPE|local|remote', 'prune all, remote or local folders' ],
 419
 420 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 421 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 422
 423 'sort|s=s' => [ 'VAL|received|relevance|docid',
 424                 "order of results is `--output'-dependent"],
 425 'reverse|r' => 'reverse search results', # like sort(1)
 426
 427 'boost=i' => 'increase/decrease priority of results (default: 0)',
 428
 429 'local' => 'limit operations to the local filesystem',
 430 'local!' => 'exclude results from the local filesystem',
 431 'remote' => 'limit operations to those requiring network access',
 432 'remote!' => 'prevent operations requiring network access',
 433
 434 # up, refresh-mail-sync, export-kw
 435 'all:s' => ['TYPE|local|remote', 'all remote or local folders' ],
 436
 437 'remote-fudge-time=s' => [ 'INTERVAL',
 438         'look for mail INTERVAL older than the last successful query' ],
 439
 440 'mid=s' => 'specify the Message-ID of a message',
 441 'oid=s' => 'specify the git object ID of a message',
 442
 443 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 444 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 445 'include=s' => 'include mailboxes/newsgroups based on pattern',
 446
 447 'exact' => 'operate on exact header matches only',
 448 'exact!' => 'rely on content match instead of exact header matches',
 449
 450 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 451
 452 'kw!' => 'disable/enable importing keywords (aka "flags")',
 453
 454 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 455 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 456
 457 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 458 ); # %OPTDESC
 459
 460 my %CONFIG_KEYS = (
 461         'leistore.dir' => 'top-level storage location',
 462 );
 463
 464 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne v2w); # internal workers
 465
 466 sub _drop_wq {
 467         my ($self) = @_;
 468         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 469                 $wq->wq_kill('-TERM');
 470                 $wq->DESTROY;
 471         }
 472 }
 473
 474 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 475 sub x_it ($$) {
 476         my ($self, $code) = @_;
 477         local $current_lei = $self;
 478         # make sure client sees stdout before exit
 479         $self->{1}->autoflush(1) if $self->{1};
 480         stop_pager($self);
 481         if ($self->{pkt_op_p}) { # worker => lei-daemon
 482                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 483         } elsif ($self->{sock}) { # lei->daemon => lei(1) client
 484                 send($self->{sock}, "x_it $code", MSG_EOR);
 485         } elsif ($quit == \&CORE::exit) { # an admin (one-shot) command
 486                 exit($code >> 8);
 487         } # else ignore if client disconnected
 488 }
 489
 490 sub err ($;@) {
 491         my $self = shift;
 492         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 493         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 494         print $err @_, @eor and return;
 495         my $old_err = delete $self->{2};
 496         close($old_err) if $! == EPIPE && $old_err;
 497         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 498         print $err @_, @eor or print STDERR @_, @eor;
 499 }
 500
 501 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 502
 503 sub qfin { # show message on finalization (LeiFinmsg)
 504         my ($lei, $msg) = @_;
 505         return if $lei->{opt}->{quiet};
 506         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 507 }
 508
 509 sub fail_handler ($;$$) {
 510         my ($lei, $code, $io) = @_;
 511         local $current_lei = $lei;
 512         close($io) if $io; # needed to avoid warnings on SIGPIPE
 513         _drop_wq($lei);
 514         x_it($lei, $code // (1 << 8));
 515 }
 516
 517 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 518         fail_handler($_[0], 13, delete $_[0]->{1});
 519 }
 520
 521 sub fail ($$;$) {
 522         my ($self, $msg, $exit_code) = @_;
 523         local $current_lei = $self;
 524         $self->{failed}++;
 525         warn(substr($msg, -1, 1) eq "\n" ? $msg : "$msg\n") if defined $msg;
 526         $self->{pkt_op_p}->pkt_do('fail_handler') if $self->{pkt_op_p};
 527         x_it($self, ($exit_code // 1) << 8);
 528         undef;
 529 }
 530
 531 sub out ($;@) {
 532         my $self = shift;
 533         return if print { $self->{1} // return } @_; # likely
 534         return note_sigpipe($self, 1) if $! == EPIPE;
 535         my $err = "error writing to output: $!";
 536         delete $self->{1};
 537         fail($self, $err);
 538 }
 539
 540 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 541
 542 sub child_error { # passes non-fatal curl exit codes to user
 543         my ($self, $child_error, $msg) = @_; # child_error is $?
 544         local $current_lei = $self;
 545         $child_error ||= 1 << 8;
 546         warn(substr($msg, -1, 1) eq "\n" ? $msg : "$msg\n") if defined $msg;
 547         $self->{child_error} ||= $child_error;
 548         if ($self->{pkt_op_p}) { # to top lei-daemon
 549                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 550         } elsif ($self->{sock}) { # to lei(1) client
 551                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 552         } # else noop if client disconnected
 553 }
 554
 555 sub note_sigpipe { # triggers sigpipe_handler
 556         my ($self, $fd) = @_;
 557         close(delete($self->{$fd})); # explicit close silences Perl warning
 558         $self->{pkt_op_p}->pkt_do('sigpipe_handler') if $self->{pkt_op_p};
 559         x_it($self, 13);
 560 }
 561
 562 sub _lei_atfork_child {
 563         my ($self, $persist) = @_;
 564         # we need to explicitly close things which are on stack
 565         if ($persist) {
 566                 open $self->{3}, '<', '/' or die "open(/) $!";
 567                 fchdir($self);
 568                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 569                 if (my $cfg = $self->{cfg}) {
 570                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 571                 }
 572         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 573                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 574                 STDERR->autoflush(1);
 575                 POSIX::setpgid(0, $$) // die "setpgid(0, $$): $!";
 576         }
 577         close($_) for (grep(defined, delete @$self{qw(old_1 au_done)}));
 578         delete $self->{-socks};
 579         if (my $op_c = delete $self->{pkt_op_c}) {
 580                 close(delete $op_c->{sock});
 581         }
 582         if (my $pgr = delete $self->{pgr}) {
 583                 close($_) for (@$pgr[1,2]);
 584         }
 585         close $listener if $listener;
 586         undef $listener;
 587         $dir_idle->force_close if $dir_idle;
 588         undef $dir_idle;
 589         %PATH2CFG = ();
 590         $MDIR2CFGPATH = {};
 591         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 592         undef $errors_log;
 593         $quit = \&CORE::exit;
 594         if (!$self->{-eml_noisy}) { # only "lei import" sets this atm
 595                 my $cb = $SIG{__WARN__} // \&CORE::warn;
 596                 $SIG{__WARN__} = sub {
 597                         $cb->(@_) unless PublicInbox::Eml::warn_ignore(@_)
 598                 };
 599         }
 600         $SIG{TERM} = sub { exit(128 + 15) };
 601         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 602 }
 603
 604 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 605         my ($self) = @_;
 606         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 607                 $op->close; # PublicInbox::PktOp::close
 608         }
 609         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 610         close $pkt_op_p->{op_p};
 611 }
 612
 613 sub pkt_op_pair {
 614         my ($self) = @_;
 615         require PublicInbox::OnDestroy;
 616         require PublicInbox::PktOp;
 617         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 618         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 619         $end;
 620 }
 621
 622 sub incr {
 623         my ($self, $field, $nr) = @_;
 624         $self->{counters}->{$field} += $nr;
 625 }
 626
 627 sub pkt_ops {
 628         my ($lei, $ops) = @_;
 629         $ops->{fail_handler} = [ $lei ];
 630         $ops->{sigpipe_handler} = [ $lei ];
 631         $ops->{x_it} = [ $lei ];
 632         $ops->{child_error} = [ $lei ];
 633         $ops->{incr} = [ $lei ];
 634         $ops;
 635 }
 636
 637 sub workers_start {
 638         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 639         $ops //= {};
 640         ($wq->can('net_merge_all_done') && $lei->{auth}) and
 641                 $lei->{auth}->op_merge($ops, $wq, $lei);
 642         pkt_ops($lei, $ops);
 643         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 644         my $end = $lei->pkt_op_pair;
 645         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 646         $flds->{lei} = $lei;
 647         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 648         delete $lei->{pkt_op_p};
 649         my $op_c = delete $lei->{pkt_op_c};
 650         @$end = ();
 651         $lei->event_step_init;
 652         $wq->wq_wait_async($wq->can('_wq_done_wait') // \&wq_done_wait, $lei);
 653         ($op_c, $ops);
 654 }
 655
 656 # call this when we're ready to wait on events and yield to other clients
 657 sub wait_wq_events {
 658         my ($lei, $op_c, $ops) = @_;
 659         my $wq1 = $lei->{wq1};
 660         ($wq1 && $wq1->can('net_merge_all_done') && !$lei->{auth}) and
 661                 $wq1->net_merge_all_done;
 662         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 663                 $wq->wq_close;
 664         }
 665         $wq1->{lei_sock} = $lei->{sock} if $wq1;
 666         $op_c->{ops} = $ops;
 667 }
 668
 669 sub wq1_start {
 670         my ($lei, $wq, $jobs) = @_;
 671         my ($op_c, $ops) = workers_start($lei, $wq, $jobs // 1);
 672         $lei->{wq1} = $wq;
 673         wait_wq_events($lei, $op_c, $ops); # net_merge_all_done if !{auth}
 674 }
 675
 676 sub _help {
 677         require PublicInbox::LeiHelp;
 678         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 679 }
 680
 681 sub optparse ($$$) {
 682         my ($self, $cmd, $argv) = @_;
 683         # allow _complete --help to complete, not show help
 684         return 1 if substr($cmd, 0, 1) eq '_';
 685         $self->{cmd} = $cmd;
 686         $OPT = $self->{opt} //= {};
 687         my $info = $CMD{$cmd} // [ '[...]' ];
 688         my ($proto, undef, @spec) = @$info;
 689         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 690         push @spec, qw(help|h);
 691         my $lone_dash;
 692         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 693                 $lone_dash = $spec[0];
 694                 $OPT->{$spec[0]} = \(my $var);
 695                 push @spec, '' => \$var;
 696         }
 697         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 698                 return _help($self, "bad arguments or options for $cmd");
 699         return _help($self) if $OPT->{help};
 700
 701         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 702
 703         # "-" aliases "stdin" or "clear"
 704         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 705
 706         my $i = 0;
 707         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 708         my ($err, $inf);
 709         my @args = split(/ /, $proto);
 710         for my $var (@args) {
 711                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 712                         $inf = defined($argv->[$i]) and last;
 713                         $var =~ s/\.\.\.\z//;
 714                         $err = "$var not supplied";
 715                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 716                         $argv->[$i++] // ($err = "$var not supplied");
 717                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 718                         $inf = 1;
 719                         last;
 720                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 721                         $i++;
 722                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 723                         $inf = 1 if index($var, '...') > 0;
 724                         my @or = split(/\|/, $var);
 725                         my $ok;
 726                         for my $o (@or) {
 727                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 728                                         my $sw = $1;
 729                                         # assume pipe/regular file on stdin
 730                                         # w/o args means stdin
 731                                         if ($sw eq 'stdin' && !@$argv &&
 732                                                         (-p $self->{0} ||
 733                                                          -f _) && -r _) {
 734                                                 $OPT->{stdin} //= 1;
 735                                         }
 736                                         $ok = defined($OPT->{$sw});
 737                                         last if $ok;
 738                                 } elsif (defined($argv->[$i])) {
 739                                         $ok = 1;
 740                                         $i++;
 741                                         last;
 742                                 } # else continue looping
 743                         }
 744                         last if $ok;
 745                         my $last = pop @or;
 746                         $err = join(', ', @or) . " or $last must be set";
 747                 } else {
 748                         warn "BUG: can't parse `$var' in $proto";
 749                 }
 750                 last if $err;
 751         }
 752         if (!$inf && scalar(@$argv) > scalar(@args)) {
 753                 $err //= 'too many arguments';
 754         }
 755         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 756 }
 757
 758 sub _tmp_cfg { # for lei -c <name>=<value> ...
 759         my ($self) = @_;
 760         my $cfg = _lei_cfg($self, 1);
 761         require File::Temp;
 762         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 763         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 764         $ft->autoflush(1);
 765         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 766 [include]
 767         path = $cfg->{-f}
 768 EOM
 769         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 770         for (@{$self->{opt}->{c}}) {
 771                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 772 `-c $_' is not of the form -c <name>=<value>'
 773 EOM
 774                 my $name = $1;
 775                 my $value = $2 // 1;
 776                 _config($self, '--add', $name, $value);
 777                 if (defined(my $v = $tmp->{$name})) {
 778                         if (ref($v) eq 'ARRAY') {
 779                                 push @$v, $value;
 780                         } else {
 781                                 $tmp->{$name} = [ $v, $value ];
 782                         }
 783                 } else {
 784                         $tmp->{$name} = $value;
 785                 }
 786         }
 787 }
 788
 789 sub lazy_cb ($$$) { # $pfx is _complete_ or lei_
 790         my ($self, $cmd, $pfx) = @_;
 791         my $ucmd = $cmd;
 792         $ucmd =~ tr/-/_/;
 793         my $cb;
 794         $cb = $self->can($pfx.$ucmd) and return $cb;
 795         my $base = $ucmd;
 796         $base =~ s/_([a-z])/\u$1/g;
 797         my $pkg = "PublicInbox::Lei\u$base";
 798         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 799                 $pkg->can($pfx.$ucmd) : undef;
 800 }
 801
 802 sub dispatch {
 803         my ($self, $cmd, @argv) = @_;
 804         fchdir($self);
 805         local %ENV = %{$self->{env}};
 806         local $current_lei = $self; # for __WARN__
 807         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 808         return _help($self, 'no command given') unless defined($cmd);
 809         # do not support Getopt bundling for this
 810         while ($cmd eq '-C' || $cmd eq '-c') {
 811                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 812                                         '-C DIRECTORY' : '-c <name>=<value>');
 813                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 814                 $cmd = shift(@argv) // return _help($self, 'no command given');
 815         }
 816         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 817                 optparse($self, $cmd, \@argv) or return;
 818                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 819                 if (my $chdir = $self->{opt}->{C}) {
 820                         for my $d (@$chdir) {
 821                                 next if $d eq ''; # same as git(1)
 822                                 chdir $d or return fail($self, "cd $d: $!");
 823                         }
 824                         open $self->{3}, '<', '.' or
 825                                 return fail($self, "open . $!");
 826                 }
 827                 $cb->($self, @argv);
 828         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 829                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 830                         or return _help($self, 'bad arguments or options');
 831                 _help($self);
 832         } else {
 833                 fail($self, "`$cmd' is not an lei command");
 834         }
 835 }
 836
 837 sub _lei_cfg ($;$) {
 838         my ($self, $creat) = @_;
 839         return $self->{cfg} if $self->{cfg};
 840         my $f = _config_path($self);
 841         my @st = stat($f);
 842         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 843         my ($sto, $sto_dir, $watches, $lne);
 844         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 845                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 846                 ($sto, $sto_dir, $watches, $lne) =
 847                                 @$cfg{qw(-lei_store leistore.dir -watches
 848                                         -lei_note_event)};
 849         }
 850         if (!@st) {
 851                 unless ($creat) {
 852                         delete $self->{cfg};
 853                         return bless {}, 'PublicInbox::Config';
 854                 }
 855                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 856                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 857                 open my $fh, '>>', $f or die "open($f): $!\n";
 858                 @st = stat($fh) or die "fstat($f): $!\n";
 859                 $cur_st = pack('dd', $st[10], $st[7]);
 860                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 861         }
 862         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{2});
 863         $cfg->{-st} = $cur_st;
 864         $cfg->{'-f'} = $f;
 865         if ($sto && canonpath_harder($sto_dir // store_path($self))
 866                         eq canonpath_harder($cfg->{'leistore.dir'} //
 867                                                 store_path($self))) {
 868                 $cfg->{-lei_store} = $sto;
 869                 $cfg->{-lei_note_event} = $lne;
 870                 $cfg->{-watches} = $watches if $watches;
 871         }
 872         if (scalar(keys %PATH2CFG) > 5) {
 873                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 874                 delete(@PATH2CFG{grep(!-f, keys %PATH2CFG)});
 875         }
 876         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 877         refresh_watches($self);
 878         $cfg;
 879 }
 880
 881 sub _lei_store ($;$) {
 882         my ($self, $creat) = @_;
 883         my $cfg = _lei_cfg($self, $creat) // return;
 884         $cfg->{-lei_store} //= do {
 885                 require PublicInbox::LeiStore;
 886                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 887                 return unless $creat || -d $dir;
 888                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 889         };
 890 }
 891
 892 sub _config {
 893         my ($self, @argv) = @_;
 894         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 895         my $cfg = _lei_cfg($self, 1);
 896         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 897         my %rdr = map { $_ => $self->{$_} } (0..2);
 898         waitpid(spawn($cmd, \%env, \%rdr), 0);
 899 }
 900
 901 sub lei_daemon_pid { puts shift, $$ }
 902
 903 sub lei_daemon_kill {
 904         my ($self) = @_;
 905         my $sig = $self->{opt}->{signal} // 'TERM';
 906         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 907 }
 908
 909 # Shell completion helper.  Used by lei-completion.bash and hopefully
 910 # other shells.  Try to do as much here as possible to avoid redundancy
 911 # and improve maintainability.
 912 sub lei__complete {
 913         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 914         shift @argv; # ignore "lei", the entire command is sent
 915         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 916         my $cmd = shift @argv;
 917         my $info = $CMD{$cmd} // do { # filter matching commands
 918                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 919                 return;
 920         };
 921         my ($proto, undef, @spec) = @$info;
 922         my $cur = pop @argv;
 923         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 924         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 925                 # gross special case since the only git-config options
 926                 # Consider moving to a table if we need more special cases
 927                 # we use Getopt::Long for are the ones we reject, so these
 928                 # are the ones we don't reject:
 929                 if ($cmd eq 'config') {
 930                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 931                         @spec = qw(add z|null get get-all unset unset-all
 932                                 replace-all get-urlmatch
 933                                 remove-section rename-section
 934                                 name-only list|l edit|e
 935                                 get-color-name get-colorbool);
 936                         # fall-through
 937                 }
 938                 # generate short/long names from Getopt::Long specs
 939                 puts $self, grep(/$re/, qw(--help -h -C), map {
 940                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 941                         } elsif (s/\+\z//) { # verbose|v+
 942                         } elsif (s/!\z//) {
 943                                 # negation: mail! => no-mail|mail
 944                                 s/([\w\-]+)/$1|no-$1/g
 945                         }
 946                         map {
 947                                 my $x = length > 1 ? "--$_" : "-$_";
 948                                 $x eq $_cur ? () : $x;
 949                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 950                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 951         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 952                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 953         }
 954
 955         # switch args (e.g. lei q -f mbox<TAB>)
 956         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 957                 my $opt = quotemeta $1;
 958                 puts $self, map {
 959                         my $v = $OPTDESC{$_};
 960                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 961                         # get rid of ALL CAPS placeholder (e.g "OUT")
 962                         # (TODO: completion for external paths)
 963                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 964                         @v;
 965                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 966         }
 967         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 968                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 969         }
 970         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 971         # proto parsing.
 972 }
 973
 974 sub exec_buf ($$) {
 975         my ($argv, $env) = @_;
 976         my $argc = scalar @$argv;
 977         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 978         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 979         $buf;
 980 }
 981
 982 sub start_mua {
 983         my ($self) = @_;
 984         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 985                 refresh_watches($self);
 986         }
 987         my $mua = $self->{opt}->{mua} // return;
 988         my $mfolder = $self->{ovv}->{dst};
 989         my (@cmd, $replaced);
 990         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 991                 @cmd = ($mua, '-f');
 992         # TODO: help wanted: other common FOSS MUAs
 993         } else {
 994                 require Text::ParseWords;
 995                 @cmd = Text::ParseWords::shellwords($mua);
 996                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 997                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 998         }
 999         push @cmd, $mfolder unless defined($replaced);
1000         if ($self->{sock}) { # lei(1) client process runs it
1001                 # restore terminal: echo $query | lei q --stdin --mua=...
1002                 my $io = [];
1003                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
1004                 send_exec_cmd($self, $io, \@cmd, {});
1005         }
1006         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
1007                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
1008         }
1009         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
1010         $self->{opt}->{quiet} = 1;
1011         delete $self->{-progress};
1012         delete $self->{opt}->{verbose};
1013 }
1014
1015 sub send_exec_cmd { # tell script/lei to execute a command
1016         my ($self, $io, $cmd, $env) = @_;
1017         my $sock = $self->{sock} // die 'lei client gone';
1018         my $fds = [ map { fileno($_) } @$io ];
1019         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
1020 }
1021
1022 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
1023         my ($self) = @_;
1024         my $alerts = $self->{opt}->{alert} // return;
1025         my $sock = $self->{sock};
1026         while (my $op = shift(@$alerts)) {
1027                 if ($op eq ':WINCH') {
1028                         # hit the process group that started the MUA
1029                         send($sock, '-WINCH', MSG_EOR) if $sock;
1030                 } elsif ($op eq ':bell') {
1031                         out($self, "\a");
1032                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1033                         push @$alerts, split(/(?<!\\),/, $op);
1034                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1035                         my $cmd = $1; # run an arbitrary command
1036                         require Text::ParseWords;
1037                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1038                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1039                 } else {
1040                         warn("W: unsupported --alert=$op\n"); # non-fatal
1041                 }
1042         }
1043 }
1044
1045 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1046 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1047
1048 # this also normalizes the path
1049 sub path_to_fd {
1050         my ($self, $path) = @_;
1051         $path = rel2abs($self, $path);
1052         $path =~ tr!/!/!s;
1053         $path_to_fd{$path} // (
1054                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1055                         fail($self, "cannot open $path from daemon") : -1
1056         );
1057 }
1058
1059 # caller needs to "-t $self->{1}" to check if tty
1060 sub start_pager {
1061         my ($self, $new_env) = @_;
1062         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1063         chomp(my $pager = <$fh> // '');
1064         close($fh) or warn "`git var PAGER' error: \$?=$?";
1065         return if $pager eq 'cat' || $pager eq '';
1066         $new_env //= {};
1067         $new_env->{LESS} //= 'FRX';
1068         $new_env->{LV} //= '-c';
1069         $new_env->{MORE} = $new_env->{LESS} if $^O eq 'freebsd';
1070         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1071         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1072         my $pgr = [ undef, @$rdr{1, 2} ];
1073         my $env = $self->{env};
1074         if ($self->{sock}) { # lei(1) process runs it
1075                 delete @$new_env{keys %$env}; # only set iff unset
1076                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1077         } else {
1078                 die 'BUG: start_pager w/o socket';
1079         }
1080         $self->{1} = $wpager;
1081         $self->{2} = $wpager if -t $self->{2};
1082         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1083         $self->{pgr} = $pgr;
1084 }
1085
1086 # display a message for user before spawning full-screen $VISUAL
1087 sub pgr_err {
1088         my ($self, @msg) = @_;
1089         return warn(@msg) unless $self->{sock} && -t $self->{2};
1090         start_pager($self, { LESS => 'RX' }); # no 'F' so we prompt
1091         print { $self->{2} } @msg;
1092         $self->{2}->autoflush(1);
1093         stop_pager($self);
1094         send($self->{sock}, 'wait', MSG_EOR); # wait for user to quit pager
1095 }
1096
1097 sub stop_pager {
1098         my ($self) = @_;
1099         my $pgr = delete($self->{pgr}) or return;
1100         $self->{2} = $pgr->[2];
1101         close(delete($self->{1})) if $self->{1};
1102         $self->{1} = $pgr->[1];
1103 }
1104
1105 sub accept_dispatch { # Listener {post_accept} callback
1106         my ($sock) = @_; # ignore other
1107         $sock->autoflush(1);
1108         my $self = bless { sock => $sock }, __PACKAGE__;
1109         vec(my $rvec = '', fileno($sock), 1) = 1;
1110         select($rvec, undef, undef, 60) or
1111                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1112         # (4096 * 33) >MAX_ARG_STRLEN
1113         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1114         if (!defined($fds[0])) {
1115                 warn(my $msg = "recv_cmd failed: $!");
1116                 return send($sock, $msg, MSG_EOR);
1117         } else {
1118                 my $i = 0;
1119                 for my $fd (@fds) {
1120                         open($self->{$i++}, '+<&=', $fd) and next;
1121                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1122                 }
1123                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1124         }
1125         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1126         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1127         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1128                 return send($sock, 'request command truncated', MSG_EOR);
1129         my ($argc, @argv) = split(/\0/, $buf, -1);
1130         undef $buf;
1131         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1132         $self->{env} = \%env;
1133         eval { dispatch($self, @argv) };
1134         $self->fail($@) if $@;
1135 }
1136
1137 sub dclose {
1138         my ($self) = @_;
1139         local $current_lei = $self;
1140         delete $self->{-progress};
1141         _drop_wq($self) if $self->{failed};
1142         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1143 }
1144
1145 # for long-running results
1146 sub event_step {
1147         my ($self) = @_;
1148         local %ENV = %{$self->{env}};
1149         local $current_lei = $self;
1150         eval {
1151                 my @fds = $recv_cmd->($self->{sock} // return, my $buf, 4096);
1152                 if (scalar(@fds) == 1 && !defined($fds[0])) {
1153                         return if $! == EAGAIN;
1154                         die "recvmsg: $!" if $! != ECONNRESET;
1155                         $buf = '';
1156                         @fds = (); # for open loop below:
1157                 }
1158                 for (@fds) { open my $rfh, '+<&=', $_ }
1159                 if ($buf eq '') {
1160                         _drop_wq($self); # EOF, client disconnected
1161                         dclose($self);
1162                         $buf = 'TERM';
1163                 }
1164                 if ($buf =~ /\A(?:STOP|CONT|TERM)\z/) {
1165                         my $sig = "-$buf";
1166                         for my $wq (grep(defined, @$self{@WQ_KEYS})) {
1167                                 $wq->wq_kill($sig);
1168                         }
1169                 } else {
1170                         die "unrecognized client signal: $buf";
1171                 }
1172                 my $s = $self->{-socks} // []; # lei up --all
1173                 @$s = grep { send($_, $buf, MSG_EOR) } @$s;
1174         };
1175         if (my $err = $@) {
1176                 eval { $self->fail($err) };
1177                 dclose($self);
1178         }
1179 }
1180
1181 sub event_step_init {
1182         my ($self) = @_;
1183         my $sock = $self->{sock} or return;
1184         $self->{-event_init_done} // do { # persist til $ops done
1185                 $sock->blocking(0);
1186                 $self->SUPER::new($sock, EPOLLIN);
1187                 $self->{-event_init_done} = $sock;
1188         };
1189 }
1190
1191 sub noop {}
1192
1193 sub oldset { $oldset }
1194
1195 sub dump_and_clear_log {
1196         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1197                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1198                 chomp(my @lines = <STDIN>);
1199                 truncate(STDIN, 0) or
1200                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1201                 for my $l (@lines) { syslog('warning', '%s', $l) }
1202                 closelog(); # don't share across fork
1203         }
1204 }
1205
1206 sub cfg2lei ($) {
1207         my ($cfg) = @_;
1208         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1209         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1210         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1211         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1212         open($lei->{3}, '<', '/') or die "open /: $!";
1213         my ($x, $y);
1214         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1215         $lei->{sock} = $x;
1216         require PublicInbox::LeiSelfSocket;
1217         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1218         $lei;
1219 }
1220
1221 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1222         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1223         my $fn = $ev->fullname;
1224         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1225                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1226                 $nc = '' if $ev->IN_DELETE || $ev->IN_MOVED_FROM;
1227                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1228                         my $cfg = $PATH2CFG{$f} // next;
1229                         eval {
1230                                 my $lei = cfg2lei($cfg);
1231                                 $lei->dispatch('note-event',
1232                                                 "maildir:$mdir", $nc, $bn, $fn);
1233                         };
1234                         warn "E: note-event $f: $@\n" if $@;
1235                 }
1236         }
1237         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1238                 $ev->cancel;
1239         }
1240         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1241                 delete $MDIR2CFGPATH->{$1};
1242         }
1243         if (!-e $fn) { # config file or Maildir gone
1244                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1245                         delete $cfgpaths->{$fn};
1246                 }
1247                 delete $PATH2CFG{$fn};
1248         }
1249 }
1250
1251 # lei(1) calls this when it can't connect
1252 sub lazy_start {
1253         my ($path, $errno, $narg) = @_;
1254         local ($errors_log, $listener);
1255         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1256         $errors_log = "$sock_dir/errors.log";
1257         my $addr = pack_sockaddr_un($path);
1258         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1259         umask(077) // die("umask(077): $!");
1260         $lk->lock_acquire;
1261         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1262         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1263                 return if connect($listener, $addr); # another process won
1264                 if ($errno == ECONNREFUSED && -S $path) {
1265                         unlink($path) or die "unlink($path): $!";
1266                 }
1267         } else {
1268                 $! = $errno; # allow interpolation to stringify in die
1269                 die "connect($path): $!";
1270         }
1271         bind($listener, $addr) or die "bind($path): $!";
1272         $lk->lock_release;
1273         undef $lk;
1274         my @st = stat($path) or die "stat($path): $!";
1275         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1276         local $oldset = PublicInbox::DS::block_signals();
1277         if ($narg == 5) {
1278                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1279                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1280                         require PublicInbox::CmdIPC4;
1281                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1282                         PublicInbox::CmdIPC4->can('recv_cmd4');
1283                 } // do {
1284                         $send_cmd = PublicInbox::Syscall->can('send_cmd4');
1285                         PublicInbox::Syscall->can('recv_cmd4');
1286                 };
1287         }
1288         $recv_cmd or die <<"";
1289 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1290
1291         require PublicInbox::Listener;
1292         require PublicInbox::PktOp;
1293         (-p STDOUT) or die "E: stdout must be a pipe\n";
1294         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1295         STDIN->autoflush(1);
1296         dump_and_clear_log();
1297         POSIX::setsid() > 0 or die "setsid: $!";
1298         my $pid = fork // die "fork: $!";
1299         return if $pid;
1300         $0 = "lei-daemon $path";
1301         local %PATH2CFG;
1302         local $MDIR2CFGPATH;
1303         $listener->blocking(0);
1304         my $exit_code;
1305         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1306         local $quit = do {
1307                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1308                 sub {
1309                         $exit_code //= shift;
1310                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1311                         my $lis = $pil or exit($exit_code);
1312                         # closing eof_p triggers \&noop wakeup
1313                         $listener = $eof_p = $pil = $path = undef;
1314                         $lis->close; # DS::close
1315                         PublicInbox::DS->SetLoopTimeout(1000);
1316                 };
1317         };
1318         my $sig = {
1319                 CHLD => \&PublicInbox::DS::enqueue_reap,
1320                 QUIT => $quit,
1321                 INT => $quit,
1322                 TERM => $quit,
1323                 HUP => \&noop,
1324                 USR1 => \&noop,
1325                 USR2 => \&noop,
1326         };
1327         require PublicInbox::DirIdle;
1328         local $dir_idle = PublicInbox::DirIdle->new(sub {
1329                 # just rely on wakeup to hit PostLoopCallback set below
1330                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1331         });
1332         $dir_idle->add_watches([$sock_dir]);
1333         PublicInbox::DS->SetPostLoopCallback(sub {
1334                 my ($dmap, undef) = @_;
1335                 if (@st = defined($path) ? stat($path) : ()) {
1336                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1337                                 warn "$path dev/ino changed, quitting\n";
1338                                 $path = undef;
1339                         }
1340                 } elsif (defined($path)) { # ENOENT is common
1341                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1342                         undef $path;
1343                         $quit->();
1344                 }
1345                 return 1 if defined($path);
1346                 my $n = 0;
1347                 for my $s (values %$dmap) {
1348                         $s->can('busy') or next;
1349                         if ($s->busy) {
1350                                 ++$n;
1351                         } else {
1352                                 $s->close;
1353                         }
1354                 }
1355                 $n; # true: continue, false: stop
1356         });
1357
1358         # STDIN was redirected to /dev/null above, closing STDERR and
1359         # STDOUT will cause the calling `lei' client process to finish
1360         # reading the <$daemon> pipe.
1361         local $SIG{__WARN__} = sub {
1362                 $current_lei ? err($current_lei, @_) : warn(
1363                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1364         };
1365         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1366         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1367         # $daemon pipe to `lei' closed, main loop begins:
1368         eval { PublicInbox::DS::event_loop($sig, $oldset) };
1369         warn "event loop error: $@\n" if $@;
1370         # exit() may trigger waitpid via various DESTROY, ensure interruptible
1371         PublicInbox::DS::sig_setmask($oldset);
1372         dump_and_clear_log();
1373         exit($exit_code // 0);
1374 }
1375
1376 sub busy { 1 } # prevent daemon-shutdown if client is connected
1377
1378 # ensures stdout hits the FS before sock disconnects so a client
1379 # can immediately reread it
1380 sub DESTROY {
1381         my ($self) = @_;
1382         if (my $counters = delete $self->{counters}) {
1383                 for my $k (sort keys %$counters) {
1384                         my $nr = $counters->{$k};
1385                         $self->child_error(0, "$nr $k messages");
1386                 }
1387         }
1388         $self->{1}->autoflush(1) if $self->{1};
1389         stop_pager($self);
1390         dump_and_clear_log();
1391         # preserve $? for ->fail or ->x_it code
1392 }
1393
1394 sub wq_done_wait { # dwaitpid callback
1395         my ($arg, $pid) = @_;
1396         my ($wq, $lei) = @$arg;
1397         local $current_lei = $lei;
1398         my $err_type = $lei->{-err_type};
1399         $? and $lei->child_error($?,
1400                 $err_type ? "$err_type errors during $lei->{cmd} \$?=$?" : ());
1401         $lei->dclose;
1402 }
1403
1404 sub fchdir {
1405         my ($lei) = @_;
1406         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1407         chdir($dh) || die "fchdir: $!";
1408 }
1409
1410 sub wq_eof { # EOF callback for main daemon
1411         my ($lei, $wq_fld) = @_;
1412         local $current_lei = $lei;
1413         my $wq = delete $lei->{$wq_fld // 'wq1'};
1414         $lei->sto_done_request($wq);
1415         $wq // $lei->fail; # already failed
1416 }
1417
1418 sub watch_state_ok ($) {
1419         my ($state) = $_[-1]; # $_[0] may be $self
1420         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1421 }
1422
1423 sub cancel_maildir_watch ($$) {
1424         my ($d, $cfg_f) = @_;
1425         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1426         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1427                 delete $MDIR2CFGPATH->{$d};
1428         for my $x (@{$w // []}) { $x->cancel }
1429 }
1430
1431 sub add_maildir_watch ($$) {
1432         my ($d, $cfg_f) = @_;
1433         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1434                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1435                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1436         }
1437 }
1438
1439 sub refresh_watches {
1440         my ($lei) = @_;
1441         $dir_idle or return;
1442         my $cfg = _lei_cfg($lei) or return;
1443         my $old = $cfg->{-watches};
1444         my $watches = $cfg->{-watches} //= {};
1445         my %seen;
1446         my $cfg_f = $cfg->{'-f'};
1447         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1448                 my $url = substr($w, length('watch.'), -length('.state'));
1449                 require PublicInbox::LeiWatch;
1450                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1451                 $seen{$url} = undef;
1452                 my $state = $cfg->get_1("watch.$url.state");
1453                 if (!watch_state_ok($state)) {
1454                         warn("watch.$url.state=$state not supported\n");
1455                         next;
1456                 }
1457                 if ($url =~ /\Amaildir:(.+)/i) {
1458                         my $d = canonpath_harder($1);
1459                         if ($state eq 'pause') {
1460                                 cancel_maildir_watch($d, $cfg_f);
1461                         } else {
1462                                 add_maildir_watch($d, $cfg_f);
1463                         }
1464                 } else { # TODO: imap/nntp/jmap
1465                         $lei->child_error(0, "E: watch $url not supported, yet")
1466                 }
1467         }
1468
1469         # add all known Maildir folders as implicit watches
1470         my $lms = $lei->lms;
1471         if ($lms) {
1472                 $lms->lms_write_prepare;
1473                 for my $d ($lms->folders('maildir:')) {
1474                         substr($d, 0, length('maildir:')) = '';
1475
1476                         # fixup old bugs while we're iterating:
1477                         my $cd = canonpath_harder($d);
1478                         my $f = "maildir:$cd";
1479                         $lms->rename_folder("maildir:$d", $f) if $d ne $cd;
1480                         next if $watches->{$f}; # may be set to pause
1481                         require PublicInbox::LeiWatch;
1482                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1483                         $seen{$f} = undef;
1484                         add_maildir_watch($cd, $cfg_f);
1485                 }
1486         }
1487         if ($old) { # cull old non-existent entries
1488                 for my $url (keys %$old) {
1489                         next if exists $seen{$url};
1490                         delete $old->{$url};
1491                         if ($url =~ /\Amaildir:(.+)/i) {
1492                                 my $d = canonpath_harder($1);
1493                                 cancel_maildir_watch($d, $cfg_f);
1494                         } else { # TODO: imap/nntp/jmap
1495                                 $lei->child_error(0, "E: watch $url TODO");
1496                         }
1497                 }
1498         }
1499         if (scalar keys %$watches) {
1500                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1501         } else {
1502                 delete $cfg->{-watches};
1503         }
1504 }
1505
1506 # TODO: support SHA-256
1507 sub git_oid {
1508         my $eml = $_[-1];
1509         $eml->header_set($_) for @PublicInbox::Import::UNWANTED_HEADERS;
1510         git_sha(1, $eml);
1511 }
1512
1513 sub lms {
1514         my ($lei, $creat) = @_;
1515         my $sto = $lei->{sto} // _lei_store($lei) // return;
1516         require PublicInbox::LeiMailSync;
1517         my $f = "$sto->{priv_eidx}->{topdir}/mail_sync.sqlite3";
1518         (-f $f || $creat) ? PublicInbox::LeiMailSync->new($f) : undef;
1519 }
1520
1521 sub sto_done_request {
1522         my ($lei, $wq) = @_;
1523         return unless $lei->{sto};
1524         local $current_lei = $lei;
1525         my $sock = $wq ? $wq->{lei_sock} : undef;
1526         $sock //= $lei->{sock};
1527         my @io;
1528         push(@io, $sock) if $sock; # async wait iff possible
1529         eval { $lei->{sto}->wq_io_do('done', \@io) };
1530         warn($@) if $@;
1531 }
1532
1533 sub cfg_dump ($$) {
1534         my ($lei, $f) = @_;
1535         my $ret = eval { PublicInbox::Config->git_config_dump($f, $lei->{2}) };
1536         return $ret if !$@;
1537         warn($@);
1538         undef;
1539 }
1540
1541 sub request_umask {
1542         my ($lei) = @_;
1543         my $s = $lei->{sock} // return;
1544         send($s, 'umask', MSG_EOR) // die "send: $!";
1545         vec(my $rvec = '', fileno($s), 1) = 1;
1546         select($rvec, undef, undef, 2) or die 'timeout waiting for umask';
1547         recv($s, my $v, 5, 0) // die "recv: $!";
1548         (my $u, $lei->{client_umask}) = unpack('AV', $v);
1549         $u eq 'u' or warn "E: recv $v has no umask";
1550 }
1551
1552 1;