lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use bytes (); # only for bytes::length
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw/id_compress mid_escape mids mids_for_index references/;
  14 use PublicInbox::MsgIter;
  15 use PublicInbox::Address;
  16 use PublicInbox::WwwStream;
  17 use PublicInbox::Reply;
  18 use PublicInbox::ViewDiff qw(flush_diff);
  19 require POSIX;
  20 use Time::Local qw(timegm);
  21 use PublicInbox::SearchMsg qw(subject_normalized);
  22 use constant COLS => 72;
  23 use constant INDENT => '  ';
  24 use constant TCHILD => '` ';
  25 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  26
  27 sub msg_html_i {
  28         my ($nr, $ctx) = @_;
  29         my $more = $ctx->{more};
  30         if ($nr == 1) {
  31                 # $more cannot be true w/o $smsg being defined:
  32                 my $upfx = $more ? '../'.mid_escape($ctx->{smsg}->mid).'/' : '';
  33                 $ctx->{tip} .
  34                         multipart_text_as_html($ctx->{mime}, $upfx, $ctx) .
  35                         '</pre><hr>'
  36         } elsif ($more && @$more) {
  37                 ++$ctx->{end_nr};
  38                 msg_html_more($ctx, $more, $nr);
  39         } elsif ($nr == $ctx->{end_nr}) {
  40                 # fake an EOF if generating the footer fails;
  41                 # we want to at least show the message if something
  42                 # here crashes:
  43                 eval {
  44                         my $hdr = delete($ctx->{mime})->header_obj;
  45                         '<pre>' . html_footer($hdr, 1, $ctx) .
  46                         '</pre>' . msg_reply($ctx, $hdr)
  47                 };
  48         } else {
  49                 undef
  50         }
  51 }
  52
  53 # public functions: (unstable)
  54
  55 sub msg_html {
  56         my ($ctx, $mime, $more, $smsg) = @_;
  57         my $ibx = $ctx->{-inbox};
  58         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  59         $ctx->{tip} = _msg_html_prepare($mime->header_obj, $ctx, $more, 0);
  60         $ctx->{more} = $more;
  61         $ctx->{end_nr} = 2;
  62         $ctx->{smsg} = $smsg;
  63         $ctx->{mime} = $mime;
  64         PublicInbox::WwwStream->response($ctx, 200, \&msg_html_i);
  65 }
  66
  67 sub msg_page {
  68         my ($ctx) = @_;
  69         my $mid = $ctx->{mid};
  70         my $ibx = $ctx->{-inbox};
  71         my ($first, $more);
  72         my $smsg;
  73         if (my $over = $ibx->over) {
  74                 my ($id, $prev);
  75                 $smsg = $over->next_by_mid($mid, \$id, \$prev);
  76                 $first = $ibx->msg_by_smsg($smsg) if $smsg;
  77                 if ($first) {
  78                         my $next = $over->next_by_mid($mid, \$id, \$prev);
  79                         $more = [ $id, $prev, $next ] if $next;
  80                 }
  81                 return unless $first;
  82         } else {
  83                 $first = $ibx->msg_by_mid($mid) or return;
  84         }
  85         msg_html($ctx, PublicInbox::MIME->new($first), $more, $smsg);
  86 }
  87
  88 sub msg_html_more {
  89         my ($ctx, $more, $nr) = @_;
  90         my $str = eval {
  91                 my ($id, $prev, $smsg) = @$more;
  92                 my $mid = $ctx->{mid};
  93                 my $ibx = $ctx->{-inbox};
  94                 $smsg = $ibx->smsg_mime($smsg);
  95                 my $next = $ibx->over->next_by_mid($mid, \$id, \$prev);
  96                 @$more = $next ? ($id, $prev, $next) : ();
  97                 if ($smsg) {
  98                         my $mime = $smsg->{mime};
  99                         my $upfx = '../' . mid_escape($smsg->mid) . '/';
 100                         _msg_html_prepare($mime->header_obj, $ctx, $more, $nr) .
 101                                 multipart_text_as_html($mime, $upfx, $ctx) .
 102                                 '</pre><hr>'
 103                 } else {
 104                         '';
 105                 }
 106         };
 107         if ($@) {
 108                 warn "Error lookup up additional messages: $@\n";
 109                 $str = '<pre>Error looking up additional messages</pre>';
 110         }
 111         $str;
 112 }
 113
 114 # /$INBOX/$MESSAGE_ID/#R
 115 sub msg_reply {
 116         my ($ctx, $hdr) = @_;
 117         my $se_url =
 118          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
 119         my $p_url =
 120          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
 121
 122         my $info = '';
 123         my $ibx = $ctx->{-inbox};
 124         if (my $url = $ibx->{infourl}) {
 125                 $url = PublicInbox::Hval::prurl($ctx->{env}, $url);
 126                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
 127         }
 128
 129         my ($arg, $link, $reply_to_all) =
 130                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 131         if (ref($arg) eq 'SCALAR') {
 132                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 133         }
 134
 135         # mailto: link only works if address obfuscation is disabled
 136         if ($link) {
 137                 $link = <<EOF;
 138
 139 * If your mail client supports setting the <b>In-Reply-To</b> header
 140   via mailto: links, try the <a
 141 href="$link">mailto: link</a>
 142 EOF
 143         }
 144
 145         push @$arg, '/path/to/YOUR_REPLY';
 146         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 147         <<EOF
 148 <hr><pre
 149 id=R><b>Reply instructions:</b>
 150
 151 You may reply publically to <a
 152 href=#t>this message</a> via plain-text email
 153 using any one of the following methods:
 154
 155 * Save the following mbox file, import it into your mail client,
 156   and $reply_to_all from there: <a
 157 href=raw>mbox</a>
 158
 159   Avoid top-posting and favor interleaved quoting:
 160   <a
 161 href="$p_url">$p_url</a>
 162 $info
 163 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 164   switches of git-send-email(1):
 165
 166   git send-email$arg
 167
 168   <a
 169 href="$se_url">$se_url</a>
 170 $link</pre>
 171 EOF
 172 }
 173
 174 sub in_reply_to {
 175         my ($hdr) = @_;
 176         my $refs = references($hdr);
 177         $refs->[-1];
 178 }
 179
 180 sub fold_addresses ($) {
 181         return $_[0] if length($_[0]) <= COLS;
 182         # try to fold on commas after non-word chars before $lim chars,
 183         # Try to get the "," preceeded by ">" or ")", but avoid folding
 184         # on the comma where somebody uses "Lastname, Firstname".
 185         # We also try to keep the last and penultimate addresses in
 186         # the list on the same line if possible, hence the extra \z
 187         # Fall back to folding on spaces at $lim + 1 chars
 188         my $lim = COLS - 8; # 8 = "\t" display width
 189         my $too_long = $lim + 1;
 190         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 191         $_[0] = join("\n\t",
 192                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 193                                 .{1,$lim}(?:,|\z)|
 194                                 .{1,$lim}|
 195                                 .{$too_long,}?)(?:\s|\z)/xgo));
 196 }
 197
 198 sub _hdr_names_html ($$) {
 199         my ($hdr, $field) = @_;
 200         my @vals = $hdr->header($field) or return '';
 201         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 202 }
 203
 204 sub nr_to_s ($$$) {
 205         my ($nr, $singular, $plural) = @_;
 206         return "0 $plural" if $nr == 0;
 207         $nr == 1 ? "$nr $singular" : "$nr $plural";
 208 }
 209
 210 # this is already inside a <pre>
 211 sub index_entry {
 212         my ($smsg, $ctx, $more) = @_;
 213         my $subj = $smsg->subject;
 214         my $mid_raw = $smsg->mid;
 215         my $id = id_compress($mid_raw, 1);
 216         my $id_m = 'm'.$id;
 217
 218         my $root_anchor = $ctx->{root_anchor} || '';
 219         my $irt;
 220         my $obfs_ibx = $ctx->{-obfs_ibx};
 221
 222         $subj = '(no subject)' if $subj eq '';
 223         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 224         $subj = '<b>'.ascii_html($subj).'</b>';
 225         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 226         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 227         $rv .= $subj . "\n";
 228         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 229         my @tocc;
 230         my $ds = $smsg->ds; # for v1 non-Xapian/SQLite users
 231         # deleting {mime} is critical to memory use,
 232         # the rest of the fields saves about 400K as we iterate across 1K msgs
 233         my ($mime) = delete @$smsg{qw(mime ds ts blob subject)};
 234
 235         my $hdr = $mime->header_obj;
 236         my $from = _hdr_names_html($hdr, 'From');
 237         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 238         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 239         my $upfx = $ctx->{-upfx};
 240         my $mhref = $upfx . mid_escape($mid_raw) . '/';
 241         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 242         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 243         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 244         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 245         my ($tlen, $clen) = (length($to), length($cc));
 246         my $to_cc = '';
 247         if (($tlen + $clen) > COLS) {
 248                 $to_cc .= '  To: '.$to."\n" if $tlen;
 249                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 250         } else {
 251                 if ($tlen) {
 252                         $to_cc .= '  To: '.$to;
 253                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 254                 } else {
 255                         $to_cc .= '  Cc: '.$cc if $clen;
 256                 }
 257                 $to_cc .= "\n";
 258         }
 259         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 260         $rv .= $to_cc;
 261
 262         my $mapping = $ctx->{mapping};
 263         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 264                 my $mirt = PublicInbox::Hval->new_msgid($irt);
 265                 my $href = $upfx . $mirt->{href}. '/';
 266                 my $html = $mirt->as_html;
 267                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 268         }
 269         $rv .= "\n";
 270
 271         # scan through all parts, looking for displayable text
 272         my $ibx = $ctx->{-inbox};
 273         msg_iter($mime, sub { $rv .= add_text_body($mhref, $ctx, $_[0]) });
 274
 275         # add the footer
 276         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 277                 "<a\nhref=\"$mhref\">permalink</a>" .
 278                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 279                 " <a\nhref=\"${mhref}#R\">reply</a>";
 280
 281         my $hr;
 282         if (my $pct = $ctx->{pct}) { # used by SearchView.pm
 283                 $rv .= "\t[relevance $pct->{$mid_raw}%]";
 284                 $hr = 1;
 285         } elsif ($mapping) {
 286                 my $nested = 'nested';
 287                 my $flat = 'flat';
 288                 my $end = '';
 289                 if ($ctx->{flat}) {
 290                         $hr = 1;
 291                         $flat = "<b>$flat</b>";
 292                 } else {
 293                         $nested = "<b>$nested</b>";
 294                 }
 295                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 296                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 297                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 298         } else {
 299                 $hr = $ctx->{-hr};
 300         }
 301
 302         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 303         $rv;
 304 }
 305
 306 sub pad_link ($$;$) {
 307         my ($mid, $level, $s) = @_;
 308         $s ||= '...';
 309         my $id = id_compress($mid, 1);
 310         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 311 }
 312
 313 sub _th_index_lite {
 314         my ($mid_raw, $irt, $id, $ctx) = @_;
 315         my $rv = '';
 316         my $mapping = $ctx->{mapping} or return $rv;
 317         my $pad = '  ';
 318         my $mid_map = $mapping->{$mid_raw};
 319         defined $mid_map or
 320                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 321         my ($attr, $node, $idx, $level) = @$mid_map;
 322         my $children = $node->{children};
 323         my $nr_c = scalar @$children;
 324         my $nr_s = 0;
 325         my $siblings;
 326         if (my $smsg = $node->{smsg}) {
 327                 # delete saves about 200KB on a 1K message thread
 328                 if (my $refs = delete $smsg->{references}) {
 329                         ($$irt) = ($refs =~ m/<([^>]+)>\z/);
 330                 }
 331         }
 332         my $irt_map = $mapping->{$$irt} if defined $$irt;
 333         if (defined $irt_map) {
 334                 $siblings = $irt_map->[1]->{children};
 335                 $nr_s = scalar(@$siblings) - 1;
 336                 $rv .= $pad . $irt_map->[0];
 337                 if ($idx > 0) {
 338                         my $prev = $siblings->[$idx - 1];
 339                         my $pmid = $prev->{id};
 340                         if ($idx > 2) {
 341                                 my $s = ($idx - 1). ' preceding siblings ...';
 342                                 $rv .= pad_link($pmid, $level, $s);
 343                         } elsif ($idx == 2) {
 344                                 my $ppmid = $siblings->[0]->{id};
 345                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 346                         }
 347                         $rv .= $pad . $mapping->{$pmid}->[0];
 348                 }
 349         }
 350         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 351         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 352         $attr =~ s!\n\z!</b>\n!s;
 353         $attr =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 354         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 355         $rv .= "<b>@ $attr";
 356         if ($nr_c) {
 357                 my $cmid = $children->[0]->{id};
 358                 $rv .= $pad . $mapping->{$cmid}->[0];
 359                 if ($nr_c > 2) {
 360                         my $s = ($nr_c - 1). ' more replies';
 361                         $rv .= pad_link($cmid, $level + 1, $s);
 362                 } elsif (my $cn = $children->[1]) {
 363                         $rv .= $pad . $mapping->{$cn->{id}}->[0];
 364                 }
 365         }
 366
 367         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 368         if ($next) {
 369                 my $nmid = $next->{id};
 370                 $rv .= $pad . $mapping->{$nmid}->[0];
 371                 my $nnext = $nr_s - $idx;
 372                 if ($nnext > 2) {
 373                         my $s = ($nnext - 1).' subsequent siblings';
 374                         $rv .= pad_link($nmid, $level, $s);
 375                 } elsif (my $nn = $siblings->[$idx + 2]) {
 376                         $rv .= $pad . $mapping->{$nn->{id}}->[0];
 377                 }
 378         }
 379         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 380 }
 381
 382 sub walk_thread {
 383         my ($rootset, $ctx, $cb) = @_;
 384         my @q = map { (0, $_, -1) } @$rootset;
 385         while (@q) {
 386                 my ($level, $node, $i) = splice(@q, 0, 3);
 387                 defined $node or next;
 388                 $cb->($ctx, $level, $node, $i) or return;
 389                 ++$level;
 390                 $i = 0;
 391                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 392         }
 393 }
 394
 395 sub pre_thread  {
 396         my ($ctx, $level, $node, $idx) = @_;
 397         $ctx->{mapping}->{$node->{id}} = [ '', $node, $idx, $level ];
 398         skel_dump($ctx, $level, $node);
 399 }
 400
 401 sub thread_index_entry {
 402         my ($ctx, $level, $smsg) = @_;
 403         my ($beg, $end) = thread_adj_level($ctx, $level);
 404         $beg . '<pre>' . index_entry($smsg, $ctx, 0) . '</pre>' . $end;
 405 }
 406
 407 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 408         my ($nr, $ctx) = @_;
 409         return unless exists($ctx->{dst});
 410         my $q = $ctx->{-queue};
 411         while (@$q) {
 412                 my $level = shift @$q;
 413                 my $node = shift @$q or next;
 414                 my $cl = $level + 1;
 415                 unshift @$q, map { ($cl, $_) } @{$node->{children}};
 416                 if (my $smsg = $ctx->{-inbox}->smsg_mime($node->{smsg})) {
 417                         return thread_index_entry($ctx, $level, $smsg);
 418                 } else {
 419                         return ghost_index_entry($ctx, $level, $node);
 420                 }
 421         }
 422         join('', thread_adj_level($ctx, 0)) . ${delete $ctx->{dst}}; # skel
 423 }
 424
 425 sub stream_thread ($$) {
 426         my ($rootset, $ctx) = @_;
 427         my $ibx = $ctx->{-inbox};
 428         my @q = map { (0, $_) } @$rootset;
 429         my ($smsg, $level);
 430         while (@q) {
 431                 $level = shift @q;
 432                 my $node = shift @q or next;
 433                 my $cl = $level + 1;
 434                 unshift @q, map { ($cl, $_) } @{$node->{children}};
 435                 $smsg = $ibx->smsg_mime($node->{smsg}) and last;
 436         }
 437         return missing_thread($ctx) unless $smsg;
 438
 439         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 440         $ctx->{-title_html} = ascii_html($smsg->subject);
 441         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $smsg);
 442         $ctx->{-queue} = \@q;
 443         PublicInbox::WwwStream->response($ctx, 200, \&stream_thread_i);
 444 }
 445
 446 sub thread_html {
 447         my ($ctx) = @_;
 448         my $mid = $ctx->{mid};
 449         my $ibx = $ctx->{-inbox};
 450         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 451         return missing_thread($ctx) if $nr == 0;
 452         my $skel = '<hr><pre>';
 453         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 454         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 455         $skel .= "<b\nid=t>Thread overview:</b> ";
 456         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 457         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 458         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 459         $skel .= "-- links below jump to the message on this page --\n";
 460         $ctx->{-upfx} = '../../';
 461         $ctx->{cur_level} = 0;
 462         $ctx->{dst} = \$skel;
 463         $ctx->{prev_attr} = '';
 464         $ctx->{prev_level} = 0;
 465         $ctx->{root_anchor} = anchor_for($mid);
 466         $ctx->{mapping} = {};
 467         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 468                        .' in thread';
 469
 470         my $rootset = thread_results($ctx, $msgs);
 471
 472         # reduce hash lookups in pre_thread->skel_dump
 473         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 474         walk_thread($rootset, $ctx, *pre_thread);
 475
 476         $skel .= '</pre>';
 477         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 478
 479         # flat display: lazy load the full message from smsg
 480         my $smsg;
 481         while (my $m = shift @$msgs) {
 482                 $smsg = $ibx->smsg_mime($m) and last;
 483         }
 484         return missing_thread($ctx) unless $smsg;
 485         $ctx->{-title_html} = ascii_html($smsg->subject);
 486         $ctx->{-html_tip} = '<pre>'.index_entry($smsg, $ctx, scalar @$msgs);
 487         $ctx->{msgs} = $msgs;
 488         PublicInbox::WwwStream->response($ctx, 200, \&thread_html_i);
 489 }
 490
 491 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 492         my ($nr, $ctx) = @_;
 493         my $msgs = $ctx->{msgs} or return;
 494         while (my $smsg = shift @$msgs) {
 495                 $ctx->{-inbox}->smsg_mime($smsg) or next;
 496                 return index_entry($smsg, $ctx, scalar @$msgs);
 497         }
 498         my ($skel) = delete @$ctx{qw(dst msgs)};
 499         $$skel;
 500 }
 501
 502 sub multipart_text_as_html {
 503         my ($mime, $upfx, $ctx) = @_;
 504         my $rv = "";
 505
 506         # scan through all parts, looking for displayable text
 507         msg_iter($mime, sub { $rv .= add_text_body($upfx, $ctx, $_[0]) });
 508         $rv;
 509 }
 510
 511 sub flush_quote {
 512         my ($s, $l, $quot) = @_;
 513
 514         # show everything in the full version with anchor from
 515         # short version (see above)
 516         my $rv = $l->linkify_1($$quot);
 517
 518         # we use a <span> here to allow users to specify their own
 519         # color for quoted text
 520         $rv = $l->linkify_2(ascii_html($rv));
 521         $$quot = undef;
 522         $$s .= qq(<span\nclass="q">) . $rv . '</span>'
 523 }
 524
 525 sub attach_link ($$$$;$) {
 526         my ($upfx, $ct, $p, $fn, $err) = @_;
 527         my ($part, $depth, @idx) = @$p;
 528         my $nl = $idx[-1] > 1 ? "\n" : '';
 529         my $idx = join('.', @idx);
 530         my $size = bytes::length($part->body);
 531
 532         # hide attributes normally, unless we want to aid users in
 533         # spotting MUA problems:
 534         $ct =~ s/;.*// unless $err;
 535         $ct = ascii_html($ct);
 536         my $desc = $part->header('Content-Description');
 537         $desc = $fn unless defined $desc;
 538         $desc = '' unless defined $desc;
 539         my $sfn;
 540         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 541                 $sfn = $fn;
 542         } elsif ($ct eq 'text/plain') {
 543                 $sfn = 'a.txt';
 544         } else {
 545                 $sfn = 'a.bin';
 546         }
 547         my $ret = qq($nl<a\nhref="$upfx$idx-$sfn">);
 548         if ($err) {
 549                 $ret .=
 550 "[-- Warning: decoded text below may be mangled --]\n";
 551         }
 552         $ret .= "[-- Attachment #$idx: ";
 553         my $ts = "Type: $ct, Size: $size bytes";
 554         $desc = ascii_html($desc);
 555         $ret .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 556         $ret .= "</a>\n";
 557 }
 558
 559 sub add_text_body {
 560         my ($upfx, $ctx, $p) = @_;
 561         my $ibx = $ctx->{-inbox};
 562         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
 563         # $p - from msg_iter: [ Email::MIME, depth, @idx ]
 564         my ($part, $depth, @idx) = @$p;
 565         my $ct = $part->content_type || 'text/plain';
 566         my $fn = $part->filename;
 567         my ($s, $err) = msg_part_text($part, $ct);
 568
 569         return attach_link($upfx, $ct, $p, $fn) unless defined $s;
 570
 571         # makes no difference to browsers, and don't screw up filename
 572         # link generation in diffs with the extra '%0D'
 573         $s =~ s/\r\n/\n/sg;
 574
 575         # always support diff-highlighting, but we can't linkify hunk
 576         # headers for solver unless some coderepo are configured:
 577         my $diff;
 578         if ($s =~ /^(?:diff|---|\+{3}) /ms) {
 579                 # diffstat anchors do not link across attachments or messages:
 580                 $idx[0] = $upfx . $idx[0] if $upfx ne '';
 581                 $ctx->{-apfx} = join('/', @idx);
 582                 $ctx->{-anchors} = {}; # attr => filename
 583                 $ctx->{-diff} = $diff = [];
 584                 delete $ctx->{-long_path};
 585                 my $spfx;
 586                 if ($ibx->{-repo_objs}) {
 587                         if (index($upfx, '//') >= 0) { # absolute URL (Atom feeds)
 588                                 $spfx = $upfx;
 589                                 $spfx =~ s!/([^/]*)/\z!/!;
 590                         } else {
 591                                 my $n_slash = $upfx =~ tr!/!/!;
 592                                 if ($n_slash == 0) {
 593                                         $spfx = '../';
 594                                 } elsif ($n_slash == 1) {
 595                                         $spfx = '';
 596                                 } else { # nslash == 2
 597                                         $spfx = '../../';
 598                                 }
 599                         }
 600                 }
 601                 $ctx->{-spfx} = $spfx;
 602         };
 603
 604         # some editors don't put trailing newlines at the end:
 605         $s .= "\n" unless $s =~ /\n\z/s;
 606
 607         # split off quoted and unquoted blocks:
 608         my @sections = split(/((?:^>[^\n]*\n)+)/sm, $s);
 609         $s = '';
 610         if (defined($fn) || $depth > 0 || $err) {
 611                 # badly-encoded message with $err? tell the world about it!
 612                 $s .= attach_link($upfx, $ct, $p, $fn, $err);
 613                 $s .= "\n";
 614         }
 615         my $l = PublicInbox::Linkify->new;
 616         foreach my $cur (@sections) {
 617                 if ($cur =~ /\A>/) {
 618                         flush_quote(\$s, $l, \$cur);
 619                 } elsif ($diff) {
 620                         @$diff = split(/^/m, $cur);
 621                         $cur = undef;
 622                         flush_diff(\$s, $ctx, $l);
 623                 } else {
 624                         # regular lines, OK
 625                         $l->linkify_1($cur);
 626                         $s .= $l->linkify_2(ascii_html($cur));
 627                         $cur = undef;
 628                 }
 629         }
 630
 631         obfuscate_addrs($obfs_ibx, $s) if $obfs_ibx;
 632         $s;
 633 }
 634
 635 sub _msg_html_prepare {
 636         my ($hdr, $ctx, $more, $nr) = @_;
 637         my $atom = '';
 638         my $over = $ctx->{-inbox}->over;
 639         my $obfs_ibx = $ctx->{-obfs_ibx};
 640         my $rv = '';
 641         my $mids = mids_for_index($hdr);
 642         if ($nr == 0) {
 643                 if ($more) {
 644                         $rv .=
 645 "<pre>WARNING: multiple messages have this Message-ID\n</pre>";
 646                 }
 647                 $rv .= "<pre\nid=b>"; # anchor for body start
 648         } else {
 649                 $rv .= '<pre>';
 650         }
 651         if ($over) {
 652                 $ctx->{-upfx} = '../';
 653         }
 654         my @title; # (Subject[0], From[0])
 655         for my $v ($hdr->header('From')) {
 656                 $v = PublicInbox::Hval->new($v);
 657                 my @n = PublicInbox::Address::names($v->raw);
 658                 $title[1] //= ascii_html(join(', ', @n));
 659                 $v = $v->as_html;
 660                 if ($obfs_ibx) {
 661                         obfuscate_addrs($obfs_ibx, $v);
 662                         obfuscate_addrs($obfs_ibx, $title[1]);
 663                 }
 664                 $rv .= "From: $v\n" if $v ne '';
 665         }
 666         foreach my $h (qw(To Cc)) {
 667                 for my $v ($hdr->header($h)) {
 668                         fold_addresses($v);
 669                         $v = ascii_html($v);
 670                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 671                         $rv .= "$h: $v\n" if $v ne '';
 672                 }
 673         }
 674         my @subj = $hdr->header('Subject');
 675         if (@subj) {
 676                 for my $v (@subj) {
 677                         $v = ascii_html($v);
 678                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 679                         $rv .= 'Subject: ';
 680                         if ($over) {
 681                                 $rv .= qq(<a\nhref="#r"\nid=t>$v</a>\n);
 682                         } else {
 683                                 $rv .= "$v\n";
 684                         }
 685                         $title[0] //= $v;
 686                 }
 687         } else { # dummy anchor for thread skeleton at bottom of page
 688                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $over;
 689                 $title[0] = '(no subject)';
 690         }
 691         for my $v ($hdr->header('Date')) {
 692                 $v = ascii_html($v);
 693                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 694                 $rv .= "Date: $v\n";
 695         }
 696         $ctx->{-title_html} = join(' - ', @title);
 697         if (scalar(@$mids) == 1) { # common case
 698                 my $mid = PublicInbox::Hval->new_msgid($mids->[0]);
 699                 my $mhtml = $mid->as_html;
 700                 $rv .= "Message-ID: &lt;$mhtml&gt; ";
 701                 $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 702         } else {
 703                 # X-Alt-Message-ID can happen if a message is injected from
 704                 # public-inbox-nntpd because of multiple Message-ID headers.
 705                 my $lnk = PublicInbox::Linkify->new;
 706                 my $s = '';
 707                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 708                         $s .= "$h: $_\n" for ($hdr->header_raw($h));
 709                 }
 710                 $lnk->linkify_mids('..', \$s, 1);
 711                 $rv .= $s;
 712         }
 713         $rv .= _parent_headers($hdr, $over);
 714         $rv .= "\n";
 715 }
 716
 717 sub thread_skel {
 718         my ($dst, $ctx, $hdr, $tpfx) = @_;
 719         my $mid = mids($hdr)->[0];
 720         my $ibx = $ctx->{-inbox};
 721         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 722         my $expand = qq(expand[<a\nhref="${tpfx}T/#u">flat</a>) .
 723                         qq(|<a\nhref="${tpfx}t/#u">nested</a>]  ) .
 724                         qq(<a\nhref="${tpfx}t.mbox.gz">mbox.gz</a>  ) .
 725                         qq(<a\nhref="${tpfx}t.atom">Atom feed</a>);
 726
 727         my $parent = in_reply_to($hdr);
 728         $$dst .= "\n<b>Thread overview: </b>";
 729         if ($nr <= 1) {
 730                 if (defined $parent) {
 731                         $$dst .= "$expand\n ";
 732                         $$dst .= ghost_parent("$tpfx../", $parent) . "\n";
 733                 } else {
 734                         $$dst .= "[no followups] $expand\n";
 735                 }
 736                 $ctx->{next_msg} = undef;
 737                 $ctx->{parent_msg} = $parent;
 738                 return;
 739         }
 740
 741         $$dst .= "$nr+ messages / $expand";
 742         $$dst .= qq!  <a\nhref="#b">top</a>\n!;
 743
 744         # nb: mutt only shows the first Subject in the index pane
 745         # when multiple Subject: headers are present, so we follow suit:
 746         my $subj = $hdr->header('Subject') // '';
 747         $subj = '(no subject)' if $subj eq '';
 748         $ctx->{prev_subj} = [ split(/ /, subject_normalized($subj)) ];
 749         $ctx->{cur} = $mid;
 750         $ctx->{prev_attr} = '';
 751         $ctx->{prev_level} = 0;
 752         $ctx->{dst} = $dst;
 753
 754         # reduce hash lookups in skel_dump
 755         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 756         walk_thread(thread_results($ctx, $msgs), $ctx, *skel_dump);
 757
 758         $ctx->{parent_msg} = $parent;
 759 }
 760
 761 sub _parent_headers {
 762         my ($hdr, $over) = @_;
 763         my $rv = '';
 764         my @irt = $hdr->header_raw('In-Reply-To');
 765         my $refs;
 766         if (@irt) {
 767                 my $lnk = PublicInbox::Linkify->new;
 768                 $rv .= "In-Reply-To: $_\n" for @irt;
 769                 $lnk->linkify_mids('..', \$rv);
 770         } else {
 771                 $refs = references($hdr);
 772                 my $irt = pop @$refs;
 773                 if (defined $irt) {
 774                         my $v = PublicInbox::Hval->new_msgid($irt);
 775                         my $html = $v->as_html;
 776                         my $href = $v->{href};
 777                         $rv .= "In-Reply-To: &lt;";
 778                         $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 779                 }
 780         }
 781
 782         # do not display References: if search is present,
 783         # we show the thread skeleton at the bottom, instead.
 784         return $rv if $over;
 785
 786         $refs //= references($hdr);
 787         if (@$refs) {
 788                 @$refs = map { linkify_ref_no_over($_) } @$refs;
 789                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 790         }
 791         $rv;
 792 }
 793
 794 sub html_footer {
 795         my ($hdr, $standalone, $ctx, $rhref) = @_;
 796
 797         my $ibx = $ctx->{-inbox} if $ctx;
 798         my $upfx = '../';
 799         my $tpfx = '';
 800         my $idx = $standalone ? " <a\nhref=\"$upfx\">index</a>" : '';
 801         my $irt = '';
 802         if ($idx && $ibx->over) {
 803                 $idx .= "\n";
 804                 thread_skel(\$idx, $ctx, $hdr, $tpfx);
 805                 my ($next, $prev);
 806                 my $parent = '       ';
 807                 $next = $prev = '    ';
 808
 809                 if (my $n = $ctx->{next_msg}) {
 810                         $n = PublicInbox::Hval->new_msgid($n)->{href};
 811                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 812                 }
 813                 my $u;
 814                 my $par = $ctx->{parent_msg};
 815                 if ($par) {
 816                         $u = PublicInbox::Hval->new_msgid($par)->{href};
 817                         $u = "$upfx$u/";
 818                 }
 819                 if (my $p = $ctx->{prev_msg}) {
 820                         $prev = PublicInbox::Hval->new_msgid($p)->{href};
 821                         if ($p && $par && $p eq $par) {
 822                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 823                                         'rel=prev>prev parent</a>';
 824                                 $parent = '';
 825                         } else {
 826                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 827                                         'rel=prev>prev</a>';
 828                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 829                         }
 830                 } elsif ($u) { # unlikely
 831                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 832                 }
 833                 $irt = "$next $prev$parent ";
 834         } else {
 835                 $irt = '';
 836         }
 837         $rhref ||= '#R';
 838         $irt .= qq(<a\nhref="$rhref">reply</a>);
 839         $irt .= $idx;
 840 }
 841
 842 sub linkify_ref_no_over {
 843         my $v = PublicInbox::Hval->new_msgid($_[0]);
 844         my $html = $v->as_html;
 845         my $href = $v->{href};
 846         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 847 }
 848
 849 sub anchor_for {
 850         my ($msgid) = @_;
 851         'm' . id_compress($msgid, 1);
 852 }
 853
 854 sub ghost_parent {
 855         my ($upfx, $mid) = @_;
 856
 857         $mid = PublicInbox::Hval->new_msgid($mid);
 858         my $href = $mid->{href};
 859         my $html = $mid->as_html;
 860         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 861 }
 862
 863 sub indent_for {
 864         my ($level) = @_;
 865         $level ? INDENT x ($level - 1) : '';
 866 }
 867
 868 sub find_mid_root {
 869         my ($ctx, $level, $node, $idx) = @_;
 870         ++$ctx->{root_idx} if $level == 0;
 871         if ($node->{id} eq $ctx->{mid}) {
 872                 $ctx->{found_mid_at} = $ctx->{root_idx};
 873                 return 0;
 874         }
 875         1;
 876 }
 877
 878 sub strict_loose_note ($) {
 879         my ($nr) = @_;
 880         my $msg =
 881 "  -- strict thread matches above, loose matches on Subject: below --\n";
 882
 883         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 884                 $msg .=
 885 "  -- use mbox.gz link to download all $nr messages --\n";
 886         }
 887         $msg;
 888 }
 889
 890 sub thread_results {
 891         my ($ctx, $msgs) = @_;
 892         require PublicInbox::SearchThread;
 893         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 894
 895         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 896         # and preserved in the future.  This bug is hidden by `sid' matches
 897         # in get_thread, so we never noticed it until now.  And even when
 898         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 899         # bump since reindexing is expensive and users may not do it
 900
 901         # loose threading could've returned too many results,
 902         # put the root the message we care about at the top:
 903         my $mid = $ctx->{mid};
 904         if (defined($mid) && scalar(@$rootset) > 1) {
 905                 $ctx->{root_idx} = -1;
 906                 my $nr = scalar @$msgs;
 907                 walk_thread($rootset, $ctx, *find_mid_root);
 908                 my $idx = $ctx->{found_mid_at};
 909                 if (defined($idx) && $idx != 0) {
 910                         my $tip = splice(@$rootset, $idx, 1);
 911                         @$rootset = reverse @$rootset;
 912                         unshift @$rootset, $tip;
 913                         $ctx->{sl_note} = strict_loose_note($nr);
 914                 }
 915         }
 916         $rootset
 917 }
 918
 919 sub missing_thread {
 920         my ($ctx) = @_;
 921         require PublicInbox::ExtMsg;
 922         PublicInbox::ExtMsg::ext_msg($ctx);
 923 }
 924
 925 sub fmt_ts { POSIX::strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 926
 927 sub dedupe_subject {
 928         my ($prev_subj, $subj, $val) = @_;
 929
 930         my $omit = ''; # '"' denotes identical text omitted
 931         my (@prev_pop, @curr_pop);
 932         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 933                 push(@prev_pop, pop(@$prev_subj));
 934                 push(@curr_pop, pop(@$subj));
 935                 $omit ||= $val;
 936         }
 937         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 938         if (scalar(@curr_pop) == 1) {
 939                 $omit = '';
 940                 push @$prev_subj, @prev_pop;
 941                 push @$subj, @curr_pop;
 942         }
 943         $omit;
 944 }
 945
 946 sub skel_dump {
 947         my ($ctx, $level, $node) = @_;
 948         my $smsg = $node->{smsg} or return _skel_ghost($ctx, $level, $node);
 949
 950         my $dst = $ctx->{dst};
 951         my $cur = $ctx->{cur};
 952         my $mid = $smsg->{mid};
 953
 954         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 955                 $$dst .= delete $ctx->{sl_note} || '';
 956         }
 957
 958         my $f = ascii_html($smsg->from_name);
 959         my $obfs_ibx = $ctx->{-obfs_ibx};
 960         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 961
 962         my $d = fmt_ts($smsg->{ds});
 963         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 964         if (my $pct = $ctx->{pct}) {
 965                 $pct = $pct->{$smsg->{mid}};
 966                 if (defined $pct) {
 967                         $d .= (sprintf(' % 2u', $pct) . '%');
 968                 } else {
 969                         $unmatched = 1;
 970                         $d .= '    ';
 971                 }
 972         }
 973         $d .= ' ' . indent_for($level) . th_pfx($level);
 974         my $attr = $f;
 975         $ctx->{first_level} ||= $level;
 976
 977         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 978                 $ctx->{prev_attr} = $attr;
 979         }
 980         $ctx->{prev_level} = $level;
 981
 982         if ($cur) {
 983                 if ($cur eq $mid) {
 984                         delete $ctx->{cur};
 985                         $$dst .= "<b>$d<a\nid=r\nhref=\"#t\">".
 986                                  "$attr [this message]</a></b>\n";
 987                         return 1;
 988                 } else {
 989                         $ctx->{prev_msg} = $mid;
 990                 }
 991         } else {
 992                 $ctx->{next_msg} ||= $mid;
 993         }
 994
 995         # Subject is never undef, this mail was loaded from
 996         # our Xapian which would've resulted in '' if it were
 997         # really missing (and Filter rejects empty subjects)
 998         my @subj = split(/ /, subject_normalized($smsg->subject));
 999         # remove common suffixes from the subject if it matches the previous,
