lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use Email::Address qw//;
  11 use POSIX qw//;
  12 use Date::Parse qw/str2time/;
  13 use PublicInbox::MID qw/mid_clean/;
  14 use Encode qw/find_encoding/;
  15 my $enc_utf8 = find_encoding('UTF-8');
  16 our $PFX2TERM_RE = undef;
  17 use constant EPOCH_822 => 'Thu, 01 Jan 1970 00:00:00 +0000';
  18 use POSIX qw(strftime);
  19
  20 sub new {
  21         my ($class, $mime) = @_;
  22         my $doc = Search::Xapian::Document->new;
  23         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  24
  25         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  26 }
  27
  28 sub wrap {
  29         my ($class, $doc, $mid) = @_;
  30         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  31 }
  32
  33 sub get_val ($$) {
  34         my ($doc, $col) = @_;
  35         Search::Xapian::sortable_unserialise($doc->get_value($col));
  36 }
  37
  38 sub load_doc {
  39         my ($class, $doc) = @_;
  40         my $data = $doc->get_data;
  41         my $ts = get_val($doc, &PublicInbox::Search::TS);
  42         $data = $enc_utf8->decode($data);
  43         my ($subj, $from, $refs, $to, $cc) = split(/\n/, $data);
  44         bless {
  45                 doc => $doc,
  46                 subject => $subj,
  47                 ts => $ts,
  48                 from => $from,
  49                 references => $refs,
  50                 to => $to,
  51                 cc => $cc,
  52         }, $class;
  53 }
  54
  55 # :bytes and :lines metadata in RFC 3977
  56 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  57 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  58 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  59
  60 sub __hdr ($$) {
  61         my ($self, $field) = @_;
  62         my $val = $self->{$field};
  63         return $val if defined $val;
  64
  65         my $mime = $self->{mime} or return;
  66         $val = $mime->header($field);
  67         $val = '' unless defined $val;
  68         $val =~ tr/\t\r\n/ /;
  69         $self->{$field} = $val;
  70 }
  71
  72 sub subject ($) { __hdr($_[0], 'subject') }
  73 sub to ($) { __hdr($_[0], 'to') }
  74 sub cc ($) { __hdr($_[0], 'cc') }
  75
  76 sub date ($) {
  77         my ($self) = @_;
  78         my $date = __hdr($self, 'date');
  79         return $date if defined $date;
  80         my $ts = $self->{ts};
  81         return unless defined $ts;
  82         $self->{date} = strftime('%a, %d %b %Y %T %z', gmtime($ts));
  83 }
  84
  85 sub from ($) {
  86         my ($self) = @_;
  87         my $from = __hdr($self, 'from');
  88         if (defined $from && !defined $self->{from_name}) {
  89                 $from =~ tr/\t\r\n/ /;
  90                 my @from = Email::Address->parse($from);
  91                 $self->{from_name} = $from[0]->name;
  92         }
  93         $from;
  94 }
  95
  96 sub from_name {
  97         my ($self) = @_;
  98         my $from_name = $self->{from_name};
  99         return $from_name if defined $from_name;
 100         $self->from;
 101         $self->{from_name};
 102 }
 103
 104 sub ts {
 105         my ($self) = @_;
 106         $self->{ts} ||= eval { str2time($self->mime->header('Date')) } || 0;
 107 }
 108
 109 sub to_doc_data {
 110         my ($self) = @_;
 111         join("\n", $self->subject, $self->from, $self->references,
 112                 $self->to, $self->cc);
 113 }
 114
 115 sub references {
 116         my ($self) = @_;
 117         my $x = $self->{references};
 118         defined $x ? $x : '';
 119 }
 120
 121 sub ensure_metadata {
 122         my ($self) = @_;
 123         my $doc = $self->{doc};
 124         my $end = $doc->termlist_end;
 125
 126         unless (defined $PFX2TERM_RE) {
 127                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 128                 $PFX2TERM_RE = qr/\A($or)/;
 129         }
 130
 131         while (my ($pfx, $field) = each %PublicInbox::Search::PFX2TERM_RMAP) {
 132                 # ideally we'd move this out of the loop:
 133                 my $i = $doc->termlist_begin;
 134
 135                 $i->skip_to($pfx);
 136                 if ($i != $end) {
 137                         my $val = $i->get_termname;
 138
 139                         if ($val =~ s/$PFX2TERM_RE//o) {
 140                                 $self->{$field} = $val;
 141                         }
 142                 }
 143         }
 144 }
 145
 146 # for threading only
 147 sub mini_mime {
 148         my ($self) = @_;
 149         $self->ensure_metadata;
 150         my @hs = (
 151                 'Subject' => $self->subject,
 152                 'X-PI-From' => $self->from_name,
 153         );
 154
 155         my @h = (
 156                 # prevent Email::Simple::Creator from running,
 157                 # this header is useless for threading as we use X-PI-TS
 158                 # for sorting and display:
 159                 'Date' => EPOCH_822,
 160                 'Message-ID' => "<$self->{mid}>",
 161                 'X-PI-TS' => $self->ts,
 162         );
 163         if (my $refs = $self->{references}) {
 164                 push @h, References => $refs;
 165         }
 166         my $mime = Email::MIME->create(header_str => \@hs, header => \@h);
 167         my $h = $mime->header_obj;
 168
 169         # set these headers manually since Encode::encode('MIME-Q', ...)
 170         # will add spaces to long values when using header_str above.
 171
 172         # drop useless headers Email::MIME set for us
 173         $h->header_set('Date');
 174         $h->header_set('MIME-Version');
 175         $mime;
 176 }
 177
 178 sub mid ($;$) {
 179         my ($self, $mid) = @_;
 180
 181         if (defined $mid) {
 182                 $self->{mid} = $mid;
 183         } elsif (my $rv = $self->{mid}) {
 184                 $rv;
 185         } else {
 186                 $self->ensure_metadata; # needed for ghosts
 187                 $self->{mid} ||= $self->_extract_mid;
 188         }
 189 }
 190
 191 sub _extract_mid { mid_clean(mid_mime($_[0]->mime)) }
 192
 193 sub mime {
 194         my ($self, $mime) = @_;
 195         if (defined $mime) {
 196                 $self->{mime} = $mime;
 197         } else {
 198                 # TODO load from git
 199                 $self->{mime};
 200         }
 201 }
 202
 203 sub doc_id {
 204         my ($self, $doc_id) = @_;
 205         if (defined $doc_id) {
 206                 $self->{doc_id} = $doc_id;
 207         } else {
 208                 # TODO load from xapian
 209                 $self->{doc_id};
 210         }
 211 }
 212
 213 sub thread_id {
 214         my ($self) = @_;
 215         my $tid = $self->{thread};
 216         return $tid if defined $tid;
 217         $self->ensure_metadata;
 218         $self->{thread};
 219 }
 220
 221 sub path {
 222         my ($self) = @_;
 223         my $path = $self->{path};
 224         return $path if defined $path;
 225         $self->ensure_metadata;
 226         $self->{path};
 227 }
 228
 229 1;