lib/PublicInbox/Qspawn.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Like most Perl modules in public-inbox, this is internal and
   5 # NOT subject to any stability guarantees!  It is only documented
   6 # for other hackers.
   7 #
   8 # This is used to limit the number of processes spawned by the
   9 # PSGI server, so it acts like a semaphore and queues up extra
  10 # commands to be run if currently at the limit.  Multiple "limiters"
  11 # may be configured which give inboxes different channels to
  12 # operate in.  This can be useful to ensure smaller inboxes can
  13 # be cloned while cloning of large inboxes is maxed out.
  14 #
  15 # This does not depend on PublicInbox::DS or any other external
  16 # scheduling mechanism, you just need to call start() and finish()
  17 # appropriately. However, public-inbox-httpd (which uses PublicInbox::DS)
  18 # will be able to schedule this based on readability of stdout from
  19 # the spawned process.  See GitHTTPBackend.pm and SolverGit.pm for
  20 # usage examples.  It does not depend on any form of threading.
  21 #
  22 # This is useful for scheduling CGI execution of both long-lived
  23 # git-http-backend(1) process (for "git clone") as well as short-lived
  24 # processes such as git-apply(1).
  25
  26 package PublicInbox::Qspawn;
  27 use strict;
  28 use warnings;
  29 use PublicInbox::Spawn qw(popen_rd);
  30 require Plack::Util;
  31
  32 # n.b.: we get EAGAIN with public-inbox-httpd, and EINTR on other PSGI servers
  33 use Errno qw(EAGAIN EINTR);
  34
  35 my $def_limiter;
  36
  37 # declares a command to spawn (but does not spawn it).
  38 # $cmd is the command to spawn
  39 # $env is the environ for the child process
  40 # $opt can include redirects and perhaps other process spawning options
  41 sub new ($$$;) {
  42         my ($class, $cmd, $env, $opt) = @_;
  43         bless { args => [ $cmd, $env, $opt ] }, $class;
  44 }
  45
  46 sub _do_spawn {
  47         my ($self, $cb) = @_;
  48         my $err;
  49         my ($cmd, $env, $opts) = @{$self->{args}};
  50         my %opts = %{$opts || {}};
  51         my $limiter = $self->{limiter};
  52         foreach my $k (PublicInbox::Spawn::RLIMITS()) {
  53                 if (defined(my $rlimit = $limiter->{$k})) {
  54                         $opts{$k} = $rlimit;
  55                 }
  56         }
  57
  58         ($self->{rpipe}, $self->{pid}) = popen_rd($cmd, $env, \%opts);
  59
  60         # drop any IO handles opt was holding open via $opt->{hold}
  61         # No need to hold onto the descriptor once the child process has it.
  62         $self->{args} = $cmd; # keep this around for logging
  63
  64         if (defined $self->{pid}) {
  65                 $limiter->{running}++;
  66         } else {
  67                 $self->{err} = $!;
  68         }
  69         $cb->($self->{rpipe});
  70 }
  71
  72 sub child_err ($) {
  73         my ($child_error) = @_; # typically $?
  74         my $exitstatus = ($child_error >> 8) or return;
  75         my $sig = $child_error & 127;
  76         my $msg = "exit status=$exitstatus";
  77         $msg .= " signal=$sig" if $sig;
  78         $msg;
  79 }
  80
  81 sub log_err ($$) {
  82         my ($env, $msg) = @_;
  83         $env->{'psgi.errors'}->print($msg, "\n");
  84 }
  85
  86 # callback for dwaitpid
  87 sub waitpid_err ($$) {
  88         my ($self, $pid) = @_;
  89         my $xpid = delete $self->{pid};
  90         my $err;
  91         if ($pid > 0) { # success!
  92                 $err = child_err($?);
  93         } elsif ($pid < 0) { # ??? does this happen in our case?
  94                 $err = "W: waitpid($xpid, 0) => $pid: $!";
  95         } # else should not be called with pid == 0
  96
  97         # done, spawn whatever's in the queue
  98         my $limiter = $self->{limiter};
  99         my $running = --$limiter->{running};
 100
 101         # limiter->{max} may change dynamically
 102         if (($running || $limiter->{running}) < $limiter->{max}) {
 103                 if (my $next = shift @{$limiter->{run_queue}}) {
 104                         _do_spawn(@$next);
 105                 }
 106         }
 107
 108         return unless $err;
 109         $self->{err} = $err;
 110         my $env = $self->{env} or return;
 111         if (!$env->{'qspawn.quiet'}) {
 112                 log_err($env, join(' ', @{$self->{args}}) . ": $err");
 113         }
 114 }
 115
 116 sub do_waitpid ($;$) {
 117         my ($self, $env) = @_;
 118         my $pid = $self->{pid};
 119         eval { # PublicInbox::DS may not be loaded
 120                 PublicInbox::DS::dwaitpid($pid, \&waitpid_err, $self);
 121                 $self->{env} = $env;
 122         };
 123         # done if we're running in PublicInbox::DS::EventLoop
 124         if ($@) {
 125                 # non public-inbox-{httpd,nntpd} callers may block:
 126                 my $ret = waitpid($pid, 0);
 127                 waitpid_err($self, $ret);
 128         }
 129 }
 130
 131 sub finish ($;$) {
 132         my ($self, $env) = @_;
 133         if (delete $self->{rpipe}) {
 134                 do_waitpid($self, $env);
 135         }
 136
 137         # limiter->{max} may change dynamically
 138         my $limiter = $self->{limiter};
 139         if ($limiter->{running} < $limiter->{max}) {
 140                 if (my $next = shift @{$limiter->{run_queue}}) {
 141                         _do_spawn(@$next);
 142                 }
 143         }
 144         $self->{err}; # may be meaningless if non-blocking
 145 }
 146
 147 sub start {
 148         my ($self, $limiter, $cb) = @_;
 149         $self->{limiter} = $limiter;
 150
 151         if ($limiter->{running} < $limiter->{max}) {
 152                 _do_spawn($self, $cb);
 153         } else {
 154                 push @{$limiter->{run_queue}}, [ $self, $cb ];
 155         }
 156 }
 157
 158 # Similar to `backtick` or "qx" ("perldoc -f qx"), it calls $qx_cb with
 159 # the stdout of the given command when done; but respects the given limiter
 160 # $env is the PSGI env.  As with ``/qx; only use this when output is small
 161 # and safe to slurp.
 162 sub psgi_qx {
 163         my ($self, $env, $limiter, $qx_cb) = @_;
 164         my $scalar = '';
 165         open(my $qx, '+>', \$scalar) or die; # PerlIO::scalar
 166         my $end = sub {
 167                 my $err = $_[0]; # $!
 168                 log_err($env, "psgi_qx: $err") if defined($err);
 169                 finish($self, $env);
 170                 eval { $qx_cb->(\$scalar) };
 171                 $qx = $scalar = undef;
 172         };
 173         my $rpipe; # comes from popen_rd
 174         my $async = $env->{'pi-httpd.async'};
 175         my $cb = sub {
 176                 my ($r, $buf);
 177 reread:
 178                 $r = sysread($rpipe, $buf, 65536);
 179                 if ($async) {
 180                         $async->async_pass($env->{'psgix.io'}, $qx, \$buf);
 181                 } elsif (defined $r) {
 182                         $r ? $qx->write($buf) : $end->();
 183                 } else {
 184                         return if $! == EAGAIN; # try again when notified
 185                         goto reread if $! == EINTR;
 186                         $end->($!);
 187                 }
 188         };
 189         $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
 190         $self->start($limiter, sub { # may run later, much later...
 191                 ($rpipe) = @_; # popen_rd result
 192                 if ($async) {
 193                 # PublicInbox::HTTPD::Async->new($rpipe, $cb, $end)
 194                         $async = $async->($rpipe, $cb, $end);
 195                 } else { # generic PSGI
 196                         $cb->() while $qx;
 197                 }
 198         });
 199 }
 200
 201 # create a filter for "push"-based streaming PSGI writes used by HTTPD::Async
 202 sub filter_fh ($$) {
 203         my ($fh, $filter) = @_;
 204         Plack::Util::inline_object(
 205                 close => sub {
 206                         $fh->write($filter->(undef));
 207                         $fh->close;
 208                 },
 209                 write => sub {
 210                         $fh->write($filter->($_[0]));
 211                 });
 212 }
 213
 214 # Used for streaming the stdout of one process as a PSGI response.
 215 #
 216 # $env is the PSGI env.
 217 # optional keys in $env:
 218 #   $env->{'qspawn.wcb'} - the write callback from the PSGI server
 219 #                          optional, use this if you've already
 220 #                          captured it elsewhere.  If not given,
 221 #                          psgi_return will return an anonymous
 222 #                          sub for the PSGI server to call
 223 #
 224 #   $env->{'qspawn.filter'} - filter callback, receives a string as input,
 225 #                             undef on EOF
 226 #
 227 # $limiter - the Limiter object to use (uses the def_limiter if not given)
 228 #
 229 # $parse_hdr - Initial read function; often for parsing CGI header output.
 230 #              It will be given the return value of sysread from the pipe
 231 #              and a string ref of the current buffer.  Returns an arrayref
 232 #              for PSGI responses.  2-element arrays in PSGI mean the
 233 #              body will be streamed, later, via writes (push-based) to
 234 #              psgix.io.  3-element arrays means the body is available
 235 #              immediately (or streamed via ->getline (pull-based)).
 236 sub psgi_return {
 237         my ($self, $env, $limiter, $parse_hdr) = @_;
 238         my ($fh, $rpipe);
 239         my $end = sub {
 240                 my $err = $_[0]; # $!
 241                 log_err($env, "psgi_return: $err") if defined($err);
 242                 finish($self, $env);
 243                 $fh->close if $fh; # async-only
 244         };
 245
 246         my $buf = '';
 247         my $rd_hdr = sub {
 248                 # typically used for reading CGI headers
 249                 # we must loop until EAGAIN for EPOLLET in HTTPD/Async.pm
 250                 # We also need to check EINTR for generic PSGI servers.
 251                 my $ret;
 252                 my $total_rd = 0;
 253                 do {
 254                         my $r = sysread($rpipe, $buf, 4096, length($buf));
 255                         if (defined($r)) {
 256                                 $total_rd += $r;
 257                                 $ret = $parse_hdr->($r ? $total_rd : 0, \$buf);
 258                         } else {
 259                                 # caller should notify us when it's ready:
 260                                 return if $! == EAGAIN;
 261                                 next if $! == EINTR; # immediate retry
 262                                 log_err($env, "error reading header: $!");
 263                                 $ret = [ 500, [], [ "Internal error\n" ] ];
 264                         }
 265                 } until (defined $ret);
 266                 $ret;
 267         };
 268
 269         my $wcb = delete $env->{'qspawn.wcb'};
 270         my $async = $env->{'pi-httpd.async'};
 271
 272         my $cb = sub {
 273                 my $r = $rd_hdr->() or return;
 274                 $rd_hdr = undef; # done reading headers
 275                 my $filter = delete $env->{'qspawn.filter'};
 276                 if (scalar(@$r) == 3) { # error
 277                         if ($async) {
 278                                 $async->close; # calls rpipe->close and $end
 279                         } else {
 280                                 $rpipe->close;
 281                                 $end->();
 282                         }
 283                         $wcb->($r);
 284                 } elsif ($async) {
 285                         # done reading headers, handoff to read body
 286                         $fh = $wcb->($r); # scalar @$r == 2
 287                         $fh = filter_fh($fh, $filter) if $filter;
 288                         $async->async_pass($env->{'psgix.io'}, $fh, \$buf);
 289                 } else { # for synchronous PSGI servers
 290                         require PublicInbox::GetlineBody;
 291                         $r->[2] = PublicInbox::GetlineBody->new($rpipe, $end,
 292                                                                 $buf, $filter);
 293                         $wcb->($r);
 294                 }
 295         };
 296         $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
 297         my $start_cb = sub { # may run later, much later...
 298                 ($rpipe) = @_;
 299                 if ($async) {
 300                         # PublicInbox::HTTPD::Async->new($rpipe, $cb, $end)
 301                         $async = $async->($rpipe, $cb, $end);
 302                 } else { # generic PSGI
 303                         $cb->() while $rd_hdr;
 304                 }
 305         };
 306
 307         # the caller already captured the PSGI write callback from
 308         # the PSGI server, so we can call ->start, here:
 309         return $self->start($limiter, $start_cb) if $wcb;
 310
 311         # the caller will return this sub to the PSGI server, so
 312         # it can set the response callback (that is, for PublicInbox::HTTP,
 313         # the chunked_wcb or identity_wcb callback), but other HTTP servers
 314         # are supported:
 315         sub {
 316                 ($wcb) = @_;
 317                 $self->start($limiter, $start_cb);
 318         };
 319 }
 320
 321 package PublicInbox::Qspawn::Limiter;
 322 use strict;
 323 use warnings;
 324
 325 sub new {
 326         my ($class, $max) = @_;
 327         bless {
 328                 # 32 is same as the git-daemon connection limit
 329                 max => $max || 32,
 330                 running => 0,
 331                 run_queue => [],
 332                 # RLIMIT_CPU => undef,
 333                 # RLIMIT_DATA => undef,
 334                 # RLIMIT_CORE => undef,
 335         }, $class;
 336 }
 337
 338 sub setup_rlimit {
 339         my ($self, $name, $config) = @_;
 340         foreach my $rlim (PublicInbox::Spawn::RLIMITS()) {
 341                 my $k = lc($rlim);
 342                 $k =~ tr/_//d;
 343                 $k = "publicinboxlimiter.$name.$k";
 344                 defined(my $v = $config->{$k}) or next;
 345                 my @rlimit = split(/\s*,\s*/, $v);
 346                 if (scalar(@rlimit) == 1) {
 347                         push @rlimit, $rlimit[0];
 348                 } elsif (scalar(@rlimit) != 2) {
 349                         warn "could not parse $k: $v\n";
 350                 }
 351                 eval { require BSD::Resource };
 352                 if ($@) {
 353                         warn "BSD::Resource missing for $rlim";
 354                         next;
 355                 }
 356                 foreach my $i (0..$#rlimit) {
 357                         next if $rlimit[$i] ne 'INFINITY';
 358                         $rlimit[$i] = BSD::Resource::RLIM_INFINITY();
 359                 }
 360                 $self->{$rlim} = \@rlimit;
 361         }
 362 }
 363
 364 1;