lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use URI::Escape qw(uri_unescape uri_escape);
   9 use PublicInbox::SearchMsg;
  10 use PublicInbox::Hval qw/ascii_html/;
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::MID qw(mid2path mid_mime mid_clean mid_escape MID_ESC);
  14 use PublicInbox::MIME;
  15 require PublicInbox::Git;
  16 require PublicInbox::SearchThread;
  17 our $LIM = 200;
  18
  19 sub noop {}
  20
  21 sub sres_top_html {
  22         my ($ctx) = @_;
  23         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  24         my $code = 200;
  25
  26         # double the limit for expanded views:
  27         my $opts = {
  28                 limit => $LIM,
  29                 offset => $q->{o},
  30                 mset => 1,
  31                 relevance => $q->{r},
  32         };
  33         my ($mset, $total, $err, $cb);
  34 retry:
  35         eval {
  36                 $mset = $ctx->{srch}->query($q->{'q'}, $opts);
  37                 $total = $mset->get_matches_estimated;
  38         };
  39         $err = $@;
  40         ctx_prepare($q, $ctx);
  41         if ($err) {
  42                 $code = 400;
  43                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  44                 $cb = *noop;
  45         } elsif ($total == 0) {
  46                 if (defined($ctx->{-uxs_retried})) {
  47                         # undo retry damage:
  48                         $q->{'q'} = $ctx->{-uxs_retried};
  49                 } elsif (index($q->{'q'}, '%') >= 0) {
  50                         $ctx->{-uxs_retried} = $q->{'q'};
  51                         $q->{'q'} = uri_unescape($q->{'q'});
  52                         goto retry;
  53                 }
  54                 $code = 404;
  55                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  56                 $cb = *noop;
  57         } else {
  58                 my $x = $q->{x};
  59                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  60
  61                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx) . "\n\n";
  62                 if ($x eq 't') {
  63                         $cb = mset_thread($ctx, $mset, $q);
  64                 } else {
  65                         $cb = mset_summary($ctx, $mset, $q);
  66                 }
  67         }
  68         PublicInbox::WwwStream->response($ctx, $code, $cb);
  69 }
  70
  71 # allow undef for individual doc loads...
  72 sub load_doc_retry {
  73         my ($srch, $mitem) = @_;
  74
  75         eval {
  76                 $srch->retry_reopen(sub {
  77                         PublicInbox::SearchMsg->load_doc($mitem->get_document)
  78                 });
  79         }
  80 }
  81
  82 # display non-threaded search results similar to what users expect from
  83 # regular WWW search engines:
  84 sub mset_summary {
  85         my ($ctx, $mset, $q) = @_;
  86
  87         my $total = $mset->get_matches_estimated;
  88         my $pad = length("$total");
  89         my $pfx = ' ' x $pad;
  90         my $res = \($ctx->{-html_tip});
  91         my $srch = $ctx->{srch};
  92         foreach my $m ($mset->items) {
  93                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  94                 my $pct = $m->get_percent;
  95                 my $smsg = load_doc_retry($srch, $m);
  96                 unless ($smsg) {
  97                         eval {
  98                                 $m = "$m ".$m->get_docid . " expired\n";
  99                                 $ctx->{env}->{'psgi.errors'}->print($m);
 100                         };
 101                         next;
 102                 }
 103                 my $s = ascii_html($smsg->subject);
 104                 my $f = ascii_html($smsg->from_name);
 105                 my $ts = PublicInbox::View::fmt_ts($smsg->ts);
 106                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
 107                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 108                         $s . "</a></b>\n";
 109                 $$res .= "$pfx  - by $f @ $ts UTC [$pct%]\n\n";
 110         }
 111         $$res .= search_nav_bot($mset, $q);
 112         *noop;
 113 }
 114
 115 sub err_txt {
 116         my ($ctx, $err) = @_;
 117         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 118         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 119         $err = ascii_html($err);
 120         "\nBad query: <b>$err</b>\n" .
 121                 qq{See <a\nhref="$u">$u</a> for help on using search};
 122 }
 123
 124 sub search_nav_top {
 125         my ($mset, $q, $ctx) = @_;
 126
 127         my $rv = '<pre>';
 128         my $initial_q = $ctx->{-uxs_retried};
 129         if (defined $initial_q) {
 130                 my $rewritten = $q->{'q'};
 131                 utf8::decode($initial_q);
 132                 utf8::decode($rewritten);
 133                 $initial_q = ascii_html($initial_q);
 134                 $rewritten = ascii_html($rewritten);
 135                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 136                 $rv .= " returned no results, used:\n";
 137                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 138         }
 139
 140         $rv .= 'Search results ordered by [';
 141         if ($q->{r}) {
 142                 my $d = $q->qs_html(r => 0);
 143                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 144         } else {
 145                 my $d = $q->qs_html(r => 1);
 146                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 147         }
 148
 149         $rv .= ']  view[';
 150
 151         my $x = $q->{x};
 152         if ($x eq '') {
 153                 my $t = $q->qs_html(x => 't');
 154                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">threaded</a>}
 155         } elsif ($q->{x} eq 't') {
 156                 my $s = $q->qs_html(x => '');
 157                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>threaded</b>};
 158         }
 159         my $A = $q->qs_html(x => 'A', r => undef);
 160         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 161 }
 162
 163 sub search_nav_bot {
 164         my ($mset, $q) = @_;
 165         my $total = $mset->get_matches_estimated;
 166         my $nr = scalar $mset->items;
 167         my $o = $q->{o};
 168         my $end = $o + $nr;
 169         my $beg = $o + 1;
 170         my $rv = '</pre><hr><pre id=t>';
 171         if ($beg <= $end) {
 172                 $rv .= "Results $beg-$end of $total";
 173                 $rv .= ' (estimated)' if $end != $total;
 174         } else {
 175                 $rv .= "No more results, only $total";
 176         }
 177         my $n = $o + $LIM;
 178
 179         if ($n < $total) {
 180                 my $qs = $q->qs_html(o => $n);
 181                 $rv .= qq{  <a\nhref="?$qs"\nrel=next>next</a>}
 182         }
 183         if ($o > 0) {
 184                 $rv .= $n < $total ? '/' : '       ';
 185                 my $p = $o - $LIM;
 186                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 187                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 188         }
 189         $rv .= '</pre>';
 190 }
 191
 192 sub sort_relevance {
 193         my ($pct) = @_;
 194         sub {
 195                 [ sort { (eval { $pct->{$b->topmost->{id}} } || 0)
 196                                 <=>
 197                         (eval { $pct->{$a->topmost->{id}} } || 0)
 198         } @{$_[0]} ] };
 199 }
 200
 201 sub mset_thread {
 202         my ($ctx, $mset, $q) = @_;
 203         my %pct;
 204         my $msgs = $ctx->{srch}->retry_reopen(sub { [ map {
 205                 my $i = $_;
 206                 my $smsg = PublicInbox::SearchMsg->load_doc($i->get_document);
 207                 $pct{$smsg->mid} = $i->get_percent;
 208                 $smsg;
 209         } ($mset->items) ]});
 210         my $r = $q->{r};
 211         my $rootset = PublicInbox::SearchThread::thread($msgs,
 212                 $r ? sort_relevance(\%pct) : *PublicInbox::View::sort_ts);
 213         my $skel = search_nav_bot($mset, $q). "<pre>";
 214         my $inbox = $ctx->{-inbox};
 215         $ctx->{-upfx} = '';
 216         $ctx->{anchor_idx} = 1;
 217         $ctx->{cur_level} = 0;
 218         $ctx->{dst} = \$skel;
 219         $ctx->{mapping} = {};
 220         $ctx->{pct} = \%pct;
 221         $ctx->{prev_attr} = '';
 222         $ctx->{prev_level} = 0;
 223         $ctx->{seen} = {};
 224         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 225
 226         PublicInbox::View::walk_thread($rootset, $ctx,
 227                 *PublicInbox::View::pre_thread);
 228         @$msgs = reverse @$msgs if $r;
 229         my $mime;
 230         sub {
 231                 return unless $msgs;
 232                 while ($mime = pop @$msgs) {
 233                         $mime = $inbox->msg_by_smsg($mime) and last;
 234                 }
 235                 if ($mime) {
 236                         $mime = PublicInbox::MIME->new($mime);
 237                         return PublicInbox::View::index_entry($mime, $ctx,
 238                                 scalar @$msgs);
 239                 }
 240                 $msgs = undef;
 241                 $skel .= "\n</pre>";
 242         };
 243 }
 244
 245 sub ctx_prepare {
 246         my ($q, $ctx) = @_;
 247         my $qh = $q->{'q'};
 248         utf8::decode($qh);
 249         $qh = ascii_html($qh);
 250         $ctx->{-q_value_html} = $qh;
 251         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 252         $ctx->{-title_html} = "$qh - search results";
 253         my $extra = '';
 254         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 255         if (my $x = $q->{x}) {
 256                 $x = ascii_html($x);
 257                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 258         }
 259         $ctx->{-extra_form_html} = $extra;
 260 }
 261
 262 sub adump {
 263         my ($cb, $mset, $q, $ctx) = @_;
 264         my $ibx = $ctx->{-inbox};
 265         my @items = $mset->items;
 266         $ctx->{search_query} = $q;
 267         my $srch = $ctx->{srch};
 268         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 269                 while (my $x = shift @items) {
 270                         $x = load_doc_retry($srch, $x);
 271                         $x = $ibx->msg_by_smsg($x) and
 272                                         return PublicInbox::MIME->new($x);
 273                 }
 274                 return undef;
 275         });
 276 }
 277
 278 package PublicInbox::SearchQuery;
 279 use strict;
 280 use warnings;
 281 use URI::Escape qw(uri_escape);
 282 use PublicInbox::Hval;
 283 use PublicInbox::MID qw(MID_ESC);
 284
 285 sub new {
 286         my ($class, $qp) = @_;
 287
 288         my $r = $qp->{r};
 289         bless {
 290                 q => $qp->{'q'},
 291                 x => $qp->{x} || '',
 292                 o => (($qp->{o} || '0') =~ /(\d+)/),
 293                 r => (defined $r && $r ne '0'),
 294         }, $class;
 295 }
 296
 297 sub qs_html {
 298         my ($self, %over) = @_;
 299
 300         if (keys %over) {
 301                 my $tmp = bless { %$self }, ref($self);
 302                 foreach my $k (keys %over) {
 303                         $tmp->{$k} = $over{$k};
 304                 }
 305                 $self = $tmp;
 306         }
 307
 308         my $q = uri_escape($self->{'q'}, MID_ESC);
 309         $q =~ s/%20/+/g; # improve URL readability
 310         my $qs = "q=$q";
 311
 312         if (my $o = $self->{o}) { # ignore o == 0
 313                 $qs .= "&amp;o=$o";
 314         }
 315         if (my $r = $self->{r}) {
 316                 $qs .= "&amp;r";
 317         }
 318         if (my $x = $self->{x}) {
 319                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A');
 320         }
 321         $qs;
 322 }
 323
 324 1;