lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search);
  13 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  14 require PublicInbox::Git;
  15 *xpfx = *PublicInbox::Search::xpfx;
  16
  17 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  18 use constant {
  19         PERM_UMASK => 0,
  20         OLD_PERM_GROUP => 1,
  21         OLD_PERM_EVERYBODY => 2,
  22         PERM_GROUP => 0660,
  23         PERM_EVERYBODY => 0664,
  24 };
  25
  26 sub new {
  27         my ($class, $git_dir, $writable) = @_;
  28         my $dir = $class->xdir($git_dir);
  29         require Search::Xapian::WritableDatabase;
  30         my $flag = Search::Xapian::DB_OPEN;
  31         my $self = bless { git_dir => $git_dir }, $class;
  32         my $perm = $self->_git_config_perm;
  33         my $umask = _umask_for($perm);
  34         $self->{umask} = $umask;
  35         $self->{xdb} = $self->with_umask(sub {
  36                 if ($writable == 1) {
  37                         require File::Path;
  38                         File::Path::mkpath($dir);
  39                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  40                 }
  41                 Search::Xapian::WritableDatabase->new($dir, $flag);
  42         });
  43         $self;
  44 }
  45
  46 sub add_val {
  47         my ($doc, $col, $num) = @_;
  48         $num = Search::Xapian::sortable_serialise($num);
  49         $doc->add_value($col, $num);
  50 }
  51
  52 sub add_message {
  53         my ($self, $mime, $bytes, $num) = @_; # mime = Email::MIME object
  54         my $db = $self->{xdb};
  55
  56         my $doc_id;
  57         my $mid = mid_clean(mid_mime($mime));
  58         my $was_ghost = 0;
  59         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  60
  61         eval {
  62                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
  63                 my $smsg = $self->lookup_message($mid);
  64                 my $doc;
  65
  66                 if ($smsg) {
  67                         $smsg->ensure_metadata;
  68                         # convert a ghost to a regular message
  69                         # it will also clobber any existing regular message
  70                         $smsg->mime($mime);
  71                         $doc = $smsg->{doc};
  72
  73                         my $type = xpfx('type');
  74                         eval {
  75                                 $doc->remove_term($type . 'ghost');
  76                                 $was_ghost = 1;
  77                         };
  78
  79                         # probably does not exist:
  80                         eval { $doc->remove_term($type . 'mail') };
  81                         $doc->add_term($type . 'mail');
  82                 }  else {
  83                         $smsg = PublicInbox::SearchMsg->new($mime);
  84                         $doc = $smsg->{doc};
  85                         $doc->add_term(xpfx('mid') . $mid);
  86                 }
  87
  88                 my $subj = $smsg->subject;
  89
  90                 if ($subj ne '') {
  91                         my $path = $self->subject_path($subj);
  92                         $doc->add_term(xpfx('path') . id_compress($path));
  93                 }
  94
  95                 add_val($doc, &PublicInbox::Search::TS, $smsg->ts);
  96
  97                 defined($num) and
  98                         add_val($doc, &PublicInbox::Search::NUM, $num);
  99
 100                 defined($bytes) and
 101                         add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 102
 103                 add_val($doc, &PublicInbox::Search::LINES,
 104                                 $mime->body_raw =~ tr!\n!\n!);
 105
 106                 my $tg = $self->term_generator;
 107
 108                 $tg->set_document($doc);
 109                 $tg->index_text($subj, 1, 'S') if $subj;
 110                 $tg->increase_termpos;
 111                 $tg->index_text($subj) if $subj;
 112                 $tg->increase_termpos;
 113
 114                 $tg->index_text($smsg->from);
 115                 $tg->increase_termpos;
 116
 117                 $mime->walk_parts(sub {
 118                         my ($part) = @_;
 119                         return if $part->subparts; # walk_parts already recurses
 120                         my $ct = $part->content_type || $ct_msg;
 121
 122                         # account for filter bugs...
 123                         $ct =~ m!\btext/plain\b!i or return;
 124
 125                         my (@orig, @quot);
 126                         my $body = $part->body;
 127                         $part->body_set('');
 128                         my @lines = split(/\n/, $body);
 129                         while (defined(my $l = shift @lines)) {
 130                                 if ($l =~ /^\s*>/) {
 131                                         push @quot, $l;
 132                                 } else {
 133                                         push @orig, $l;
 134                                 }
 135                         }
 136                         if (@quot) {
 137                                 $tg->index_text(join("\n", @quot), 0);
 138                                 @quot = ();
 139                                 $tg->increase_termpos;
 140                         }
 141                         if (@orig) {
 142                                 $tg->index_text(join("\n", @orig));
 143                                 @orig = ();
 144                                 $tg->increase_termpos;
 145                         }
 146                 });
 147
 148                 if ($was_ghost) {
 149                         $doc_id = $smsg->doc_id;
 150                         $self->link_message($smsg, 0);
 151                         $doc->set_data($smsg->to_doc_data);
 152                         $db->replace_document($doc_id, $doc);
 153                 } else {
 154                         $self->link_message($smsg, 0);
 155                         $doc->set_data($smsg->to_doc_data);
 156                         $doc_id = $db->add_document($doc);
 157                 }
 158         };
 159
 160         if ($@) {
 161                 warn "failed to index message <$mid>: $@\n";
 162                 return undef;
 163         }
 164         $doc_id;
 165 }
 166
 167 # returns deleted doc_id on success, undef on missing
 168 sub remove_message {
 169         my ($self, $mid) = @_;
 170         my $db = $self->{xdb};
 171         my $doc_id;
 172         $mid = mid_clean($mid);
 173
 174         eval {
 175                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 176                 $db->delete_document($doc_id) if defined $doc_id;
 177         };
 178
 179         if ($@) {
 180                 warn "failed to remove message <$mid>: $@\n";
 181                 return undef;
 182         }
 183         $doc_id;
 184 }
 185
 186 sub term_generator { # write-only
 187         my ($self) = @_;
 188
 189         my $tg = $self->{term_generator};
 190         return $tg if $tg;
 191
 192         $tg = Search::Xapian::TermGenerator->new;
 193         $tg->set_stemmer($self->stemmer);
 194
 195         $self->{term_generator} = $tg;
 196 }
 197
 198 # increments last_thread_id counter
 199 # returns a 64-bit integer represented as a hex string
 200 sub next_thread_id {
 201         my ($self) = @_;
 202         my $db = $self->{xdb};
 203         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 204
 205         $db->set_metadata('last_thread_id', ++$last_thread_id);
 206
 207         $last_thread_id;
 208 }
 209
 210 sub link_message {
 211         my ($self, $smsg, $is_ghost) = @_;
 212
 213         if ($is_ghost) {
 214                 $smsg->ensure_metadata;
 215         } else {
 216                 $self->link_message_to_parents($smsg);
 217         }
 218 }
 219
 220 sub link_message_to_parents {
 221         my ($self, $smsg) = @_;
 222         my $doc = $smsg->{doc};
 223         my $mid = $smsg->mid;
 224         my $mime = $smsg->mime;
 225         my $hdr = $mime->header_obj;
 226         my $refs = $hdr->header_raw('References');
 227         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 228         if (my $irt = $hdr->header_raw('In-Reply-To')) {
 229                 # last References should be $irt
 230                 # we will de-dupe later
 231                 push @refs, mid_clean($irt);
 232         }
 233
 234         my $tid;
 235         if (@refs) {
 236                 my %uniq = ($mid => 1);
 237                 my @orig_refs = @refs;
 238                 @refs = ();
 239
 240                 # prevent circular references via References: here:
 241                 foreach my $ref (@orig_refs) {
 242                         if (length($ref) > MAX_MID_SIZE) {
 243                                 warn "References: <$ref> too long, ignoring\n";
 244                         }
 245                         next if $uniq{$ref};
 246                         $uniq{$ref} = 1;
 247                         push @refs, $ref;
 248                 }
 249         }
 250         if (@refs) {
 251                 $smsg->{references} = '<'.join('> <', @refs).'>';
 252
 253                 # first ref *should* be the thread root,
 254                 # but we can never trust clients to do the right thing
 255                 my $ref = shift @refs;
 256                 $tid = $self->_resolve_mid_to_tid($ref);
 257
 258                 # the rest of the refs should point to this tid:
 259                 foreach $ref (@refs) {
 260                         my $ptid = $self->_resolve_mid_to_tid($ref);
 261                         if ($tid ne $ptid) {
 262                                 $self->merge_threads($tid, $ptid);
 263                         }
 264                 }
 265         } else {
 266                 $tid = $self->next_thread_id;
 267         }
 268         $doc->add_term(xpfx('thread') . $tid);
 269 }
 270
 271 sub index_blob {
 272         my ($self, $git, $mime, $bytes, $num) = @_;
 273         $self->add_message($mime, $bytes, $num);
 274 }
 275
 276 sub unindex_blob {
 277         my ($self, $git, $mime) = @_;
 278         my $mid = eval { mid_clean(mid_mime($mime)) };
 279         $self->remove_message($mid) if defined $mid;
 280 }
 281
 282 sub index_mm {
 283         my ($self, $git, $mime) = @_;
 284         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 285 }
 286
 287 sub unindex_mm {
 288         my ($self, $git, $mime) = @_;
 289         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 290 }
 291
 292 sub index_mm2 {
 293         my ($self, $git, $mime, $bytes) = @_;
 294         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 295         index_blob($self, $git, $mime, $bytes, $num);
 296 }
 297
 298 sub unindex_mm2 {
 299         my ($self, $git, $mime) = @_;
 300         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 301         unindex_blob($self, $git, $mime);
 302 }
 303
 304 sub index_both {
 305         my ($self, $git, $mime, $bytes) = @_;
 306         my $num = index_mm($self, $git, $mime);
 307         index_blob($self, $git, $mime, $bytes, $num);
 308 }
 309
 310 sub unindex_both {
 311         my ($self, $git, $mime) = @_;
 312         unindex_blob($self, $git, $mime);
 313         unindex_mm($self, $git, $mime);
 314 }
 315
 316 sub do_cat_mail {
 317         my ($git, $blob, $sizeref) = @_;
 318         my $mime = eval {
 319                 my $str = $git->cat_file($blob, $sizeref);
 320                 Email::MIME->new($str);
 321         };
 322         $@ ? undef : $mime;
 323 }
 324
 325 sub index_sync {
 326         my ($self, $head) = @_;
 327         $self->with_umask(sub { $self->_index_sync($head) });
 328 }
 329
 330 sub rlog {
 331         my ($self, $range, $add_cb, $del_cb) = @_;
 332         my $hex = '[a-f0-9]';
 333         my $h40 = $hex .'{40}';
 334         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 335         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 336         my $git = PublicInbox::Git->new($self->{git_dir});
 337         my $log = $git->popen(qw/log --reverse --no-notes --no-color
 338                                 --raw -r --no-abbrev/, $range);
 339         my $latest;
 340         my $bytes;
 341         while (defined(my $line = <$log>)) {
 342                 if ($line =~ /$addmsg/o) {
 343                         my $mime = do_cat_mail($git, $1, \$bytes) or next;
 344                         $add_cb->($self, $git, $mime, $bytes);
 345                 } elsif ($line =~ /$delmsg/o) {
 346                         my $mime = do_cat_mail($git, $1) or next;
 347                         $del_cb->($self, $git, $mime);
 348                 } elsif ($line =~ /^commit ($h40)/o) {
 349                         $latest = $1;
 350                 }
 351         }
 352         $latest;
 353 }
 354
 355 # indexes all unindexed messages
 356 sub _index_sync {
 357         my ($self, $head) = @_;
 358         my $db = $self->{xdb};
 359         $head ||= 'HEAD';
 360         my $mm = $self->{mm} = eval {
 361                 require PublicInbox::Msgmap;
 362                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 363         };
 364
 365         $db->begin_transaction;
 366         my $lx = $db->get_metadata('last_commit');
 367         my $range = $lx eq '' ? $head : "$lx..$head";
 368         if ($mm) {
 369                 $mm->{dbh}->begin_work;
 370                 my $lm = $mm->last_commit || '';
 371                 if ($lm eq $lx) {
 372                         # Common case is the indexes are synced,
 373                         # we only need to run git-log once:
 374                         $lx = $self->rlog($range, *index_both, *unindex_both);
 375                         $mm->{dbh}->commit;
 376                         if (defined $lx) {
 377                                 $db->set_metadata('last_commit', $lx);
 378                                 $mm->last_commit($lx);
 379                         }
 380                 } else {
 381                         # dumb case, msgmap and xapian are out-of-sync
 382                         # do not care for performance:
 383                         my $r = $lm eq '' ? $head : "$lm..$head";
 384                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 385                         $mm->{dbh}->commit;
 386                         $mm->last_commit($lm) if defined $lm;
 387
 388                         $lx = $self->rlog($range, *index_mm2, *unindex_mm2);
 389                         $db->set_metadata('last_commit', $lx) if defined $lx;
 390                 }
 391         } else {
 392                 # user didn't install DBD::SQLite and DBI
 393                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 394                 $db->set_metadata('last_commit', $lx) if defined $lx;
 395         }
 396         if ($@) {
 397                 $db->cancel_transaction;
 398                 $mm->{dbh}->rollback if $mm;
 399         } else {
 400                 $db->commit_transaction;
 401         }
 402 }
 403
 404 # this will create a ghost as necessary
 405 sub _resolve_mid_to_tid {
 406         my ($self, $mid) = @_;
 407
 408         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 409         $smsg->thread_id;
 410 }
 411
 412 sub create_ghost {
 413         my ($self, $mid, $tid) = @_;
 414
 415         $tid = $self->next_thread_id unless defined $tid;
 416
 417         my $doc = Search::Xapian::Document->new;
 418         $doc->add_term(xpfx('mid') . $mid);
 419         $doc->add_term(xpfx('thread') . $tid);
 420         $doc->add_term(xpfx('type') . 'ghost');
 421
 422         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 423         $self->link_message($smsg, 1);
 424         $self->{xdb}->add_document($doc);
 425
 426         $smsg;
 427 }
 428
 429 sub merge_threads {
 430         my ($self, $winner_tid, $loser_tid) = @_;
 431         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 432         my $thread_pfx = xpfx('thread');
 433         my $db = $self->{xdb};
 434
 435         for (; $head != $tail; $head->inc) {
 436                 my $docid = $head->get_docid;
 437                 my $doc = $db->get_document($docid);
 438                 $doc->remove_term($thread_pfx . $loser_tid);
 439                 $doc->add_term($thread_pfx . $winner_tid);
 440                 $db->replace_document($docid, $doc);
 441         }
 442 }
 443
 444 sub _read_git_config_perm {
 445         my ($self) = @_;
 446         my @cmd = qw(config core.sharedRepository);
 447         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 448         my $perm = <$fh>;
 449         chomp $perm if defined $perm;
 450         $perm;
 451 }
 452
 453 sub _git_config_perm {
 454         my $self = shift;
 455         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 456         return PERM_GROUP if (!defined($perm) || $perm eq '');
 457         return PERM_UMASK if ($perm eq 'umask');
 458         return PERM_GROUP if ($perm eq 'group');
 459         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 460                 return PERM_EVERYBODY;
 461         }
 462         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 463         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 464
 465         my $i = oct($perm);
 466         return PERM_UMASK if ($i == PERM_UMASK);
 467         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 468         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 469
 470         if (($i & 0600) != 0600) {
 471                 die "core.sharedRepository mode invalid: ".
 472                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 473         }
 474         ($i & 0666);
 475 }
 476
 477 sub _umask_for {
 478         my ($perm) = @_; # _git_config_perm return value
 479         my $rv = $perm;
 480         return umask if $rv == 0;
 481
 482         # set +x bit if +r or +w were set
 483         $rv |= 0100 if ($rv & 0600);
 484         $rv |= 0010 if ($rv & 0060);
 485         $rv |= 0001 if ($rv & 0006);
 486         (~$rv & 0777);
 487 }
 488
 489 sub with_umask {
 490         my ($self, $cb) = @_;
 491         my $old = umask $self->{umask};
 492         my $rv = eval { $cb->() };
 493         my $err = $@;
 494         umask $old;
 495         die $err if $@;
 496         $rv;
 497 }
 498
 499 1;