lib/PublicInbox/MIME.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # The license for this file differs from the rest of public-inbox.
   5 #
   6 # We no longer load this in any of our code outside of maintainer
   7 # tests for compatibility.
   8 #
   9 # It monkey patches the "parts_multipart" subroutine with patches
  10 # from Matthew Horsfall <wolfsage@gmail.com> at:
  11 #
  12 # git clone --mirror https://github.com/rjbs/Email-MIME.git refs/pull/28/head
  13 #
  14 # commit fe0eb870ab732507aa39a1070a2fd9435c7e4877
  15 # ("Make sure we don't modify the body of a message when injecting a header.")
  16 # commit 981d8201a7239b02114489529fd366c4c576a146
  17 # ("GH #14 - Handle CRLF emails properly.")
  18 # commit 2338d93598b5e8432df24bda8dfdc231bdeb666e
  19 # ("GH #14 - Support multipart messages without content-type in subparts.")
  20 #
  21 # For Email::MIME >= 1.923 && < 1.935,
  22 # commit dcef9be66c49ae89c7a5027a789bbbac544499ce
  23 # ("removing all trailing newlines was too much")
  24 # is also included
  25 package PublicInbox::MIME;
  26 use strict;
  27 use warnings;
  28 use base qw(Email::MIME);
  29 use Email::MIME::ContentType;
  30 use PublicInbox::MsgIter ();
  31 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  32
  33 if ($Email::MIME::VERSION <= 1.937) {
  34 sub parts_multipart {
  35   my $self     = shift;
  36   my $boundary = $self->{ct}->{attributes}->{boundary};
  37
  38   # Take a message, join all its lines together.  Now try to Email::MIME->new
  39   # it with 1.861 or earlier.  Death!  It tries to recurse endlessly on the
  40   # body, because every time it splits on boundary it gets itself. Obviously
  41   # that means it's a bogus message, but a mangled result (or exception) is
  42   # better than endless recursion. -- rjbs, 2008-01-07
  43   return $self->parts_single_part
  44     unless $boundary and $self->body_raw =~ /^--\Q$boundary\E\s*$/sm;
  45
  46   $self->{body_raw} = Email::Simple::body($self);
  47
  48   # rfc1521 7.2.1
  49   my ($body, $epilogue) = split /^--\Q$boundary\E--\s*$/sm, $self->body_raw, 2;
  50
  51   # Split on boundaries, but keep blank lines after them intact
  52   my @bits = split /^--\Q$boundary\E\s*?(?=$self->{mycrlf})/m, ($body || '');
  53
  54   Email::Simple::body_set($self, undef);
  55
  56   # If there are no headers in the potential MIME part, it's just part of the
  57   # body.  This is a horrible hack, although it's debatable whether it was
  58   # better or worse when it was $self->{body} = shift @bits ... -- rjbs,
  59   # 2006-11-27
  60   Email::Simple::body_set($self, shift @bits) if ($bits[0] || '') !~ /.*:.*/;
  61
  62   my $bits = @bits;
  63
  64   my @parts;
  65   for my $bit (@bits) {
  66     # Parts don't need headers. If they don't have them, they look like this:
  67     #
  68     #   --90e6ba6e8d06f1723604fc1b809a
  69     #
  70     #   Part 2
  71     #
  72     #   Part 2a
  73     #
  74     # $bit will contain two new lines before Part 2.
  75     #
  76     # Anything with headers will only have one new line.
  77     #
  78     # RFC 1341 Section 7.2 says parts without headers are to be considered
  79     # plain US-ASCII text. -- alh
  80     # 2016-08-01
  81     my $added_header;
  82
  83     if ($bit =~ /^(?:$self->{mycrlf}){2}/) {
  84       $bit = "Content-type: text/plain; charset=us-ascii" . $bit;
  85
  86       $added_header = 1;
  87     }
  88
  89     $bit =~ s/\A[\n\r]+//smg;
  90     $bit =~ s/(?<!\x0d)$self->{mycrlf}\Z//sm;
  91
  92     my $email = (ref $self)->new($bit);
  93
  94     if ($added_header) {
  95       # Remove our changes so we don't change the raw email content
  96       $email->header_str_set('Content-Type');
  97     }
  98
  99     push @parts, $email;
 100   }
 101
 102   $self->{parts} = \@parts;
 103
 104   return @{ $self->{parts} };
 105 }
 106 }
 107
 108 no warnings 'once';
 109 *each_part = \&PublicInbox::MsgIter::em_each_part;
 110 1;