1000         # so we do not show redundant text at the end.
1001         my $prev_subj = $ctx->{prev_subj} || [];
1002         $ctx->{prev_subj} = [ @subj ];
1003         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
1004         my $end;
1005         if (@subj) {
1006                 my $subj = join(' ', @subj);
1007                 $subj = ascii_html($subj);
1008                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1009                 $end = "$subj</a> $omit$f\n"
1010         } else {
1011                 $end = "$f</a>\n";
1012         }
1013         my $m;
1014         my $id = '';
1015         my $mapping = $unmatched ? undef : $ctx->{mapping};
1016         if ($mapping) {
1017                 my $map = $mapping->{$mid};
1018                 $id = id_compress($mid, 1);
1019                 $m = '#m'.$id;
1020                 $map->[0] = "$d<a\nhref=\"$m\">$end";
1021                 $id = "\nid=r".$id;
1022         } else {
1023                 $m = $ctx->{-upfx}.mid_escape($mid).'/';
1024         }
1025         $$dst .=  $d . "<a\nhref=\"$m\"$id>" . $end;
1026         1;
1027 }
1028
1029 sub _skel_ghost {
1030         my ($ctx, $level, $node) = @_;
1031
1032         my $mid = $node->{id};
1033         my $d = '     [not found] ';
1034         $d .= '    '  if exists $ctx->{pct};
1035         $d .= indent_for($level) . th_pfx($level);
1036         my $upfx = $ctx->{-upfx};
1037         my $m = PublicInbox::Hval->new_msgid($mid);
1038         my $href = $upfx . $m->{href} . '/';
1039         my $html = $m->as_html;
1040
1041         my $mapping = $ctx->{mapping};
1042         my $map = $mapping->{$mid} if $mapping;
1043         if ($map) {
1044                 my $id = id_compress($mid, 1);
1045                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1046                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1047         } else {
1048                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1049         }
1050         my $dst = $ctx->{dst};
1051         $$dst .= $d;
1052         1;
1053 }
1054
1055 sub sort_ds {
1056         [ sort {
1057                 (eval { $a->topmost->{smsg}->ds } || 0) <=>
1058                 (eval { $b->topmost->{smsg}->ds } || 0)
1059         } @{$_[0]} ];
1060 }
1061
1062 # accumulate recent topics if search is supported
1063 # returns 200 if done, 404 if not
1064 sub acc_topic {
1065         my ($ctx, $level, $node) = @_;
1066         my $mid = $node->{id};
1067         my $x = $node->{smsg} || $ctx->{-inbox}->smsg_by_mid($mid);
1068         my ($subj, $ds);
1069         my $topic;
1070         if ($x) {
1071                 $subj = $x->subject;
1072                 $subj = subject_normalized($subj);
1073                 $subj = '(no subject)' if $subj eq '';
1074                 $ds = $x->ds;
1075                 if ($level == 0) {
1076                         $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1077                         $ctx->{-cur_topic} = $topic;
1078                         push @{$ctx->{order}}, $topic;
1079                         return 1;
1080                 }
1081
1082                 $topic = $ctx->{-cur_topic}; # should never be undef
1083                 $topic->[0] = $ds if $ds > $topic->[0];
1084                 $topic->[1]++;
1085                 my $seen = $topic->[2];
1086                 if (scalar(@$topic) == 3) { # parent was a ghost
1087                         push @$topic, $subj;
1088                 } elsif (!$seen->{$subj}) {
1089                         push @$topic, $level, $subj;
1090                 }
1091                 $seen->{$subj} = $mid; # latest for subject
1092         } else { # ghost message
1093                 return 1 if $level != 0; # ignore child ghosts
1094                 $topic = [ -666, 0, {} ];
1095                 $ctx->{-cur_topic} = $topic;
1096                 push @{$ctx->{order}}, $topic;
1097         }
1098         1;
1099 }
1100
1101 sub dump_topics {
1102         my ($ctx) = @_;
1103         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1104         if (!@$order) {
1105                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1106                 return 404;
1107         }
1108
1109         my @out;
1110         my $ibx = $ctx->{-inbox};
1111         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1112
1113         # sort by recency, this allows new posts to "bump" old topics...
1114         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1115                 my ($ds, $n, $seen, $top, @ex) = @$topic;
1116                 @$topic = ();
1117                 next unless defined $top;  # ghost topic
1118                 my $mid = delete $seen->{$top};
1119                 my $href = mid_escape($mid);
1120                 my $prev_subj = [ split(/ /, $top) ];
1121                 $top = PublicInbox::Hval->new($top)->as_html;
1122                 $ds = fmt_ts($ds);
1123
1124                 # $n isn't the total number of posts on the topic,
1125                 # just the number of posts in the current results window
1126                 my $anchor;
1127                 if ($n == 1) {
1128                         $n = '';
1129                         $anchor = '#u'; # top of only message
1130                 } else {
1131                         $n = " ($n+ messages)";
1132                         $anchor = '#t'; # thread skeleton
1133                 }
1134
1135                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1136                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1137                 my $s = "<a\nhref=\"$href/T/$anchor\">$top</a>\n" .
1138                         " $ds UTC $n - $mbox / $atom\n";
1139                 for (my $i = 0; $i < scalar(@ex); $i += 2) {
1140                         my $level = $ex[$i];
1141                         my $subj = $ex[$i + 1];
1142                         $mid = delete $seen->{$subj};
1143                         my @subj = split(/ /, subject_normalized($subj));
1144                         my @next_prev = @subj; # full copy
1145                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1146                         $prev_subj = \@next_prev;
1147                         $subj = ascii_html(join(' ', @subj));
1148                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1149                         $href = mid_escape($mid);
1150                         $s .= indent_for($level) . TCHILD;
1151                         $s .= "<a\nhref=\"$href/T/#u\">$subj</a>$omit\n";
1152                 }
1153                 push @out, $s;
1154         }
1155         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1156         200;
1157 }
1158
1159 sub ts2str ($) {
1160         my ($ts) = @_;
1161         POSIX::strftime('%Y%m%d%H%M%S', gmtime($ts));
1162 }
1163
1164 sub str2ts ($) {
1165         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1166         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1167 }
1168
1169 sub pagination_footer ($$) {
1170         my ($ctx, $latest) = @_;
1171         delete $ctx->{qp} or return;
1172         my $next = $ctx->{next_page} || '';
1173         my $prev = $ctx->{prev_page} || '';
1174         if ($prev) {
1175                 $next = $next ? "$next " : '     ';
1176                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1177         }
1178         "<hr><pre>page: $next$prev</pre>";
1179 }
1180
1181 sub index_nav { # callback for WwwStream
1182         my (undef, $ctx) = @_;
1183         pagination_footer($ctx, '.')
1184 }
1185
1186 sub paginate_recent ($$) {
1187         my ($ctx, $lim) = @_;
1188         my $t = $ctx->{qp}->{t} || '';
1189         my $opts = { limit => $lim };
1190         my ($after, $before);
1191
1192         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1193         # if only $after exists "YYYYMMDD.." because "." could be skipped
1194         # if interpreted as an end-of-sentence
1195         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1196         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1197
1198         my $ibx = $ctx->{-inbox};
1199         my $msgs = $ibx->recent($opts, $after, $before);
1200         my $nr = scalar @$msgs;
1201         if ($nr < $lim && defined($after)) {
1202                 $after = $before = undef;
1203                 $msgs = $ibx->recent($opts);
1204                 $nr = scalar @$msgs;
1205         }
1206         my $more = $nr == $lim;
1207         my ($newest, $oldest);
1208         if ($nr) {
1209                 $newest = $msgs->[0]->{ts};
1210                 $oldest = $msgs->[-1]->{ts};
1211                 # if we only had $after, our SQL query in ->recent ordered
1212                 if ($newest < $oldest) {
1213                         ($oldest, $newest) = ($newest, $oldest);
1214                         $more = 0 if defined($after) && $after < $oldest;
1215                 }
1216         }
1217         if (defined($oldest) && $more) {
1218                 my $s = ts2str($oldest);
1219                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1220         }
1221         if (defined($newest) && (defined($before) || defined($after))) {
1222                 my $s = ts2str($newest);
1223                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1224         }
1225         $msgs;
1226 }
1227
1228 sub index_topics {
1229         my ($ctx) = @_;
1230         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1231         if (@$msgs) {
1232                 walk_thread(thread_results($ctx, $msgs), $ctx, *acc_topic);
1233         }
1234         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), *index_nav);
1235 }
1236
1237 sub thread_adj_level {
1238         my ($ctx, $level) = @_;
1239
1240         my $max = $ctx->{cur_level};
1241         if ($level <= 0) {
1242                 return ('', '') if $max == 0; # flat output
1243
1244                 # reset existing lists
1245                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1246                 $ctx->{cur_level} = 0;
1247                 ("$beg</ul>", '');
1248         } elsif ($level == $max) { # continue existing list
1249                 qw(<li> </li>);
1250         } elsif ($level < $max) {
1251                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1252                 $ctx->{cur_level} = $level;
1253                 ("$beg<li>", '</li>');
1254         } else { # ($level > $max) # start a new level
1255                 $ctx->{cur_level} = $level;
1256                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1257                 ($beg, '</li>');
1258         }
1259 }
1260
1261 sub ghost_index_entry {
1262         my ($ctx, $level, $node) = @_;
1263         my ($beg, $end) = thread_adj_level($ctx,  $level);
1264         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{id})
1265                 . '</pre>' . $end;
1266 }
1267
1268 1;