lib/PublicInbox/LeiMailSync.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for maintaining synchronization between lei/store <=> Maildir|MH|IMAP|JMAP
   5 package PublicInbox::LeiMailSync;
   6 use strict;
   7 use v5.10.1;
   8 use parent qw(PublicInbox::Lock);
   9 use DBI qw(:sql_types); # SQL_BLOB
  10 use PublicInbox::ContentHash qw(git_sha);
  11 use Carp ();
  12
  13 sub dbh_new {
  14         my ($self) = @_;
  15         my $f = $self->{filename};
  16         my $creat = !-s $f;
  17         if ($creat) {
  18                 require PublicInbox::Syscall;
  19                 open my $fh, '+>>', $f or Carp::croak "open($f): $!";
  20                 PublicInbox::Syscall::nodatacow_fh($fh);
  21         }
  22         my $dbh = DBI->connect("dbi:SQLite:dbname=$f",'','', {
  23                 AutoCommit => 1,
  24                 RaiseError => 1,
  25                 PrintError => 0,
  26                 sqlite_use_immediate_transaction => 1,
  27         });
  28         # no sqlite_unicode, here, all strings are binary
  29         create_tables($self, $dbh);
  30         $dbh->do('PRAGMA journal_mode = WAL') if $creat;
  31         $dbh->do('PRAGMA case_sensitive_like = ON');
  32         $dbh;
  33 }
  34
  35 sub new {
  36         my ($cls, $f) = @_;
  37         bless {
  38                 filename => $f,
  39                 fmap => {},
  40                 lock_path => "$f.flock",
  41         }, $cls;
  42 }
  43
  44 sub lms_write_prepare { ($_[0]->{dbh} //= dbh_new($_[0])); $_[0] }
  45
  46 sub lms_pause {
  47         my ($self) = @_;
  48         $self->{fmap} = {};
  49         my $dbh = delete $self->{dbh};
  50         eval { $dbh->do('PRAGMA optimize') } if $dbh;
  51 }
  52
  53 sub create_tables {
  54         my ($self, $dbh) = @_;
  55         my $lk = $self->lock_for_scope;
  56
  57         $dbh->do(<<'');
  58 CREATE TABLE IF NOT EXISTS folders (
  59         fid INTEGER PRIMARY KEY,
  60         loc VARBINARY NOT NULL, /* URL;UIDVALIDITY=$N or $TYPE:/pathname */
  61         UNIQUE (loc)
  62 )
  63
  64         $dbh->do(<<'');
  65 CREATE TABLE IF NOT EXISTS blob2num (
  66         oidbin VARBINARY NOT NULL,
  67         fid INTEGER NOT NULL, /* folder ID */
  68         uid INTEGER NOT NULL, /* NNTP article number, IMAP UID, MH number */
  69         /* not UNIQUE(fid, uid), since we may have broken servers */
  70         UNIQUE (oidbin, fid, uid)
  71 )
  72
  73         # speeds up LeiImport->ck_update_kw (for "lei import") by 5-6x:
  74         $dbh->do(<<'');
  75 CREATE INDEX IF NOT EXISTS idx_fid_uid ON blob2num(fid,uid)
  76
  77         $dbh->do(<<'');
  78 CREATE TABLE IF NOT EXISTS blob2name (
  79         oidbin VARBINARY NOT NULL,
  80         fid INTEGER NOT NULL, /* folder ID */
  81         name VARBINARY NOT NULL, /* Maildir basename, JMAP blobId */
  82         /* not UNIQUE(fid, name), since we may have broken software */
  83         UNIQUE (oidbin, fid, name)
  84 )
  85
  86         # speeds up LeiImport->pmdir_cb (for "lei import") by ~6x:
  87         $dbh->do(<<'');
  88 CREATE INDEX IF NOT EXISTS idx_fid_name ON blob2name(fid,name)
  89
  90 }
  91
  92 # used to fixup pre-1.7.0 folders
  93 sub update_fid ($$$) {
  94         my ($dbh, $fid, $loc) = @_;
  95         my $sth = $dbh->prepare(<<'');
  96 UPDATE folders SET loc = ? WHERE fid = ?
  97
  98         $sth->bind_param(1, $loc, SQL_BLOB);
  99         $sth->bind_param(2, $fid);
 100         $sth->execute;
 101 }
 102
 103 sub get_fid ($$$) {
 104         my ($sth, $folder, $dbh) = @_;
 105         $sth->bind_param(1, $folder, SQL_BLOB);
 106         $sth->execute;
 107         my ($fid) = $sth->fetchrow_array;
 108         if (defined $fid) { # for downgrade+upgrade (1.8 -> 1.7 -> 1.8)
 109                 $dbh->do('DELETE FROM folders WHERE loc = ? AND fid != ?',
 110                         undef, $folder, $fid) if defined($dbh);
 111         } else {
 112                 $sth->execute($folder); # fixup old stuff
 113                 ($fid) = $sth->fetchrow_array;
 114                 update_fid($dbh, $fid, $folder) if defined($fid) && $dbh;
 115         }
 116         $fid;
 117 }
 118
 119 sub fid_for {
 120         my ($self, $folder, $creat) = @_;
 121         my $dbh = $self->{dbh} //= dbh_new($self);
 122         my $sth = $dbh->prepare_cached(<<'', undef, 1);
 123 SELECT fid FROM folders WHERE loc = ? LIMIT 1
 124
 125         my $fid = get_fid($sth, $folder, $dbh);
 126         return $fid if defined($fid);
 127
 128         # caller had trailing slash (LeiToMail)
 129         if ($folder =~ s!\A((?:maildir|mh):.*?)/+\z!$1!i) {
 130                 $fid = get_fid($sth, $folder, $dbh);
 131                 if (defined $fid) {
 132                         update_fid($dbh, $fid, $folder);
 133                         return $fid;
 134                 }
 135         # sometimes we stored trailing slash..
 136         } elsif ($folder =~ m!\A(?:maildir|mh):!i) {
 137                 $fid = get_fid($sth, $folder, $dbh);
 138                 if (defined $fid) {
 139                         update_fid($dbh, $fid, $folder);
 140                         return $fid;
 141                 }
 142         } elsif ($creat && $folder =~ m!\Aimaps?://!i) {
 143                 require PublicInbox::URIimap;
 144                 my $uri = PublicInbox::URIimap->new($folder);
 145                 $uri->uidvalidity //
 146                         Carp::croak("BUG: $folder has no UIDVALIDITY");
 147                 defined($uri->uid) and Carp::confess("BUG: $folder has UID");
 148         }
 149
 150         return unless $creat;
 151         ($fid) = $dbh->selectrow_array('SELECT MAX(fid) FROM folders');
 152
 153         $fid += 1;
 154         # in case we're reusing, clobber existing stale refs:
 155         $dbh->do('DELETE FROM blob2name WHERE fid = ?', undef, $fid);
 156         $dbh->do('DELETE FROM blob2num WHERE fid = ?', undef, $fid);
 157
 158         $sth = $dbh->prepare('INSERT INTO folders (fid, loc) VALUES (?, ?)');
 159         $sth->bind_param(1, $fid);
 160         $sth->bind_param(2, $folder, SQL_BLOB);
 161         $sth->execute;
 162
 163         $fid;
 164 }
 165
 166 sub add_folders {
 167         my ($self, @folders) = @_;
 168         my $lk = $self->lock_for_scope;
 169         for my $f (@folders) { $self->{fmap}->{$f} //= fid_for($self, $f, 1) }
 170 }
 171
 172 sub set_src {
 173         my ($self, $oidbin, $folder, $id) = @_;
 174         my $lk = $self->lock_for_scope;
 175         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 176         my $dbh = $self->{dbh};
 177         my ($sth, @param3, $del_old);
 178         if (ref($id)) { # scalar name
 179                 @param3 = ($$id, SQL_BLOB);
 180                 $sth = $dbh->prepare_cached(<<'');
 181 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 182
 183                 $del_old = $dbh->prepare_cached(<<'');
 184 DELETE FROM blob2name WHERE oidbin = ? AND fid = ? AND name = ?
 185
 186         } else { # numeric ID (IMAP UID, MH number)
 187                 @param3 = ($id);
 188                 $sth = $dbh->prepare_cached(<<'');
 189 INSERT OR IGNORE INTO blob2num (oidbin, fid, uid) VALUES (?, ?, ?)
 190
 191                 $del_old = $dbh->prepare_cached(<<'');
 192 DELETE FROM blob2num WHERE oidbin = ? AND fid = ? AND uid = ?
 193
 194         }
 195         $sth->bind_param(1, $oidbin, SQL_BLOB);
 196         $sth->bind_param(2, $fid);
 197         $sth->bind_param(3, @param3);
 198         my $ret = $sth->execute;
 199         $del_old->execute($oidbin, $fid, $param3[0]);
 200         $ret;
 201 }
 202
 203 sub clear_src {
 204         my ($self, $folder, $id) = @_;
 205         my $lk = $self->lock_for_scope;
 206         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 207         my ($sth, @param3);
 208         if (ref($id)) { # scalar name
 209                 @param3 = ($$id, SQL_BLOB);
 210                 $sth = $self->{dbh}->prepare_cached(<<'');
 211 DELETE FROM blob2name WHERE fid = ? AND name = ?
 212
 213         } else {
 214                 @param3 = ($id);
 215                 $sth = $self->{dbh}->prepare_cached(<<'');
 216 DELETE FROM blob2num WHERE fid = ? AND uid = ?
 217
 218         }
 219         $sth->bind_param(1, $fid);
 220         $sth->bind_param(2, @param3);
 221         my $ret = $sth->execute;
 222
 223         # older versions may not have used SQL_BLOB:
 224         if (defined($ret) && $ret == 0 && scalar(@param3) == 2) {
 225                 $sth->bind_param(1, $fid);
 226                 $sth->bind_param(2, $param3[0]);
 227                 $ret = $sth->execute;
 228         }
 229         $ret;
 230 }
 231
 232 # Maildir-only
 233 sub mv_src {
 234         my ($self, $folder, $oidbin, $id, $newbn) = @_;
 235         my $lk = $self->lock_for_scope;
 236         my $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder, 1);
 237         $self->{dbh}->begin_work;
 238         my $sth = $self->{dbh}->prepare_cached(<<'');
 239 UPDATE blob2name SET name = ? WHERE fid = ? AND oidbin = ? AND name = ?
 240
 241         # eval since unique constraint may fail due to race
 242         $sth->bind_param(1, $newbn, SQL_BLOB);
 243         $sth->bind_param(2, $fid);
 244         $sth->bind_param(3, $oidbin, SQL_BLOB);
 245         $sth->bind_param(4, $$id, SQL_BLOB);
 246         my $nr = eval { $sth->execute };
 247         if (!defined($nr) || $nr == 0) { # $nr may be `0E0'
 248                 # delete from old, pre-SQL_BLOB rows:
 249                 my $del_old = $self->{dbh}->prepare_cached(<<'');
 250 DELETE FROM blob2name WHERE fid = ? AND oidbin = ? AND name = ?
 251
 252                 $del_old->execute($fid, $oidbin, $$id); # missing-OK
 253                 $del_old->execute($fid, $oidbin, $newbn); # ditto
 254
 255                 # may race with a clear_src, ensure new value exists
 256                 $sth = $self->{dbh}->prepare_cached(<<'');
 257 INSERT OR IGNORE INTO blob2name (oidbin, fid, name) VALUES (?, ?, ?)
 258
 259                 $sth->bind_param(1, $oidbin, SQL_BLOB);
 260                 $sth->bind_param(2, $fid);
 261                 $sth->bind_param(3, $newbn, SQL_BLOB);
 262                 $sth->execute;
 263         }
 264         $self->{dbh}->commit;
 265 }
 266
 267 # read-only, iterates every oidbin + UID or name for a given folder
 268 sub each_src {
 269         my ($self, $folder, $cb, @args) = @_;
 270         my $dbh = $self->{dbh} //= dbh_new($self);
 271         my ($fid, @rng);
 272         my $and_ge_le = '';
 273         if (ref($folder) eq 'HASH') {
 274                 $fid = $folder->{fid} // die "BUG: no `fid'";
 275                 @rng = grep(defined, @$folder{qw(min max)});
 276                 $and_ge_le = 'AND uid >= ? AND uid <= ?' if @rng;
 277         } else {
 278                 $fid = $self->{fmap}->{$folder} //=
 279                         fid_for($self, $folder) // return;
 280         }
 281
 282         # minimize implicit txn time to avoid blocking writers by
 283         # batching SELECTs.  This looks wonky but is necessary since
 284         # $cb-> may access the DB on its own.
 285         my $ary = $dbh->selectall_arrayref(<<"", undef, $fid, @rng);
 286 SELECT _rowid_,oidbin,uid FROM blob2num WHERE fid = ? $and_ge_le
 287 ORDER BY _rowid_ ASC LIMIT 1000
 288
 289         my $min = @$ary ? $ary->[-1]->[0] : undef;
 290         while (defined $min) {
 291                 for my $row (@$ary) { $cb->($row->[1], $row->[2], @args) }
 292
 293                 $ary = $dbh->selectall_arrayref(<<"", undef, $fid, @rng, $min);
 294 SELECT _rowid_,oidbin,uid FROM blob2num
 295 WHERE fid = ? $and_ge_le AND _rowid_ > ?
 296 ORDER BY _rowid_ ASC LIMIT 1000
 297
 298                 $min = @$ary ? $ary->[-1]->[0] : undef;
 299         }
 300
 301         $ary = $dbh->selectall_arrayref(<<'', undef, $fid);
 302 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ?
 303 ORDER BY _rowid_ ASC LIMIT 1000
 304
 305         $min = @$ary ? $ary->[-1]->[0] : undef;
 306         while (defined $min) {
 307                 for my $row (@$ary) { $cb->($row->[1], \($row->[2]), @args) }
 308
 309                 $ary = $dbh->selectall_arrayref(<<'', undef, $fid, $min);
 310 SELECT _rowid_,oidbin,name FROM blob2name WHERE fid = ? AND _rowid_ > ?
 311 ORDER BY _rowid_ ASC LIMIT 1000
 312
 313                 $min = @$ary ? $ary->[-1]->[0] : undef;
 314         }
 315 }
 316
 317 sub location_stats {
 318         my ($self, $folder) = @_;
 319         my $dbh = $self->{dbh} //= dbh_new($self);
 320         my $fid;
 321         my $ret = {};
 322         $fid = $self->{fmap}->{$folder} //= fid_for($self, $folder) // return;
 323         my ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 324 SELECT COUNT(name) FROM blob2name WHERE fid = ?
 325
 326         $ret->{'name.count'} = $row if $row;
 327         my $ntype = ($folder =~ m!\A(?:nntps?|s?news)://!i) ? 'article' :
 328                 (($folder =~ m!\Aimaps?://!i) ? 'uid' : "TODO<$folder>");
 329         for my $op (qw(count min max)) {
 330                 ($row) = $dbh->selectrow_array(<<"", undef, $fid);
 331 SELECT $op(uid) FROM blob2num WHERE fid = ?
 332
 333                 $row or last;
 334                 $ret->{"$ntype.$op"} = $row;
 335         }
 336         $ret;
 337 }
 338
 339 # returns a { location => [ list-of-ids-or-names ] } mapping
 340 sub locations_for {
 341         my ($self, $oidbin) = @_;
 342         my ($fid, $sth, $id, %fid2id, %seen);
 343         my $dbh = $self->{dbh} //= dbh_new($self);
 344         $sth = $dbh->prepare('SELECT fid,uid FROM blob2num WHERE oidbin = ?');
 345         $sth->bind_param(1, $oidbin, SQL_BLOB);
 346         $sth->execute;
 347         while (my ($fid, $uid) = $sth->fetchrow_array) {
 348                 push @{$fid2id{$fid}}, $uid;
 349                 $seen{"$uid.$fid"} = 1;
 350         }
 351
 352         # deal with 1.7.0 DBs :<
 353         $sth->execute($oidbin);
 354         while (my ($fid, $uid) = $sth->fetchrow_array) {
 355                 next if $seen{"$uid.$fid"};
 356                 push @{$fid2id{$fid}}, $uid;
 357         }
 358
 359         %seen = ();
 360         $sth = $dbh->prepare('SELECT fid,name FROM blob2name WHERE oidbin = ?');
 361         $sth->bind_param(1, $oidbin, SQL_BLOB);
 362         $sth->execute;
 363         while (my ($fid, $name) = $sth->fetchrow_array) {
 364                 push @{$fid2id{$fid}}, $name;
 365                 $seen{"$fid.$name"} = 1;
 366         }
 367
 368         # deal with 1.7.0 DBs :<
 369         $sth->execute($oidbin);
 370         while (my ($fid, $name) = $sth->fetchrow_array) {
 371                 next if $seen{"$fid.$name"};
 372                 push @{$fid2id{$fid}}, $name;
 373         }
 374
 375         $sth = $dbh->prepare('SELECT loc FROM folders WHERE fid = ? LIMIT 1');
 376         my $ret = {};
 377         while (my ($fid, $ids) = each %fid2id) {
 378                 $sth->execute($fid);
 379                 my ($loc) = $sth->fetchrow_array;
 380                 unless (defined $loc) {
 381                         my $oidhex = unpack('H*', $oidbin);
 382                         warn "E: fid=$fid for $oidhex unknown:\n", map {
 383                                         'E: '.(ref() ? $$_ : "#$_")."\n";
 384                                 } @$ids;
 385                         next;
 386                 }
 387                 $ret->{$loc} = $ids;
 388         }
 389         scalar(keys %$ret) ? $ret : undef;
 390 }
 391
 392 # returns a list of folders used for completion
 393 sub folders {
 394         my ($self, @pfx) = @_;
 395         my $sql = 'SELECT loc FROM folders';
 396         my $re;
 397         if (defined($pfx[0])) {
 398                 $sql .= ' WHERE loc REGEXP ?'; # DBD::SQLite uses perlre
 399                 $re = !!$pfx[1] ? '.*' : '';
 400                 $re .= quotemeta($pfx[0]);
 401                 $re .= '.*';
 402         }
 403         my $sth = ($self->{dbh} //= dbh_new($self))->prepare($sql);
 404         $sth->bind_param(1, $re) if defined($re);
 405         $sth->execute;
 406         map { $_->[0] } @{$sth->fetchall_arrayref};
 407 }
 408
 409 sub local_blob {
 410         my ($self, $oidhex, $vrfy) = @_;
 411         my $dbh = $self->{dbh} //= dbh_new($self);
 412         my $b2n = $dbh->prepare(<<'');
 413 SELECT f.loc,b.name FROM blob2name b
 414 LEFT JOIN folders f ON b.fid = f.fid
 415 WHERE b.oidbin = ?
 416
 417         $b2n->bind_param(1, pack('H*', $oidhex), SQL_BLOB);
 418         $b2n->execute;
 419         while (my ($d, $n) = $b2n->fetchrow_array) {
 420                 substr($d, 0, length('maildir:')) = '';
 421                 # n.b. both mbsync and offlineimap use ":2," as a suffix
 422                 # in "new/", despite (from what I understand of reading
 423                 # <https://cr.yp.to/proto/maildir.html>), the ":2," only
 424                 # applies to files in "cur/".
 425                 my @try = $n =~ /:2,[a-zA-Z]+\z/ ? qw(cur new) : qw(new cur);
 426                 for my $x (@try) {
 427                         my $f = "$d/$x/$n";
 428                         open my $fh, '<', $f or next;
 429                         # some (buggy) Maildir writers are non-atomic:
 430                         next unless -s $fh;
 431                         local $/;
 432                         my $raw = <$fh>;
 433                         if ($vrfy) {
 434                                 my $got = git_sha(1, \$raw)->hexdigest;
 435                                 if ($got ne $oidhex) {
 436                                         warn "$f changed $oidhex => $got\n";
 437                                         next;
 438                                 }
 439                         }
 440                         return \$raw;
 441                 }
 442         }
 443         undef;
 444 }
 445
 446 sub match_imap_url {
 447         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 448         $all //= [ $self->folders ];
 449         require PublicInbox::URIimap;
 450         my $want = PublicInbox::URIimap->new($url)->canonical;
 451         my ($s, $h, $mb) = ($want->scheme, $want->host, $want->mailbox);
 452         my @uri = map { PublicInbox::URIimap->new($_)->canonical }
 453                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$mb\E\b!, @$all);
 454         my @match;
 455         for my $x (@uri) {
 456                 next if $x->mailbox ne $want->mailbox;
 457                 next if $x->host ne $want->host;
 458                 next if $x->port != $want->port;
 459                 my $x_uidval = $x->uidvalidity;
 460                 next if ($want->uidvalidity // $x_uidval) != $x_uidval;
 461
 462                 # allow nothing in want to possibly match ";AUTH=ANONYMOUS"
 463                 if (defined($x->auth) && !defined($want->auth) &&
 464                                 !defined($want->user)) {
 465                         push @match, $x;
 466                 # or maybe user was forgotten on CLI:
 467                 } elsif (defined($x->user) && !defined($want->user)) {
 468                         push @match, $x;
 469                 } elsif (($x->user//"\0") eq ($want->user//"\0")) {
 470                         push @match, $x;
 471                 }
 472         }
 473         return @match if wantarray;
 474         scalar(@match) <= 1 ? $match[0] :
 475                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 476 }
 477
 478 sub match_nntp_url ($$$) {
 479         my ($self, $url, $all) = @_; # $all = [ $lms->folders ];
 480         $all //= [ $self->folders ];
 481         require PublicInbox::URInntps;
 482         my $want = PublicInbox::URInntps->new($url)->canonical;
 483         my ($s, $h, $p) = ($want->scheme, $want->host, $want->port);
 484         my $ng = $want->group; # force scalar (no article ranges)
 485         my @uri = map { PublicInbox::URInntps->new($_)->canonical }
 486                 grep(m!\A\Q$s\E://.*?\Q$h\E\b.*?/\Q$ng\E\b!, @$all);
 487         my @match;
 488         for my $x (@uri) {
 489                 next if $x->group ne $ng || $x->host ne $h || $x->port != $p;
 490                 # maybe user was forgotten on CLI:
 491                 if (defined($x->userinfo) && !defined($want->userinfo)) {
 492                         push @match, $x;
 493                 } elsif (($x->userinfo//"\0") eq ($want->userinfo//"\0")) {
 494                         push @match, $x;
 495                 }
 496         }
 497         return @match if wantarray;
 498         scalar(@match) <= 1 ? $match[0] :
 499                         "E: `$url' is ambiguous:\n\t".join("\n\t", @match)."\n";
 500 }
 501
 502 # returns undef on failure, number on success
 503 sub group2folders {
 504         my ($self, $lei, $all, $folders) = @_;
 505         return $lei->fail(<<EOM) if @$folders;
 506 --all= not compatible with @$folders on command-line
 507 EOM
 508         my %x = map { $_ => $_ } split(/,/, $all);
 509         my @ok = grep(defined, delete(@x{qw(local remote), ''}));
 510         push(@ok, '') if $all eq '';
 511         my @no = keys %x;
 512         if (@no) {
 513                 @no = (join(',', @no));
 514                 return $lei->fail(<<EOM);
 515 --all=@no not accepted (must be `local' and/or `remote')
 516 EOM
 517         }
 518         my (%seen, @inc);
 519         my @all = $self->folders;
 520         for my $ok (@ok) {
 521                 if ($ok eq 'local') {
 522                         @inc = grep(!m!\A[a-z0-9\+]+://!i, @all);
 523                 } elsif ($ok eq 'remote') {
 524                         @inc = grep(m!\A[a-z0-9\+]+://!i, @all);
 525                 } elsif ($ok ne '') {
 526                         return $lei->fail("--all=$all not understood");
 527                 } else {
 528                         @inc = @all;
 529                 }
 530                 push(@$folders, (grep { !$seen{$_}++ } @inc));
 531         }
 532         scalar(@$folders) || $lei->fail(<<EOM);
 533 no --mail-sync folders known to lei
 534 EOM
 535 }
 536
 537 # map CLI args to folder table entries, returns undef on failure
 538 sub arg2folder {
 539         my ($self, $lei, $folders) = @_;
 540         my @all = $self->folders;
 541         my %all = map { $_ => 1 } @all;
 542         my @no;
 543         for (@$folders) {
 544                 next if $all{$_}; # ok
 545                 if (m!\A(maildir|mh):(.+)!i) {
 546                         my $type = lc $1;
 547                         my $d = "$type:".$lei->abs_path($2);
 548                         push(@no, $_) unless $all{$d};
 549                         $_ = $d;
 550                 } elsif (-d "$_/new" && -d "$_/cur") {
 551                         my $d = 'maildir:'.$lei->abs_path($_);
 552                         push(@no, $_) unless $all{$d};
 553                         $_ = $d;
 554                 } elsif (m!\Aimaps?://!i) {
 555                         my $orig = $_;
 556                         my $res = match_imap_url($self, $orig, \@all);
 557                         if (ref $res) {
 558                                 $_ = $$res;
 559                                 $lei->qerr(<<EOM);
 560 # using `$res' instead of `$orig'
 561 EOM
 562                         } else {
 563                                 warn($res, "\n") if defined $res;
 564                                 push @no, $orig;
 565                         }
 566                 } elsif (m!\A(?:nntps?|s?news)://!i) {
 567                         my $orig = $_;
 568                         my $res = match_nntp_url($self, $orig, \@all);
 569                         if (ref $res) {
 570                                 $_ = $$res;
 571                                 $lei->qerr(<<EOM);
 572 # using `$res' instead of `$orig'
 573 EOM
 574                         } else {
 575                                 warn($res, "\n") if defined $res;
 576                                 push @no, $orig;
 577                         }
 578                 } else {
 579                         push @no, $_;
 580                 }
 581         }
 582         if (@no) {
 583                 my $no = join("\n\t", @no);
 584                 die <<EOF;
 585 No sync information for: $no
 586 Run `lei ls-mail-sync' to display valid choices
 587 EOF
 588         }
 589 }
 590
 591 sub forget_folders {
 592         my ($self, @folders) = @_;
 593         my $lk = $self->lock_for_scope;
 594         for my $folder (@folders) {
 595                 my $fid = delete($self->{fmap}->{$folder}) //
 596                         fid_for($self, $folder) // next;
 597                 for my $t (qw(blob2name blob2num folders)) {
 598                         $self->{dbh}->do("DELETE FROM $t WHERE fid = ?",
 599                                         undef, $fid);
 600                 }
 601         }
 602 }
 603
 604 # only used for changing canonicalization errors
 605 sub rename_folder {
 606         my ($self, $old, $new) = @_;
 607         my $lk = $self->lock_for_scope;
 608         my $ofid = delete($self->{fmap}->{$old}) //
 609                 fid_for($self, $old) // return;
 610         eval {
 611                 $self->{dbh}->do(<<EOM, undef, $new, $ofid);
 612 UPDATE folders SET loc = ? WHERE fid = ?
 613 EOM
 614         };
 615         if ($@ =~ /\bunique\b/i) {
 616                 my $nfid = $self->{fmap}->{$new} // fid_for($self, $new);
 617                 for my $t (qw(blob2name blob2num)) {
 618                         $self->{dbh}->do(<<EOM, undef, $nfid, $ofid);
 619 UPDATE OR REPLACE $t SET fid = ? WHERE fid = ?
 620 EOM
 621                 }
 622                 $self->{dbh}->do(<<EOM, undef, $ofid);
 623 DELETE FROM folders WHERE fid = ?
 624 EOM
 625         }
 626 }
 627
 628 sub num_oidbin ($$$) {
 629         my ($self, $url, $uid) = @_; # $url MUST have UIDVALIDITY if IMAP
 630         my $fid = $self->{fmap}->{$url} //= fid_for($self, $url) // return ();
 631         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 632 SELECT oidbin FROM blob2num WHERE fid = ? AND uid = ? ORDER BY _rowid_
 633 EOM
 634         $sth->execute($fid, $uid);
 635         my %uniq; # for public-inbox <= 1.7.0
 636         grep { !$uniq{$_}++ } map { $_->[0] } @{$sth->fetchall_arrayref};
 637 }
 638
 639 sub name_oidbin ($$$) {
 640         my ($self, $mdir, $nm) = @_;
 641         my $fid = $self->{fmap}->{$mdir} //= fid_for($self, $mdir) // return;
 642         my $sth = $self->{dbh}->prepare_cached(<<EOM, undef, 1);
 643 SELECT oidbin FROM blob2name WHERE fid = ? AND name = ?
 644 EOM
 645         $sth->bind_param(1, $fid);
 646         $sth->bind_param(2, $nm, SQL_BLOB);
 647         $sth->execute;
 648         my @bin = map { $_->[0] } @{$sth->fetchall_arrayref};
 649         $sth->execute($fid, $nm);
 650         my @old = map { $_->[0] } @{$sth->fetchall_arrayref};
 651         my %uniq; # for public-inbox <= 1.7.0
 652         grep { !$uniq{$_}++ } (@bin, @old);
 653 }
 654
 655 sub imap_oidhex {
 656         my ($self, $lei, $uid_uri) = @_;
 657         my $mailbox_uri = $uid_uri->clone;
 658         $mailbox_uri->uid(undef);
 659         my $folders = [ $$mailbox_uri ];
 660         eval { $self->arg2folder($lei, $folders) };
 661         $lei->qerr("# no sync information for $mailbox_uri") if $@;
 662         map { unpack('H*',$_) } num_oidbin($self, $folders->[0], $uid_uri->uid)
 663 }
 664
 665 1;